Wenn / Und Funktionen

[ArneMS]

   

Ich habe 4 Bereiche mit jeweils 3 Zellen. Sobald in jedem der 4 Bereiche in einer der 3 Zellen ein Eintrag ist, soll in einer gesonderten Kontrollzelle ein X erscheinen, damit ich weiß, dass der Vorgang abgeschlossen ist. Ich wollte das mit einer Wenn / Und Funktion erledigten, bekomme das aber nicht hin.

[steve1da]

Hola,
wie sieht denn dein Versuch aus?
Gruß,
steve1da

[ArneMS]

=WENN(UND;(UND(ISTLEER(B2)=FALSCH;ISTLEER(B3)=FALSCH;ISTLEER(B4)=FALSCH);(UND(ISTLEER(D2)=FALSCH;ISTLEER(D3)=FALSCH;ISTLEER(D4)=FALSCH);(UND(ISTLEER(F2)=FALSCH;ISTLEER(F3)=FALSCH;ISTLEER(F4)=FALSCH);(UND(ISTLEER(H2)=FALSCH;ISTLEER(H3)=FALSCH;ISTLEER(H4)=FALSCH);"X";"")

[steve1da]

Eine Möglichkeit:

Code:

=WENN(UND(ANZAHL2(B2:B4)>0;ANZAHL2(D2:D4)>0;ANZAHL2(F2:F4)>0;ANZAHL2(H2:H4)>0);"X";"")

[HKindler]

Hi,

ich würde ZÄHLENWENN() verwenden:
=(ZÄHLENWENN(Bereich1;"x")>0)*(ZÄHLENWENN(Bereich2;"x")>=0)*...
Diese Formel ergibt 1 wenn in jedem Bereich mindesten ein x ist. Ansonsten gibt es 0.

[LCohen]

=WENN((ANZAHL2(B2:B4)>0)*(ANZAHL2(D2:D4)>0)*(ANZAHL2(F2:F4)>0)*(ANZAHL2(H2:H4)>0);"X";"")

---

Hättest Du 365 und keine Lücken zwischen den Spalten, dann:

=UND(NACHSPALTE(B6:E8;LAMBDA(a;ANZAHL(a)>0)))

[ArneMS]

Vielen Dank schon mal an alle für die schnelle Hilfe.
Eine Frage noch: Wenn die zu betrachtenden Zellen in den Bereichen nicht direkt untereinander liegen, kann ich ja nicht den Zellenblock z.B. "B2:B4" benennen. Wie kann ich dann einzelnliegende Zellen in Bezug setzen?

---

OK hat sich erledigt. Ich hab sie Semikolon getrennt. Danke! Problem erledigt.

[LCohen]

Mit ZÄHLENWENN geht es nicht, mit ANZAHL2 schon: =ANZAHL2(B2;D2:D4;F4;...)

Übrigens auch für die Helfer: =ANZAHL2() ist das Komplement zu =SUMME(--ISTLEER()), denn es zählt auch Fehler. Leider kann aber ISTLEER keine Mehrfachauswahlen.

[steve1da]

Dann halt so:

Code:

ANZAHL2(D2;D4;D6)