Wenn (Und mit Zählenwenn Frage

[Jomich]

Hallo zusammen

Diese Formel funktioniert bei mir nicht und ich checke nicht warum ?  Fehlermeldung #Name?

Ziel ist es Duplikate in Spalte A zu erkennen und wenn in Spalte Y ein Wert ist, die Fallzahl um einen Fall zu erhöhen und dann gleichzeitig die Differenz zwischen z und W auszuweisen.


=WENN(UND(Y2="";ZÄHLENWENN($A$2:$A$2700;A2)=1);“Fallzahl_1“;WENN(UND(Y2<>"";ZÄHLENWENN($A$2:$A$2700;A2)=1);Fallzahl_2_FZ_Diff_“&Z2-W2;“Check“))



Excel Version 2010
Herzlicher Gruss Jomich

[shift-del]

Hallo Jomich

Du verwendest in deiner Formel sowohl “ (Zeichen 147) als auch " (Zeichen 34).
Wenn in Formeln Text vorkommt dann gehört dieser zwischen zwei " (Zeichen 34).
Passe deine Formel also entsprechend an.

[Jomich]

Hallo

Die Formel funktioniert nun super (Nochmals Danke an shift-del), vermutlich haben sich die Zeichen so eingeschlichen als ich diese zur besseren Ansicht ins Word übernommen und ergänzt hatte.

nun habe ich die Formel ausgebaut. Sie funktioniert, aber ist recht unübersichtlich. Gibt es bessere Möglichkeiten?


bisherige Formel:

=WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=1;S2="");"Fallzahl_1";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=1;S2<>"");"Fallzahl_2_FZ_Diff_"&T2-R2;WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=2;S2="");"Fallzahl_2";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=2;S2<>"");"Fallzahl_3_FZ_Diff_"&T2-R2;WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=3;S2="");"Fallzahl_3";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=3;S2<>"");"Fallzahl_4_FZ_Diff_"&T2-R2;WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=4;S2="");"Fallzahl_4";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=4;S2<>"");"Fallzahl_5_FZ_Diff_"&T2-R2;
WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=5;S2="");"Fallzahl_5";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=5;S2<>"");"Fallzahl_6_FZ_Diff_"&T2-R2;
WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=6;S2="");"Fallzahl_6";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=6;S2<>"");"Fallzahl_7_FZ_Diff_"&T2-R2;
WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=7;S2="");"Fallzahl_7";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=7;S2<>"");"Fallzahl_8_FZ_Diff_"&T2-R2;WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=8;S2="");"Fallzahl_8";WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=8;S2<>"");"Fallzahl_9_FZ_Diff_"&T2-R2;WENN(UND(ZÄHLENWENN($A$2:$A$2700;A2)=9;S2="");"Fallzahl_9";"Fallzahl_min_10"))))))))
)))))))))


Gruss Jomich

[shift-del]

Hallo

Probiere mal das:

Arbeitsblatt mit dem Namen 'Tabelle1'
	U	V
2	10	Fallzahl__min_10
3	2	Fallzahl_2
4	2	Fallzahl_2_FZ_Diff_-25
5	1	Fallzahl_1

Zelle	Formel
U2	=ZÄHLENWENN($A$2:$A$2700;$A2)+(S2<>"")
V2	="Fallzahl_"&WENN(AF7>9;"_min_10";AF7&WENN(S2<>"";"_FZ_Diff_"&T2-R2;""))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

oder auch so:

Code:

="Fallzahl_"&WENN(ZÄHLENWENN($A$2:$A$2700;A2)+(S2<>"")<10;ZÄHLENWENN($A$2:$A$2700;A2)+(S2<>"")&WENN(S2<>"";"_FZ_Diff_"&T2-R2;"");"_min_10")