Wenn zwei Bedingungen positiv sind ,soll der Wert Spalte M übernommen werden

[Tommiks]

Hallo zusammen,

ich habe die beiden Tabellen hinzugefügt.

Die Excel Tabelle Q-Kosten Verlauf soll in der Zelle F5 die angegebene Kostenstelle und das Datum mit der Excel Tabelle SAP Fehlerkostenliste vergleichen und die Kosten aus der Spalte M übernehmen.

Ich habe es mit der unteren Formel versucht, aber nur in der Zelle O14 einen Erfolg erlebt. Die anderen Zellen zeigen Garnichts an

=WENN(UND('[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$C$2:$C$23=$F$5;O8='[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$B$2:$B$23);'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$M$2:$M$23;0)

Bedanke mich im Voraus für die Unterstützung.

[Tommiks]

Ich habe es hinbekommen  

Untere Formel gilt für die Zelle F8. 


=WENNFEHLER(INDEX('[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$M$2:$M$23;VERGLEICH($F$5&F8;'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$C$2:$C$23&'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$B$2:$B$23;0));"0")

---

[StefanB]

Hallo,

Code:

{=SVERWEIS($F$5&F8;WAHL({1.2};'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$C$2:$C$23&'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$B$2:$B$23;'[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$M$2:$M$23);2;0)}

in Zelle F14 eingeben. Wichtig, weil Matrixformel, mit Strg+Shift+Enter bestätigen.

[Tommiks]

Vielen Dank für die Formel, ich habe in meiner Excel Tabelle festgestellt ,dass zum Beispiel 01.09.2021 fünf Mal vorhanden ist, und jede Position hat eine andere Kosten. Wie kann man sie addieren, und ausgeben?

[StefanB]

Code:

{=SVERWEIS(E1&F1&G1;WAHL({1.2.3};A:A&B:B&C:C;D:D);2;0)}

Das ist mal ein Beispiel.
E1 = P- 01 --> zu suchen in Spalte A
F1 = 01.09.2021 --> zu suchen in Spalte B
G1 = Müller --> zu suchen in Spalte C

und das was dann ausgegeben werden soll findest du dann in Spalte D. Die 0 steht für exate Übereinstimmung.

[Tommiks]

@StefanB,

was ist ,wenn 01.09.2021 in der Spalte 5 oder 7-8 Mal vorhanden ist, wie erstelle ich die Summe?

Ich habe es mit SUMMENPRODUKT probiert, aber kein Erfolg gehabt.

[steve1da]

Hola,

@stefanB: man sollte solche Formeln nicht über ganze Spalten laufen lassen. Das könnte auf die Performance gehen.

Für die Summierung:

Code:

=SUMMENPRODUKT(('[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$C$2:$C$23=$F$5)*('[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$B$2:$B$23=F$8)*('[SAP Fehlerkostenliste.xlsx]SAP-Auszug'!$M$2:$M$23))

Gruß,
steve1da

[StefanB]

Hola,

@stefanB: man sollte solche Formeln nicht über ganze Spalten laufen lassen. Das könnte auf die Performance gehen.

Stimmt. 

[Tommiks]

@steve1da,

deine Formel kommunuziert in der original-Datei nicht. Ich habe es jedenfalls nicht hinbekommen. Die original Datei SAP Fehlerkostenliste habe ich hier unten hinzugefügt.

Ich würde mich sehr freuen, wenn Du mir dabei helfen könntest.

Vielen Dank Euch beiden @StefanB & steve1da

[steve1da]

Hola,

zum Einen ist das keine Matrixformel.
Zum Anderen sind die Werte in der SAP Liste Spalte C TEXT, der Wert in C5 ist eine ZAHL.
Gleiche das an und die Formel funktioniert.
Gruß,
steve1da