Wennfehler Index Funktion

[Klexx]

Schönen guten Morgen zusammen!

Ich habe hier ein Problem und bin, um ehrlich zu sein, völlig ratlos.

Über ein paar Umwege bin ich zu der folgenden Formel im Internet gelangt.

{=WENNFEHLER(INDEX('Abteilung A'!A$2:A$50;
KGRÖSSTE(('Abteilung A'!$F$2:$F$50=$B$2)*(ZEILE('Abteilung A'!$F$2:$F$50)-1);
ZÄHLENWENN('Abteilung A'!$F$2:$F$50;$B$2)+1-ZEILE(A1)));"Fehler")}

Und es passt auch soweit alles. Er zeigt mir hier die richtigen Werte aus Abteilung A an.
Das Ganze wird dann noch von A2:A50 auf W2:W50 und auf etwa 10 Zeilen erweitert. Passt alles!

Jetzt habe ich diese Formel genommen, in dem selben Tabellenblatt 20 Zeilen weiter unten eingefügt und anstatt 'Abteilung A' nun die 'Abteilung B' und die etwas veränderten Zeilen eingegeben.
Das Problem ist, er spuckt mir jetzt entweder einen falschen Wert aus, oder wie in den meisten Fällen "Fehler".

Es ist so, die Abfrage F2:F50=B2 bezieht sich auf die Zahl "40" in B2. Bei Abteilung B gibt er mir aber ein Ergebnis mit der Zahl 43 wieder. (Oder wie gesagt "Fehler")

Hat von euch hier jemand eine Idee woran das liegen könnte?
Ich habe das Ganze nochmal in einem neuen Blatt gemacht, aber ohne Erfolg. Und auch die Formate der Tabellenblätter Abteilung A und B hab ich kontrolliert. Diese sind identisch.

Ich wäre demjenigen echt dankbar, der mir hier helfen kann!

Grüße,

Alex

[steve1da]

Hola,

und die etwas veränderten Zeilen eingegeben.

die da wären?

Kannst du das anhand einer Beispieldatei zeigen?

Gruß,
steve1da

[Klexx]

Eine Beispieldatei muss ich erst etwas abspecken, das kann kurz dauern.

Hier schon mal die Formel in der "veränderten" Form:

{=WENNFEHLER(INDEX('Abteilung B'!A$63:A$181;
KGRÖSSTE(('Abteilung B'!$F$63:$F$181=$B$2)*(ZEILE('Abteilung B'!$F$63:$F$181)-1);
ZÄHLENWENN('Abteilung B'!$F$63:$F$181;$B$2)+1-ZEILE(A1)));"")}

[BoskoBiati]

Hallo,

Du hast das ZEILE('Abteilung B'!$F$63:$F$181 nicht zurückgesetzt. Außerdem könnte man die Formel (ab Office 2010) in eine Aggregat-Formel umwandeln!

Richtig wäre wohl eher das:

Code:

=WENNFEHLER(INDEX('Abteilung B'!A:A;
KGRÖSSTE(('Abteilung B'!$F$63:$F$181=$B$2)*(ZEILE('Abteilung B'!$F$63:$F$181));
ZÄHLENWENN('Abteilung B'!$F$63:$F$181;$B$2)+1-ZEILE(A1)));"")

[Klexx]

Deine Formel hat jetzt bei Abteilung B funktioniert - super! Vielen Dank!

Ich versteh nur nicht ganz was du unter "ZEILE(...) nicht zurückgesetzt" verstehst.

Ich muss das Ganze noch für eine weitere Abteilung machen, aber dann passiert mir das Gleiche wie beim ersten mal.

[BoskoBiati]

Hallo,

entweder so wie meine Formel, oder so:

Code:

=WENNFEHLER(INDEX('Abteilung A'!A$2:A$50;
KGRÖSSTE(('Abteilung A'!$F$2:$F$50=$B$2)*ZEILE('Abteilung A'!$A$1:$A$50);
ZÄHLENWENN('Abteilung A'!$F$2:$F$50;$B$2)+1-ZEILE(A1)));"Fehler")

 
wobei dieser Teil

Code:

ZEILE('Abteilung A'!$A$1:$A$50)

in jeder Formel genau so stehen bleiben muß!

[lupo1]

Ich würde eher vermuten, dass da jetzt falsch ZEILE(A21) statt ZEILE(A1) steht.

[Klexx]

Ich bin jetzt bei deiner Formel geblieben. Funktioniert jetzt bei allen Abteilungen, ich sag nochmal danke!

[Nyanah]

Hallo!

Habe ein auch ein Problem mit der besagten Formel und zwar werden genau die richtige Anzahl Ergebnisse angezeigt allerdings eine Zeile nach oben verrutscht.

Das heißt ich habe immer ein falsches Ergebnis mit drin.

Code:

=WENNFEHLER(INDEX('L2A ein'!$M:$M;KGRÖSSTE(('L2A ein'!$I:$I=$G$1)*(ZEILE('L2A ein'!$I:$I)-1);ZÄHLENWENN('L2A ein'!$I:$I;$G$1)+1-ZEILE(A1)));"")

So sieht meine Formel aus. 
Ergebnisse werden ab A3;B3;C3 in separater Tabelle angezeigt


Über Hilfe wäre ich sehr dankbar :)

[steve1da]

Hola,

hast du mal versucht die -1 aus der Formel raus zu nehmen?

Gruß,
steve1da