Wert aus Tabelle in andere Tabelle übernehmen

[Stogi]

Hallo,

ich habe ein "kleines" Problem was die Übernahme von Werten aus einer in eine andere Tabelle betrifft.
Vielleicht erst mal die Situation / Motivation: 

Ich möchte Taktzeiten von den Einzelteilen einer Anlage aufnehmen und immer wieder protokollieren nach Umbau / Wartungen etc. 

Als Beispiel hab ich eine Anlage, die ein Teil mit einem Roboter aufnimmt und zu einer Säge bringt, dann sägt und dann mit einem anderen Roboter wieder entnimmt.
Dann hätte ich mir das ganze in drei Einzelteile definiert.
1. Eintranspost Roboter 
2. Sägen
3. Austransport Roboter

Tabelle dafür sieht so aus und es gibt eine eigene Tabelle für jedes Bauteil, dass an einer Anlage produziert wird.
Tabelle1 im Anhang.

Gleiche Tabelle für anders Bauteil.
Tabelle 2 im Anhang.

Nun habe ich eine zweite Tabelle, in die ich jede neue Messung eintrage. Die soll so aussehen.
Tabelle 3 im Anhang.

Nun zum eigentlichen Problem:
ich möchte, dass die ersten beiden Tabelle automatisch aus den aktuellsten Werten der Messungen der dritten Tabelle bestehen.

Die Bedingung für einen Wert der Taktzeit für den Sägeprozess (Nr. 2) in Tabelle 1 wäre also:
Taktzeit aus Tabelle 3 mit:
- Nr = 2
- Bauteil = 223
- aktuellstem Datum

-> 31s

Ich habe leider absolut keine Idee, wie man sowas umsetzt.
Datei ist im Anhang.
Excel 2007 wird verwendet ... ja wirklich ^^

Danke schon mal und 
liebe Grüße
Stogi

[UweD]

Hallo

Code:

G5: =MAXWENNS(Tabelle3[[Gemessen am ]];Tabelle3[Nr.];[@[Nr.]];Tabelle3[Bauteil];[@Bauteil])

F5: =WENNFEHLER(INDEX(Tabelle3[Taktzeit '[s']];VERGLEICH([@[Nr.]]&"|"&[@Bauteil]&"|"&[@[Gemessen am]];Tabelle3[Nr.]&"|"&Tabelle3[Bauteil]&"|"&Tabelle3[[Gemessen am ]];0));"--")

H5: =WENNFEHLER(INDEX(Tabelle3[Gemessen weil];VERGLEICH([@[Nr.]]&"|"&[@Bauteil]&"|"&[@[Gemessen am]];Tabelle3[Nr.]&"|"&Tabelle3[Bauteil]&"|"&Tabelle3[[Gemessen am ]];0));"--")

G5 Formatieren Benutzerdefiniert: TT.MM.JJJJ;;;@ 
Dadurch werden die Nullen ausgeblendet



Analog dann in N5:P5

LG UweD

[neopa]

Hallo Stogi,

lässt mit MAX(), INDEX() und VERWEIS() unter Einbeziehung von WENNFEHLER() auch in Deiner XL-Version ganz ohne spez. Formeleingabeabschluss berechnen.

Zuerst in G5 

Code:

=WENNFEHLER(1/(1/MAX(INDEX(Tabelle3[[Gemessen am ]]*(Tabelle3[Bauteil]=[@Bauteil])*(Tabelle3[Nr.]=[@[Nr.]]);)));"")

Datumsformat zuweisen.

Dann in F5:

Code:

=WENNFEHLER(VERWEIS(9;1/(Tabelle3[Nr.]=[@[Nr.]])/(Tabelle3[Bauteil]=[@Bauteil])/(Tabelle3[[Gemessen am ]]=[@[Gemessen am]]);Tabelle3[Taktzeit '[s']]);"")

und in H5:

Code:

=WENNFEHLER(VERWEIS(9;1/(Tabelle3[Nr.]=[@[Nr.]])/(Tabelle3[Bauteil]=[@Bauteil])/(Tabelle3[[Gemessen am ]]=[@[Gemessen am]]);Tabelle3[Gemessen weil]);"")

Diese 3 Formel analog auch in der rechten Tabelle einsetzen.

[Stogi]

Vielen, vielen Dank ihr beiden! 

Minimal musste ich es ändern,

G5:

=WENNFEHLER(1/(1/MAX(INDEX(Tabelle3[[Gemessen am ]]*(Tabelle3[Bauteil]=Tabelle1[[#Diese Zeile];[Bauteil]])*(Tabelle3[Nr.]=Tabelle1[[#Diese Zeile];[Nr.]]);)));"")

Interessehalber, weiß jemand woran das liegt? Meiner Excel Version?

LG Stogi