Wert ausrechnen von anderem Tabellenblatt

[m.mueller]

Hallo, muss gleich sagen, dass ich bin ein Neuling in Sachen Exel bin. Hoffe dass Ihr mir helfen könnt.

Würde eine Formel brauchen, in der folgendes gerechnet wird.
1. Wenn im Feld "Leistung" -->Beschaffung steht und
2. Land Abs "D" steht und
3. Land Empf "D" steht dann
4. nimm den Wert von Verkettung aus anderem Tabellenblatt und
5. multipliziere den Wert von Verkettung mit Gewicht

Hoffe dass es verständlich ist.. Dies wäre mein Ansatz gewesen, aber funktioniert nicht

=SVERWEIS(WENN(BW3=“Beschaffung“;G3="D";L3="D");(BF3;'Beschaff DE-->DE'!$B$26:$C$125);2;0)*BG3

Danke Euch

[steve1da]

Hola,

ein Bild einer Exceldatei in einem Word Dokument. Pfiffig. Aber nicht hilfreich.

nimm den Wert von Verkettung aus anderem Tabellenblatt und

Welchen genau? Da gibt es bestimmt mehrere die zu unterschiedlichen Bedingungen herangezogen werden sollen.

Lade eine aussagekräftige Exceldatei hoch als xlsx.

Gruß,
steve1da

[m.mueller]

Peinlich :33: :33:

Habe jetzt mal eine neue Exel erstellt mit anderen Zahlen...

Wichtig wäre, wenn das Gewicht bei Kategorie (min.+ max. Kosten) ist, dann muss dieser Wert übernommen werden und soll nicht multipliziert werden.

Hoffe ich habe jetzt alles richtig gemacht

[Rabe]

Hi,
versuche mal diese Formel:
=WENN(UND(E2="Beschaffung";A2="D";B2="D");SVERWEIS(BF3;Verkettung!C17:D66;2;0)*D2;"")

[shift-del]

Moin

Ich habe es dann mal extra kompliziert gemacht.

[m.mueller]

Mit dieser Formel sind drei Ergebnisse richtig und zwei Ergebnisse falsch. Hat was mit min. Festpreis und Max Festpreis zu tun...

Wo liegt der Fehler? siehe Anhang

=WENN(UND(E2="Beschaffung";A2="D";B2="D");SVERWEIS(C2;Verkettung!C17:D66;2;0)*D2;"")

@shift-del
mit deiner Formel bin ich nicht klar gekommen

@[b]Rabe[/b]
deine Formel hat anscheinend noch einen kleinen Fehler

Danke Euch

[Rabe]

Hi,

dann teste mal diese Formel:
=WENN(UND([@Leistung]="Beschaffung";[@[Land Abs]]="D";[@[Land Empf]]="D");WENN(ODER([@Gewichtsrubrik]=1;[@Gewichtsrubrik]=5);SVERWEIS([@Verkettung];Verkettung!C17:D66;2;0);SVERWEIS([@Verkettung];Verkettung!C17:D66;2;0)*D2);"N.A.")

mMn müßte es passen.

Arbeitsblatt mit dem Namen 'Kontrolle'
	A	B	C	D	E	F	G	H	I	J	K
1	Land Abs	Land Empf	Verkettung	Gewicht in kg	Leistung	PLZ 1 stellig	Gewichtsrubrik	shift_del	Rabe alt	Rabe neu	richtiger Wert sollte sein
2	D	D	DE8-1	50	Beschaffung	8	1	900,00	900,00	18,00
3	D	D	DE9-2	190	Beschaffung	9	2	39,90	39,90	39,90
4	H	D	DE7-3	280	Beschaffung	7	3	0,00	N.A.	N.A.
5	H	D	DE1-4	400	Beschaffung	1	4	0,00	N.A.	N.A.
6	A	D	DE6-5	700	Beschaffung	6	5	0,00	N.A.	N.A.
7	D	D	DE8-1	50	Beschaffung	8	1	900,00	900,00	18,00	18
8	D	D	DE9-2	300	Beschaffung	9	2	63,00	63,00	63,00	63
9	D	D	DE7-3	280	Beschaffung	7	3	53,20	53,20	53,20	53,2
10	D	D	DE1-4	400	Beschaffung	1	4	52,00	52,00	52,00	52
11	D	D	DE6-5	700	Beschaffung	6	5	49.000,00	49.000,00	70,00	70

Zelle	Formel
C2	=VERKETTEN("DE";[@[PLZ 1 stellig]];"-";[@Gewichtsrubrik])
H2	=UND([@Leistung]="Beschaffung";[@[Land Abs]]="D";[@[Land Empf]]="D")*FILTER(tbl_Werte[Wert];(tbl_Werte[PLZ-Region]=[@[PLZ 1 stellig]])*(tbl_Werte[Gewichtsrubrik]=[@Gewichtsrubrik]))*D2
I2	=WENN(UND([@Leistung]="Beschaffung";[@[Land Abs]]="D";[@[Land Empf]]="D");SVERWEIS([@Verkettung];Verkettung!C17:D66;2;0)*D2;"N.A.")
J2	=WENN(UND([@Leistung]="Beschaffung";[@[Land Abs]]="D";[@[Land Empf]]="D");WENN(ODER([@Gewichtsrubrik]=1;[@Gewichtsrubrik]=5);SVERWEIS([@Verkettung];Verkettung!C17:D66;2;0);SVERWEIS([@Verkettung];Verkettung!C17:D66;2;0)*D2);"N.A.")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

  Versandkosten Rabe.xlsx (Größe: 20,33 KB / Downloads: 1)