Wert in mehreren Listen finden -> Listennamen ausgeben

[Rhak]

Hallo zusammen,

um mein Problem darzustellen fange ich mal ganz von vorne an: 

Zunächst habe ich eine Liste von Produktverkäufen mit dem jeweiligen Standort, an dem das Produkt verkauft wurde.

Tabelle1

	A	B	C
1	Produkte	Standorte
2	Produkt A	Standort A
3	Produkt C	Standort A
4	Produkt G	Standort A
5	Produkt A	Standort A
6	Produkt B	Standort B
7	Produkt B	Standort B
8	Produkt H	Standort B
9	Produkt A	Standort B
10

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Auf einem zweiten Tabellenblatt habe ich alle Produktgruppen aufgelistet, in denen jedes Produkt genau einmal vorkommt.

Tabelle2

	A	B	C	D
1	Produktgruppe 1	Produktgruppe 2	Produktgruppe 3
2	Produkt A	Produkt C	Produkt G
3	Produkt B	Produkt D	Produkt H
4		Produkt E	Produkt I
5		Produkt F
6

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Auf einem weiteren Tabellenblatt liste ich Verkäufe für einen bestimmten Standort auf, also wieder eine Liste, in der Produkte (je nachdem wie oft sie verkauft wurden) öfter vorkommen können. Hier möchte ich nun im Bereich B4:B1000 (das dürfte reichen) die Produktgruppen für die jeweiligen Produkte angezeigt bekommen. 

Tabelle3

	A	B	C
1	Verkäufe für
2	Standort A
3	Produkte	Produktgruppen
4	Produkt A
5	Produkt C
6	Produkt G
7

Formeln der Tabelle

Zelle Formel A4 {=WENNFEHLER(INDEX(Tabelle1!$A$2:$A$10000;KKLEINSTE(WENN(Tabelle1!$B$2:$B$10000=A$2;WENN(ZÄHLENWENN($A$2:A2;Tabelle1!$A$2:$A$10000)=0;ZEILE(Tabelle1!$A$2:$A$10000)-ZEILE(Tabelle1!$A$2)+1));1));"")} A5 {=WENNFEHLER(INDEX(Tabelle1!$A$2:$A$10000;KKLEINSTE(WENN(Tabelle1!$B$2:$B$10000=A$2;WENN(ZÄHLENWENN($A$2:A4;Tabelle1!$A$2:$A$10000)=0;ZEILE(Tabelle1!$A$2:$A$10000)-ZEILE(Tabelle1!$A$2)+1));1));"")} A6 {=WENNFEHLER(INDEX(Tabelle1!$A$2:$A$10000;KKLEINSTE(WENN(Tabelle1!$B$2:$B$10000=A$2;WENN(ZÄHLENWENN($A$2:A5;Tabelle1!$A$2:$A$10000)=0;ZEILE(Tabelle1!$A$2:$A$10000)-ZEILE(Tabelle1!$A$2)+1));1));"")} A7 {=WENNFEHLER(INDEX(Tabelle1!$A$2:$A$10000;KKLEINSTE(WENN(Tabelle1!$B$2:$B$10000=A$2;WENN(ZÄHLENWENN($A$2:A6;Tabelle1!$A$2:$A$10000)=0;ZEILE(Tabelle1!$A$2:$A$10000)-ZEILE(Tabelle1!$A$2)+1));1));"")}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8



Hat da jemand eine Idee für mich was in B4 und folgende rein muss? Über jedwede Hilfe wäre ich sehr dankbar! :)


Beste Grüße
Rhak

[Klaus-Dieter]

Hallo,

wie gefällt dir dieser Lösungsvorschlag?: (Formel aus E2 nach Rechts und Unten ziehen)

Tabelle1

	D	E	F	G	H	I	J	K	L
1		Produkt A	Produkt B	Produkt C	Produkt D	Produkt E	Produkt F	Produkt G	Produkt H
2	Standort A	2		1				1
3	Standort B	1	2						1

Formeln der Tabelle

Zelle Formel E2 =SUMMENPRODUKT(($A$2:$A$9=E$1)*($B$2:$B$9=$D2))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Rhak]

Hallo,

wie gefällt dir dieser Lösungsvorschlag?: (Formel aus E2 nach Rechts und Unten ziehen)

Danke für die fixe Antwort! 

Wenn ich dich richtig verstehe, dann könnte ich die Produktgruppen in deinem Beispiel über die Artikel setzen. Problem ist nur, dass regelmäßig Produkte zu den Produktgruppen hinzugefügt werden. Wenn das passiert, müsste ich ständig neue Spalten einfügen. Das funktioniert zwar (und zur Not mache ich es so), noch schöner wäre es natürlich wenn ich meine Tabelle mit Produktgruppen weiter führen kann und diese dann dynamisch in der Liste von Verkäufen ergänzt werden.

[BoskoBiati]

Hi,

Tabelle 2 in eine vernünftige Form bringen:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B
1	Produkt	Produktgruppe
2	Produkt A	Produktgruppe 1
3	Produkt B	Produktgruppe 1
4	Produkt C	Produktgruppe 2
5	Produkt D	Produktgruppe 2
6	Produkt E	Produktgruppe 2
7	Produkt F	Produktgruppe 2
8	Produkt G	Produktgruppe 3
9	Produkt H	Produktgruppe 3
10	Produkt I	Produktgruppe 3

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Dann geht die Auswertung ganz einfach:

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B
1	Verkäufe für
2	Standort A
3	Produkte	Produktgruppen
4	Produkt A	Produktgruppe 1
5	Produkt C	Produktgruppe 2
6	Produkt G	Produktgruppe 3

Zelle	Formel
A4	=WENNFEHLER(INDEX(Tabelle1!$A:$A;AGGREGAT(15;6;ZEILE($A$1:$A$1000)/(Tabelle1!$B$1:$B$1000=$A$2);ZEILE(A1)));"")
B4	=WENN(A4="";"";WENNFEHLER(SVERWEIS(A4;Tabelle2!$A:$B;2;0);""))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Rhak]

Das funktioniert wunderbar, besten Dank! :D

[Schachspieler]

Hallo Rhak,

für mich schreit das Ganze nach einer Pivottabelle - wenn du in Tabelle1 noch die Produktgruppe in SpalteC schreiben würdest (notfalls per SVerweis) hast du alle Infos auf einem Blatt und kannst viel mehr Aussagen treffen (Bereichsfilter=Standort)

[Jockel]

Hallo, wie ich finde: eine schöne kleine Übung für PQ (klein und unbeholfen, aber jeder fängt mal klein an...)

Ohne Formeln und erweiterbar... langsam fängt's an Spaß zu machen... eine etwaige automatische Aktualisierung geht bestimmt (per Makro) auch noch...



  PQ_Übung_1.xlsx (Größe: 28,53 KB / Downloads: 0)