Werte aus Tabelle1 gruppiert in Tabelle2

[omron2003]

Hallo Forum,

ich suche eine Möglichkeit Werte aus Tabelle1 (stehen dort zum Artikel untereinander)
in Tabelle2 pro Artikel nebeneinander darzustellen, siehe Beispielmappe im Anhang.


Besten Dank im Voraus
omron2003

[Oldiefan]

Hallo Omron!

Ich habe dein Problem über eine Hilfsspalte und dann mit der Index-Vergleich-Variante des SVerweises gelöst.

In der Hilfsspalte (Tabelle1) steht folgende Formel: =A3&"-"&ZÄHLENWENN($A$3:A3;A3)
Tabelle2 Spalte A bekommt folgende Matrix-Formel, die die Einträge auflistet: {=WENN(ZEILE(A1)>SUMME(WENN(Tabelle1!A$1:A$99="";0;1/(ZÄHLENWENN(Tabelle1!A$1:A$99;Tabelle1!A$1:A$99)));-(ZÄHLENWENN(Tabelle1!A$1:A$99;Tabelle1!A$1:A$99)=1)*1);"";INDIREKT("Tabelle1!A"&KKLEINSTE(WENN((ZÄHLENWENN(INDIREKT("Tabelle1!A1:A"&ZEILE($1:$99));Tabelle1!A$1:A$99)=1)*(ZÄHLENWENN(Tabelle1!A$1:A$99;Tabelle1!A$1:A$99)>1);ZEILE($1:$99));ZEILE(A1))))}

Die einzelnen Einträge bekommst du mit der Index-Variante, den ersten Bezug musst du anpassen und kannst dann blockweise kopieren: =WENNFEHLER(INDEX(Tabelle1!$B:$B;VERGLEICH($A2&"-"&RECHTS(B$1;1);Tabelle1!$E:$E;0));"")

Liebe Grüße
Alex

[Fred11]

...oder so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Tabelle1 Ist
2	Arti	Komponente	Pos.	Menge
3	AB0001	ABC	10	10
4	AB0001	DEF	20	15
5	AB0001	GHI	30	33
6	AB0001	JKL	40	47
7	BC0003	KHF	10	12
8	BC0003	ABC	20	54
9	DR0005	RES	10	65
10	DR0005	GHI	30	87
11	DR0005	FTE	40	41
12	DR0005	DEF	30	36
13
14
15
16
17	Tabelle2 SOLL
18	Arti	Komonente1	Pos1	Menge1	Komonente2	Pos2	Menge2	Komonente3	Pos3	Menge3	Komonente4	Pos4	Menge4
19	AB0001	ABC	10	10	DEF	20	15	GHI	30	33	JKL	40	47
20	BC0003	KHF	10	12	ABC	20	54
21	DR0005	RES	10	65	GHI	30	87	FTE	40	41	DEF	30	36

Zelle	Formel
A19	=WENNFEHLER(INDEX(Tabelle1!$A$3:$A$12;AGGREGAT(15;6;ZEILE(Tabelle1!$A$3:$A$12)/(VERGLEICH(Tabelle1!$A$3:$A$12;Tabelle1!$A$3:$A$12;0)=ZEILE(Tabelle1!$A$3:$A$12)-2)-2;ZEILE(A1)));"")
B19	=WENNFEHLER(INDEX(Tabelle1!$B$3:$D$12;AGGREGAT(15;6;ZEILE(Tabelle1!$A$3:$A$12)/(Tabelle1!$A$3:$A$12=$A19)-2;GANZZAHL((SPALTE()-2)/3)+1);REST(SPALTE()-2;3)+1);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß
Fred