Werte automatisch aufgrund von Quell-Tabelle einfügen

[StellarMonkey]

Hallo Zusammen,

das ist mein erster Beitrag hier im Forum, aber ich bin mir sicher ihr könnt mir weiterhelfen.

Ich bin unter Anderem für den Einkauf bei mir auf der Arbeit zuständig und habe hier eine Bestell-Liste in Excelform, die ich schon länger verwende. Ich möchte diese für nächstes Jahr etwas optimieren, damit ich nicht mehr so viele Daten händisch eingeben muss.
Ich habe euch mal eine sehr stark vereinfachte Beispiel-Datei angehängt, mit der meine Frage aber klar werden sollte.

Wir haben mehrere Außenstellen, die ihr eigenes Budget verwalten. Allerdings werden nicht alle Beschaffungen, die für eine bestimmte Außenstelle bestellt werden auch über das eigene Budget beschafft. Manchmal werden Beschaffungen über ein allgemeines Budget finanziert. Beschaffungen für die Hauptstelle werden immer über das allgemeine Budget finanziert.

Folgende Tabellenspalten sollen automatisch ausgefüllt werden:

Kostenstelle (Spalte F)

• Die Kostenstelle soll immer fest dem Empfänger zugeordnet werden.
  
• Hier muss also geprüft werden, was in der Spalte "Empfänger" im Tabellenblatt "Bestell-Liste" steht und mit der Spalte "Empfänger" im Tabellenblatt "Datenquelle" verglichen werden und der Wert, der in der        Spalte "Kostenstelle" in "Datenquelle" steht, eingefügt werden. 
  

Kostenträger (Spalte G)

• Der Kostenträger soll je nachdem wer die Beschaffung finanziert zugeordnet werden. Wenn es über das eigene Budget finanziert wird, soll der Kostenträger, der der Außenstellt zugewiesen ist eingetragen werden. Wenn es über das allgemeine Budget finanziert wird, soll der Kostenträger der Hauptstelle zugewiesen werden.
  
• Hier muss also einmal wie bei der Kostenstelle der Empfänger geprüft werden, aber zusätzlich noch die Spalte "Finanzierung über" und aus diesem Zusammenspiel der entsprechende Wert eingetragen werden. 
  

---

Im Beispiel sollten also die folgenden Werte automatisch eingetragen werden:

Für BestellNr. 22120001:
Kostenstelle - 0001
Kostenträger - 2200

Für BestellNr. 22120002:
Kostenstelle - 0003
Kostenträger - 2120

Für BestellNr. 22120003:
Kostenstelle - 1000
Kostenträger - 2200

Für BestellNr. 22120004:
Kostenstelle - 0005
Kostenträger - 2130

---

In meiner Beispiel-Datei habe ich folgende Arbeitsblätter:

Bestell-Liste - die Liste an sich
Datenquelle - Tabelle mit Zuweisung Empfänger - Kostenstelle - Kostenträger
Dropdowns - Auswahlmöglichkeiten für die Spalten "Empfänger" und "Finanzierung über" in der Bestell-Liste

Wahrscheinlich ist das Ganze total simpel, aber ich komme einfach nicht drauf, welche Funktion ich hierfür verwenden kann. Wenn mich jemand in die richtige Richtung schubsen könnte, wäre mir schon sehr geholfen.
Verwendet wird übrigens Excel 2016.

Danke schonmal

[Warkings]

Das sieht nach SVERWEIS und WENN aus.

[StellarMonkey]

Hallo Warkings,

edit: Während des Schreibens bin ich auf die richtigen Formeln gekommen. Ich lasse meinen Text trotzdem mal so stehen, damit man meinen Gedankengang nachvollziehen kann. 
Die finalen Formeln stehen ganz unten und sind fett gedruckt.

an die WENN Funktion habe ich auch schon gedacht, aber ich komme leider nicht drauf, wie ich die Datenquelle in die WENN Funktion integriere.
Ich könnte bei der Beispieldatei für die Kostenstelle theoretisch folgende Funktion verwenden:

=WENN([@Empfänger]="Außenstelle 1";"0001";WENN([@Empfänger]="Außenstelle 2";"0002";WENN([@Empfänger]="Außenstelle ";"0003";WENN([@Empfänger]="Außenstelle 4";"0004";WENN([@Empfänger]="Außenstelle 5";"0005";WENN([@Empfänger]="Hauptstelle";"1000";"error"))

Das wäre bei der Beispieldatei vielleicht noch vertretbar, aber bei meiner tatsächlichen Datei hätte ich 45 Kostenstellen und 12 Kostenträger.

Ich habe das automatische Einfügen für die Kostenstelle jetzt aber über den SVERWEIS lösen können. Danke für den Tipp.

---

Falls jemand eine Lösung für ein ähnliches Beispiel sucht - hier die Formel, die ich für die Kostenstelle verwende:

=SVERWEIS([@Empfänger];Tabelle4;2;FALSCH)

Das Suchkriterium ist ja der Wert, der in "Empfänger" eingetragen ist. Die Matrix ist die komplette Tabelle im Blatt "Datenquelle". Der Spaltenindex ist "2", weil es die zweite Spalte in der angegebenen Matrix ist. Und "FALSCH" weil es eine genaue Übereinstimmung sein soll.

---

Beim Kostenträger habe ich mir etwas schwerer getan, aber es dann doch noch hinbekommen, während ich hier antworte... 

Hier die Formel:

=WENN([@[Finanzierung über]]="allgemeines Budget";Datenquelle!$D$8;WENN([@[Finanzierung über]]="eigenes Budget";SVERWEIS([@Empfänger];Tabelle4;3;FALSCH)))

Also wenn in der Spalte "Finanzierung über" "allgemeines Budget" eingetragen ist, dann holt sich Excel den Wert aus Zelle D8 im Blatt "Datenquelle". Wenn "eigenes Budget" in der Zelle steht, dann wird eine SVERWEIS wie bei der Kostenstelle gemacht, nur mit dem Spaltenindex 3.

---

Jetzt habe ich noch den Schönheitsfehler bereinigt, dass in den Zellen, die kein Ergebnis zurückgegeben werden, kein Eintrag gemacht wird. Mit den obigen Formeln hatte ich in der Spalte "Kostenstelle" bei Zellen ohne Ergebnis "#NV" stehen und beim Kostenträger "FALSCH".

Hier die angepassten Formeln um die Zellen leer zu lassen:

Kostenstelle:
=WENN([@Empfänger]="";"";SVERWEIS([@Empfänger];Tabelle4;2;FALSCH))

Kostenträger:
=WENN([@[Finanzierung über]]="";"";WENN([@[Finanzierung über]]="allgemeines Budget";Datenquelle!$D$8;WENN([@[Finanzierung über]]="eigenes Budget";SVERWEIS([@Empfänger];Tabelle4;3;FALSCH))))

Ich hänge die Datei noch einmal mit den Formeln an. Vielleicht hilft es jemandem weiter. 


Der kleine Schubs hat wirklich geholfen. Danke 

[HKindler]

Hi,

eigentlich müsste für den Kostenträger doch folgendes reichen:

=WENN([@[Finanzierung über]]="";"";WENN([@[Finanzierung über]]="allgemeines Budget";Datenquelle!$D$8;SVERWEIS([@Empfänger];Tabelle4;3;FALSCH))))

Damit landet alles, was nicht "allgemeines Budget" ist automatisch bei "eigenes Budget".

[StellarMonkey]

Stimmt. Das sollte im Beispiel ausreichend sein.

Ich hab bei meiner tatsächlichen Liste ein paar mehr Kostenträger. Und teilweise werden verschieden finanzierte Bestellungen über denselben Kostenträger abgebildet, bei manchen greift dann aber eine Förderung und wir bekommen Beträge wieder gutgeschrieben, daher bestimmt "Finanzierung über" nicht nur, welcher Kostenträger eingetragen wird, sondern auch andere Sachen wie z.B. mein Tabellenblatt in dem ich die Budgets tracke.
Da ist das Ganze etwas verschachtelter. Da könnte ich aber sicherlich auch noch etwas optimieren.

Aber ja - für das Beispiel hast du definitiv recht.

LG