Werte innerhalb einer Zelle ermitteln

[sdraxler]

Hallo,
ich habe Zellen in denen Zeichenketten wie nachfolgend dargestellet enthalten sind:

A1: 01001100
A2: 10011100
A3: 00011011

Ich möchte für jede Zelle ermitteln an welcher Stelle die erste und die letzte 1 stehen. Bei Zelle A1 sind das die Stellen 2 und 6, Bei Zelle A2 sind das die Stellen 1 und 6

Gibt es eine Möglichkeit diese Stellen zu ermitteln?

LG
Stuart

[Fennek]

Hallo,

die gezeigten Werte sehen aus wie Binär-Zahlen. Excel kann sie direkt in Dezimal umrechen. Danach kann dann auf ">127", "ungerade" usw geprüft werden.

mfg

(es geht auch direkt mit VBA.Instr(1, cells(1,1), "1"))

[sdraxler]

Die Zahlen sehen aus wie Binärzahlen. Die Zeichenkette zeigt eigentlich Monate an. Jede Stelle steht für 1 monat. D.h. wenn an zweiter Stelle eine 1 steht, dann gab es im zweiten Monat eine Bestellung. Das nur zum Hintergrund.

Gibt es auch eine Lösung ohne VBA?

[Warkings]

Code:

=FIND(1;A1;1)

und

=FIND("@";SUBSTITUTE(A1;"1";"@";LEN(A1)-LEN(SUBSTITUTE(A1;"1";"")));1)

https://trumpexcel.com/find-characters-last-position/

[shift-del]

Moin

Code:

=AGGREGAT(15;6;1/(1/(TEIL(A1;SEQUENZ(LÄNGE(A1));1)*SEQUENZ(LÄNGE(A1))));1)
=AGGREGAT(14;6;1/(1/(TEIL(A1;SEQUENZ(LÄNGE(A1));1)*SEQUENZ(LÄNGE(A1))));1)

[LCohen]

=VERGLEICH(1;--TEIL(A1;ZEILE($1:$8);1);)
=VERGLEICH(1;--TEIL(A1;ZEILE($1:$8);1))

für ältere Excel (dann wohl mit {} abzuschließen)

[sdraxler]

Danke. Funktioniert super!!!