Wochentage aus Anfangsdatum und Enddatum ausgeben

[Dirk O.]

Hallo liebe Excelgemeinde,
könnt ihr mir bei meinem Vorhaben behilflich sein?
Die Wochentage, vom Anfangsdatum (E4:E8) bis zum Enddatum (G4:G8), sollen in die passende Spalte (Mo - So) eingetragen werden.
Gibt es dafür eine Lösung? Wäre euch sehr dankbar!
Hoffe, dass die beigefügte Tabelle zum besseren Verständnis beiträgt.
Im Voraus vielen Dank und ein schönes Wochenende.
Viele Grüße Dirk

[Gastlich]

Hallo,

PHP-Code:

=WENN(TEXT($E4;"TTT")=J$3;$E4;WENN(TEXT($G4;"TTT")=J$3;$G4;"")) 


[Dirk O.]

Danke für die schnelle Antwort! 
Können wir die Formel noch so umstellen, dass die dazwischen liegenden Tage auch mit angezeigt werden?
Viele Grüße Dirk

[Gastlich]

Hallo,

die Formatierung kann in der Funktion TEXT() geändert werden.

PHP-Code:

=WENN(TEXT($E4;"TTT")=J$3;TEXT($E4;"TT.MM")&" "&"Tage "&$I4;WENN(TEXT($G4;"TTT")=J$3;TEXT($G4;"TT.MM")&" "&"Tage "&$I4;"")) 


[Dirk O.]

Du hast mich, glaube ich, falsch verstanden.

Beispiel:

Anfangsdatum = 05.12.22      Enddatum = 10.12.22

Angezeigt werden soll:

Spalte Mo = 05.12.
Spalte Di = 06.12.
Spalte Mi = 07.12.
Spalte Do = 08.12.
Spalte Fr = 09.12.
Spalte Sa = 10.12.

Siehe auch Mustertabelle!

Nochmals vielen Dank für deine Unterstützung!

Gruß Dirk

[HKindler]

Hi,

J4: =WENN((SPALTE(A:A)>=WOCHENTAG($E4;2))*(SPALTE(A:A)<=WOCHENTAG($G4;2));$E4-WOCHENTAG($E4;2)+SPALTE(A:A);"")
nach rechts und runter ziehen

bei neuem Excel geht auch
J4: =LET(x;SEQUENZ(;7;0);y;E4;a;WOCHENTAG(y;3);e;WOCHENTAG(G4;3);WENN((x>=a)*(x<=e);y-a+x;""))
runter ziehen (nach rechts wird gespillt)


Aber mal so ganz nebenbei: macht deine Darstellung Sinn?
- Was passiert, wenn Anfang und Ende nicht in einer Woche liegen?
- Wie willst du auf einen Blick sehen, ob eine bestimmte Woche belegt ist oder nicht?

[echo]

Hallo zusammen,
eine weitere, recht einfache Möglichkeit wäre es, 
ALLE Daten (Plural Datum) der Woche in die Liste einzufügen und die Anzeige per bedingter Formatierung anzupassen.

Gruß Holger