Wörter vergleichen

[wjeckos]

Hallo Zusammen.

Wie kann ich in excel für zwei Wörter finden wie viel gleiche Buchstaben haben?
z.B. Tag, Nacht = 2 (t,a)
Auftrag, Banane = 2 (a,a)

Danke im Voraus

[LCohen]

C1: =SUMMENPRODUKT(WENN(
LÄNGE(A1)-LÄNGE(WECHSELN(GROSS(A1);ZEICHEN(ZEILE($65:$90));))<
LÄNGE(B1)-LÄNGE(WECHSELN(GROSS(B1);ZEICHEN(ZEILE($65:$90));));
LÄNGE(A1)-LÄNGE(WECHSELN(GROSS(A1);ZEICHEN(ZEILE($65:$90));));
LÄNGE(B1)-LÄNGE(WECHSELN(GROSS(B1);ZEICHEN(ZEILE($65:$90));)))*(((
LÄNGE(A1)-LÄNGE(WECHSELN(GROSS(A1);ZEICHEN(ZEILE($65:$90));)))*(
LÄNGE(B1)-LÄNGE(WECHSELN(GROSS(B1);ZEICHEN(ZEILE($65:$90));))))>0))

äöüß sind nicht dabei; die zählst Du händisch dazu. Als Finne (Mäkärainen) hast Du schlechte Karten, aber dann kann man Dich immer noch am Heck montieren.

[shift-del]

Moin

Für Anwender mit einer aktuellen Excel-Version:

Code:

=SUMME(--ISTZAHL(SUCHEN(TEIL(A1;SEQUENZ(LÄNGE(A1));1);B1)))

=SUMME(ZÄHLENWENNS(B1;"*"&TEIL(A1;SEQUENZ(LÄNGE(A1));1)&"*"))

[LCohen]

A u f t r a g s h a n s e l
B a n a n e n p f l ü c k e r

zeigt bei mir 7, bei Dir jeweils 8 an, shift-del.

[wjeckos]

Danke für Antwort, sequenz Funktion habe ich leider nicht.

LCohen: Deine Funktion funktioniert bei manchen Reihen, bei manchen nicht.
Ich weiss nicht was habe ich falsch gemacht.

[XOR LX]

Hallo,

Array-Formel**:

=SUMME(REST(KKLEINSTE(100*ZEILE($1:$26)+LÄNGE(A1:B1)-LÄNGE(WECHSELN(GROSS(A1:B1);ZEICHEN(ZEILE($65:$90));""));2*(ZEILE($1:$26)-1)+1);100))

Gruß


**STRG+Umschalt+Eingabe

[snb]

UDF:

Code:

Function F_snb(sn)
  sn = sn
  For j = 1 To Len(sn(1, 1))
      n = n - (InStr(1, sn(2, 1), Mid(sn(1, 1), j, 1), 1) > 0)
  Next
  F_snb = n
End Function

PHP-Code:

=F_snb(A1:A2)