ZÄHLENWENNS mit ODER Funktion

[madmaddin]

Hallo zusammen,

ich bin auf der Suche nach einer Lösung, um mehrere unterschiedliche Kombinationsmöglichkeiten zu zählen.

Es müssen dabei mehrere Kriterien in unterschiedlichen Tabellenblättern eingehalten werden.
Um es einfach zu halten, habe ich eine Beispieldatei angefügt.

Zum einen muss nach einer eindeutigen ID gesucht werden, dann muss geschaut werden ob eine der folgenden Kombinationen zutrifft

Die eindeutige ID muss immer übereinstimmen
dann...
Kombination in Spalte B Ja und Spalte C Ja = 1
oder...
Kombination in Spalte B Ja und Spalte C Nein = 1
oder...
Kombination in Spalte B Nein und Spalte C Ja = 1

Sollte die Kombination Nein und Nein in den Spalten B und C auftreten, muss eine 0 gezählt werden.

Habt Ihr eine Idee?
Mit ZÄHLENWENNS / SUMMEWENNS komme ich nicht weiter...

Danke vorab und liebe Grüße

Maddin

[steve1da]

Hola,

wie auch immer du auf 6 bei der 2. Zahl kommst. Mach dir im Blatt "Daten" eine Hilfsspalte, z.B. ab D2:

Code:

=(B2="ja")+(C2="ja")

Dann:

Code:

=ZÄHLENWENNS(daten!$A$2:$A$11;A2;daten!$D$2:$D$11;">0")

Gruß,
steve1da

[WillWissen]

Hi,

meine Lösung anhand deiner Beispielmappe:


  madmaddin-summewenn.xlsx (Größe: 9,52 KB / Downloads: 5)

Die HS einfach ausblenden. Sie kann auch irgendwo bei den 16384 Spalten stehen. :32:

[Luffy]

Hola,

wie auch immer du auf 6 bei der 2. Zahl kommst. Mach dir im Blatt "Daten" eine Hilfsspalte, z.B. ab D2:

Code:

=(B2="ja")+(C2="ja")

Dann:

Code:

=ZÄHLENWENNS(daten!$A$2:$A$11;A2;daten!$D$2:$D$11;">0")

Gruß,
steve1da

Hallo, ich hoffe ich lehne mich nicht zu weit aus dem Fenster aber sollte die Formel in der Hilfsspalte nicht so aussehen?:

Code:

=WENN(UND(B2="Ja";C2="Ja");1;(B2="ja")+(C2="ja"))

Wenn 2x Ja ist soll ja auch nur 1 gezählt werden.

[steve1da]

Hola,

@Luffy: das geht natürlich auch. Ändert aber im Endeffekt nichts, da ich mit der Zählenwenns Formel auf Größer Null abfrage - von daher ist es egal (aber kürzer).

Gruß,
steve1da

[lupo1]

Es heißt doch ZÄHLENWENNS(...;">0"). Daher:

=(B2="ja")+(C2="ja") ergibt das gewünschte inklusive ODER
=(B2="ja")+(C2="ja")=1 ergäbe ein XOR (also ein ODER ohne UND)
=(B2="ja")*(C2="ja") ergäbe ein UND, für welches wir aber keine Hilfsspalte brauchen

[madmaddin]

Hallo zusammen,

gaaaaaanz lieben Dank an Euch alle!

@Steve: Ich hatte mich tatsächlich vertan bei der Angabe der Werte. Sorry dafür!
@WillsWissen: Ich habe Deine Tabelle entsprechend in meine große Liste angepasst und es funktioniert einwandfrei! TOLL!

Viele Grüße

Maddin

[BoskoBiati]

Hallo,

ohne Hilfsspalten:

Arbeitsblatt mit dem Namen 'zusammenfassung'
	A	B	C
1	ID	Frageergebnis
2	12345678	3	3
3	23456789	4	4

Zelle	Formel
B2	=ZÄHLENWENN(daten!A:A;A2)-ZÄHLENWENNS(daten!A:A;A2;daten!B:B;"nein";daten!C:C;"nein")
C2	=SUMMENPRODUKT((daten!A:A=A2)*((daten!B:B="ja")+(daten!C:C="ja")>0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg