Zählen von Text und addieren von Zahlen mit mehreren Kriterien

[steve1da]

Hola,

mach aus deiner Formel in B37:

Code:

=WENNFEHLER(WENN(MONAT($B$34)=MONAT($B$34+3);$B$34+3;0);0)

Die Nullwerte kannst du über die Formatierung ausblenden,

Code:

0;;;@

Für die Sonntage dann:

Code:

=SUMMENPRODUKT((WOCHENTAG(A7:A37;2)>6)*1)*25

Für die anderen Tage:

Code:

=SUMMENPRODUKT((WOCHENTAG(A7:A37;2)<7)*1)*20

Übrigens erzeugt deine Formel im Februar falsche Datumswerte, da kommt der März mit dazu.

Gruß,
steve1da

[Der Steuerfuzzi]

Ist halt manchmal doch besser, die Datei zu zeigen ;)

Mit Summenprodukt:

Code:

=SUMMENPRODUKT((C7:C37="x")*(20+(TEXT($B$7:$B$37;"TTT")="So")*5))

Zählenwenn(s) wird hier aufgrund des Datums nicht umzusetzen sein.

[ExcelAzubi777]

Hey,

Vielen Dank für eure Hilfe !

Durch euch bin ich sehr weiter gekommen und habe sehr viel gelernt.

Das mit dem Februar werd ich versuchen zu ändern  .


Gibt es vielleicht eine Möglichkeit die Feiertage in die Formel einzubauen?

[Der Steuerfuzzi]

Was soll denn an den Feiertagen passieren? Wie beim Sonntag +5?

[ExcelAzubi777]

Ja genau +5      


Danke Steuerfuzzi

[Der Steuerfuzzi]

Mit Feiertagen:

Code:

{=SUMME((C7:C37="x")*(20+WENN($B$7:$B$37="";0;(ARBEITSTAG.INTL($B$7:$B$37-1;1;11;'Feiertage und Monate'!$E$3:$E$13)<>$B$7:$B$37))*5))}

Mtrixformel, bitte mit Strg+Shift+Enter eingeben, die geschweiften Klammern bitte nicht mit eingeben, die fügt Excel automatisch ein!

[ExcelAzubi777]

Danke Michael du bist mein Held