=Zählenwenn(); Suchkriterium= Zeitspanne/Datum

[Felipo95]

Hallo,

ich möchte eine "ZÄHLENWENN" Formel anwenden, in der das Suchkriterium eine Zeitspanne ist (z.B.: 01.01.2015 bis 20.01.2015) nur leider bekomme ich nicht raus wie das funktioniert.

probiert habe ich u.a. z.B. mit:

F1: 01.01.2015 F2: 20.01.2015

=ZÄHLENWENN(Bereich;"F1;F2")

=ZÄHLENWENN(Bereich;"Datum(F1);Datum(F2)")

=ZÄHLENWENN(Bereich;"">="F1;"<="F2")

=ZÄHLENWENN(Bereich;"">="Datum(F1);"<="Datum(F2)")

Funktioniert hat noch nichts aber evtl ist ja schon ein richtiger Ansatz dabei ?

Ich bin mir sicher, ihr könnt mir weiterhelfen ;)

Vielen Dank im Voraus!

MfG Felipo

[shift-del]

Hallo Felipo

nur leider bekomme ich nicht raus wie das funktioniert.

Da kannst du probieren bis zu schwarz wirst. :19:
ZÄHLENWENN() kann nur eine Abfrage verarbeiten.
Deshalb haben die Excel-Programmierer auch ZÄHLENWENNS() erfunden.

[Winny]

Hi

also entweder 

Code:

=ZÄHLENWENNS(Bereich;">=" & F1;Bereich;"<" & F2)

oder

Code:

=ZÄHLENWENN(Bereich;">=" & F1) - ZÄHLENWENN(Bereich;">=" & F2)

[shift-del]

Hallo Winny

Code:

=ZÄHLENWENN(Bereich;">=" & F1) - ZÄHLENWENN(Bereich;">=" & F2)

Guter Trick.

[Felipo95]

Code:

=ZÄHLENWENN(Bereich;">=" & F1) - ZÄHLENWENN(Bereich;">=" & F2)

Hallo Winny,

Danke, diese Funktion hat mir jetzt erstmals Werte ausgegeben anstatt nur "0".
100% nachvollziehen kann ich sie aber nicht und ich bin mir auch nicht sicher ob meine Aufgabe so richtig gelöst ist...
Denn als Summe müsste theoretisch wieder 1000 rauskommen.
Allerdings kommen nur 956 heraus.

Damit ihr wisst um was es geht henge ich mal die betreffende Excel-Datei mit an und markiere die Betreffende fFäche rot.
Gezählt werden soll die Anzahl der verschiedenen Tierkreiszeichen der 1000 Personen.

[Winny]

Etwas mehr Konzentration, bitte!

Code:

=ZÄHLENWENN($C$1:$C$1000;">="&I2)-ZÄHLENWENN($C$1:$C$1000;">"&J2)

[Winny]

und wieso verwendest Du immer noch diese Formel?

Code:

=TEXT(B1;"TT.MM")*1

sie funktioniert nicht für einen 29.02. Das hatten wir doch Letztens erst!

[Felipo95]

Ich danke dir für deine Hilfe Winny !


Die "TEXT()" Formel hab ich nur verwendet, weil in der Aufgabe steht, das man zuerst das Geburtsdatum auf das aktuelle Jahr umrechnen soll.
Den 29.02. habe ich aus der Aufgabe entfernt und zu einem 27.02. gemacht.
Der 29.02. war ja nur in der Aufgabe, weil diese schon etwas älter ist und vom Prof. wohl in einem Schaltjahr geschrieben/erdacht worden war.


Das ist übrigens aber auch nicht die gleiche Aufgabe. 
Die Geburtstage/Wochentage habe ich nur zur Übung in dieser Aufgabe nochmal gemacht.

[WillWissen]

Hi Felix,

Den 29.02. habe ich aus der Aufgabe entfernt und zu einem 27.02. gemacht.

ok, du hast nur Übungsaufgaben. Doch was machst du, wenn du real eine derartige Aufstellung benötigst und tatsächlich Schaltjahrgeburtstagskinder vorhanden sind?

[BoskoBiati]

Hallo,

irgendwie hast Du ein Problem mit der Zählenwenn-Formel, die sowieso nicht ganz stimmt:

v0-1

	H	I	J	K	L	M
1		von	bis	Häufigkeit	Häufigkeit
2	Steinbock	01.01.2015	20.01.2015	60	60	60
3	Wassermann	21.01.2015	19.02.2015	76	76	76
4	Fisch	20.02.2015	20.03.2015	73	73	73
5	Widder	21.03.2015	20.04.2015	91	91	91
6	Stier	21.04.2015	20.05.2015	79	79	79
7	Zwilling	21.05.2015	20.06.2015	92	92	92
8	Krebs	21.06.2015	22.07.2015	102	102	102
9	Löwe	23.07.2015	23.08.2015	89	89	89
10	Jungfrau	24.08.2015	22.09.2015	74	74	74
11	Waage	23.09.2015	22.10.2015	70	70	70
12	Skorpion	23.10.2015	22.11.2015	93	93	93
13	Schütze	23.11.2015	21.12.2015	84	84	84
14	Steinbock	22.12.2015	31.12.2015	17	17	17
15			Summe:	1000	1000	1000

Formeln der Tabelle

Zelle Formel K2 =ZÄHLENWENN($C$1:$C$1000;">="&I2)-ZÄHLENWENN($C$1:$C$1000;">"&J2) L2 =HÄUFIGKEIT($C$1:$C$1000;J2) M2 =SUMMENPRODUKT((DATUM(JAHR($I2);MONAT($B$1:$B$1000);TAG($B$1:$B$1000))>=I2)*(DATUM(JAHR($I2);MONAT($B$1:$B$1000);TAG($B$1:$B$1000))<=J2)) K3 =ZÄHLENWENN($C$1:$C$1000;">="&I3)-ZÄHLENWENN($C$1:$C$1000;">"&J3) L3 =HÄUFIGKEIT($C$1:$C$1000;J3)-SUMME($L$2:L2) M3 =SUMMENPRODUKT((DATUM(JAHR($I3);MONAT($B$1:$B$1000);TAG($B$1:$B$1000))>=I3)*(DATUM(JAHR($I3);MONAT($B$1:$B$1000);TAG($B$1:$B$1000))<=J3))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4