Zählenwenn mit mehreren Daten je Zeile

[Basisa]

Guten Tag,

ich stehe seit gestern Abend etwas auf dem Schlauch.
Daher bitte ich um eine "kleine" Hilfe von euch ;)

Problem:
   

Beschreibung ist eher schwierig, daher ein Beispiel als Datei im Anhang.

Danke wieder einmal im Voraus!!! :-*


  Beispiel.xlsx (Größe: 8,91 KB / Downloads: 11)

[schauan]

Hallöchen,

so?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	x				3
2		x	x
3
4				x
5

Zelle	Formel
E1	=SUMMENPRODUKT(--(ZÄHLENWENN(INDIREKT("A"&ZEILE(1:500)&":D"&ZEILE(1:500));"<>")>0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Basisa]

Geiles Ding, danke...

Nach Anpassung der "exakten" Zeilen:

Code:

=SUMMENPRODUKT(--(ZÄHLENWENN(INDIREKT("A"&ZEILE(A1:D4)&":D"&ZEILE(A1:D4));"<>")>0))

funktioniert es für mich genauso wie es soll....

DANKE :-*

[Ego]

Hallo b...,

ein Beispiel ohne die volatile Funktion Indirekt:

=SUMME(1*((MMULT(1*(A1:D4<>"");ZEILE(A1:A4))>0)))

[Basisa]

Hallöchen,

so?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	x				3
2		x	x
3
4				x
5

Zelle	Formel
E1	=SUMMENPRODUKT(--(ZÄHLENWENN(INDIREKT("A"&ZEILE(1:500)&":D"&ZEILE(1:500));"<>")>0))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

@schauan
Hallo und Danke dir erneut...
Aber eine Nachfrage dazu! Ich habe noch einmal versucht etwas hinzuzufügen was mir aber nicht gelang, da ich ehrlich nicht verstehe wie die funktioniert

Die Formel klappt wie beschrieben sehr gut, nur wie kann man diese Formel ergänzen, damit wenn in einer anderen Zeile ebenfalls ein x steht er diese ebenfalls prüft?
Beispiel mit Erläuterung im Anhang.


  Beispiel_2.xlsx (Größe: 9,03 KB / Downloads: 9)

Wenn du Zeit und Lust hast die Formel kurz zu erläutern wäre ich auch dankbar  :19:
Lerne gerne dazu! Irgendwie muss ich feststellen, dass jeder so seine Lieblingsformeln hat

[Gast 123]

Hallo

ich habe es mit dieser Formel geschafft, sie gibt der Spalte B immer den Vorrang!!
=IF(B3="x";IF(COUNTIF(G3:J3;"x");1;0);0)

Wenn du weitere Spalten prüen willst musst du in der Formel nur den Spalten Bereich aendern!
Die Summe laesst sich mit einer einfachen Summeformel erfassen:    =SUM(M3:M6)

mfg  Gast 123

[Basisa]

Funktioniert leider nur, wenn man eine Hilfsspalte nutzt, was hier aber nicht der Fall sein soll!

[schauan]

Hallöchen,

mit der Formel werden die Zeilen gezählt, wo in meinem Beispiel in A:B un D in der gleichen Zeile ein x steht. 3 käme dann nur raus, wenn in D1, D2 und A4 auch was stünde. Meinst Du das so?

=SUMMENPRODUKT((--(ZÄHLENWENN(INDIREKT("A"&ZEILE(1:500)&":B"&ZEILE(1:500));"<>")>0))*(--(ZÄHLENWENN(INDIREKT("D"&ZEILE(1:500)&":D"&ZEILE(1:500));"<>")>0)))

[Basisa]

Danke... verstehe zwar nicht genau wie es funktioniert. Aber anpassen geht ohne Probleme.

Für mein Beispiel geht es ohne Probleme so:
=SUMMENPRODUKT((--(ZÄHLENWENN(INDIREKT("B"&ZEILE(3:500)&":B"&ZEILE(3:500));"<>")>0)*(--(ZÄHLENWENN(INDIREKT("G"&ZEILE(3:500)&":J"&ZEILE(3:500));"<>")>0))))

Sonst hat er ja die "Überschrift" mitgezählt  :15: 

Danke dir wieder einmal

[Ego]

Hallo,

noch einmal ohne Indirekt und mit weniger zu schreiben:

=SUMMENPRODUKT((B3:B6="x")*(MMULT(1*(G3:J6="x");MTRANS(SPALTE(G3:J3)))>0))