Zahlensuche auf eine Richtung innerhalb einer Spalte beschränken

[Anne Haubrich]

Hallo Leute,
ich habe folgendes Problemchen.  Wenn ich in der Spalte A an einer Stelle, z.B. der Zelladdresse "A10" eine Zahl z.B. 100 stehen habe und ich die Zelleaddresse der nächsten größere Zahl suche, also die 101,  wie mache ich das? Das Problem dabei ist, die Suche soll nur die Addressen von 101 finden, die sich abwärts der Addresse von "A10" befinden und nicht zwischen "A1"  und "A9".

[Ego]

Hallo Anne,

Wenn  in A10 eine ganze Zahl steht ist die Formel für die nächsthöhere ganze Zahl  B10:  = A10+1  


Spass beiseite, eine Formel für B10 könnte sein:

Code:

=WENNFEHLER(AGGREGAT(15;6;$A11:$A$100/($A11:$A$100>$A10);1);"")

Durch den gemischten Bezug $A11 kann die Formel kopiert werden und sucht immer unterhalb.

[BoskoBiati]

Hallo,

das wird schwierig, wenn die Basis-Zahl (hier: 100) mehrfach vorkommt. Auch sonst ist die Formel nicht ganz so einfach, wie Ego es beschrieben hat:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D
1	107	10		100
2	124
3	172
4	101
5	113
6	151
7	121
8	100
9	155
10	102
11	107

Zelle	Formel
B1	=VERGLEICH(AGGREGAT(15;6;INDEX(A:A;VERGLEICH(D1;A:A;0)):A10000/(INDEX(A:A;VERGLEICH(D1;A:A;0)):A10000>D1);1);INDEX(A:A;VERGLEICH(D1;A:A;0)):A10000;0)+VERGLEICH(D1;A:A;0)-1

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Ergebnis ist die Zeile in der der Wert steht.

Wofür braucht man sowas? Zelladressen braucht man häufig in VBA, aber selten bei Formeln!

[Ego]

Hallo Anne,

ich hatte überlesen dass du die Adresse suchst. Bei ganzzahligen Werten hätte ich diese Formel zur Berechnung der Zeile genutzt:

Code:

=WENNFEHLER(REST(AGGREGAT(15;6;1000*($A11:$A$100)/($A11:$A$100>$A10)+ZEILE($A11:$A$100);1);1000);"")

[BoskoBiati]

Hi,

Du hast noch mehr überlesen:

z.B. der Zelladdresse "A10" eine Zahl z.B. 100

[Ego]

Hallo Edgar,

da haben wir unterschiedliche Auffassungen der Aufgabenstellung, aber das kann Anne entscheiden.  Ich habe die Information Zelle A10 genutzt und dadurch kein Problem beim mehrmaligen Auftretet des Wertes in A10.

die sich abwärts der Addresse von "A10" befinden

Nach einem nochmaligen Durchsehen der Fragestellung könnte sie auch bedeuten:

alle Adressen unterhalb von A10 in denen der Wert genau um Eins grösser ist als der Wert in A10.

Dann wäre mein Vorschlag für B10 (auch nach rechts kopierbar für mehrere Ergebnisse):

Code:

=WENNFEHLER(AGGREGAT(15;6;ZEILE($A11:$A$100)/($A11:$A$100=$A10+1);SPALTE()-1);"")

[BoskoBiati]

Hi,

ich gehe davon aus, dass sowohl A10 als auch 100 willkürlich gewählt wurden, um das Ganze besser darstellen zu können. Aus diesem grund habe ich eine Formel gestaltet, die mit jedem beliebigen Wert arbeiten kann, aber nicht richtig funktioniert, wenn dieser Wert mehrfach vorkommt.!

[Anne Haubrich]

Danke euch allen für eure Hilfe.
@Edgar, ja du hast vollkommen Recht, es handelt sich nur um ein Beispiel.