Zeichen trennen

[esined]

Hallo Liebe Excel-Power-User,

ich habe folgendes Problem:

Ich habe Kundennamen, die wie folgt aussehen

ABC-1-1-2022
ABCDE-10-10-2021
AB-CD-8-11-2021

Ich muss nun das Datum am Ende entfernen, aber ich kann nicht mit Text in Spalten trennen, da auch Kundennamen einen Bindestrich haben können.
Rechts abschneiden funktioniert leider auch nicht, da das Datum unterschiedliche Längen hat.

Hat jemand vielleicht eine Idee?

Ganz herzlichen Dank
LG
Denise

[Oberon]

Hi,

für Zelle A2:

PHP-Code:

=TEIL(A2;1;FINDEN("~";WECHSELN(A2;"-";"~";-2+LÄNGE(A2)-LÄNGE(WECHSELN(A2;"-";""))))-1) 


Der Kundenname darf keine Tilde enthalten.

CU
Oberon

[LCohen]

Kürzer und mit nur einem Argument:

=--GLÄTTEN(RECHTS(WECHSELN(A2;"-";"-    ");18))

EDIT: Habe statt "Datum entfernen" das Gegenteil gelesen: =WECHSELN(A2;"-"&WECHSELN(RECHTS(WECHSELN(A2;"-";"-    ");18);" ";);)

[RPP63]

Oder
=TEXTVOR(A1;"-";-3)
Denkbar, dass es noch Beta ist …

	A	B
1	ABC-1-1-2022	ABC
2	ABCDE-10-10-2021	ABCDE
3	AB-CD-8-11-2021	AB-CD

Zelle	Formel
B1	=TEXTVOR(A1;"-";-3)
B2	=TEXTVOR(A2;"-";-3)
B3	=TEXTVOR(A3;"-";-3)

Und falls das Datum gewünscht wäre, dann geht es auch sehr einfach mit
=--TEXTNACH(A1;"-";-3)

Gruß Ralf

[esined]

Super, danke es hat funktioniert, ich danke Euch