Zeile überspringen beim KKLEINSTE Befehl

[Grateful]

Hallo Community,

folgendes:

=KKLEINSTE(A1:A15;1) zeigt mir den Wert 0 von Zeile 3.
=KKLEINSTE(A1:A15;2) zeigt mir wieder den Wert 0 von Zeile 3 aber nicht den Wert 0 von Zeile 6.

Wie kann ich Zeile 3 überspringen, damit mir nicht zweimal die selbe Zelle angezeigt wird?
Es geht mir vor allem darum das mir mit:

=INDEX(B1:B15;VERGLEICH(KKLEINSTE(A1:A15;1 oder 2);B1:B15;0))

der selbe Text wiedergegeben wird.

Vielen Dank für eure Hilfe!

[Kuwer]

Hallo,

Es geht mir vor allem darum das mir mit:

=INDEX(B1:B15;VERGLEICH(KKLEINSTE(A1:A15;1 oder 2);B1:B15;0))

der selbe Text wiedergegeben wird.

dann passt es doch so!?

Gruß Uwe

[echo]

Hallo
in Spalte A gibt es Duplikate da VERGLEICH() nun mal immer den ersten Treffer übergibt kannst du das nur ändern in dem es in Spalte A keine Duplikate gibt!
Wenn in Spalte A ganze Zahlen stehen könntest du einfach Zeile()/1000 dazu addieren.

Alternative ist eine Hilfsspalte Das läßt sich leicht bewältigen:
=A1+zeile()/1000
Statt Spalte A fragst du die Hilfsspalte ab
Keine Duplikate: alle Zeilen werden gefunden ohne den Rang zu ändern.
Sind es Dezimalzahlen in Spalte A müssest du ggf zeile() durch einen noch höheren Wert teilen so das der Rang nicht verändert wird.

Gruß Holger

[echo]

Nachtrag: Link
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=236

[LCohen]

Ohne Hilfsspalte runterzukopieren:

=INDEX(B$1:B$15;REST(KKLEINSTE(INDEX(A$1:A$15+ZEILE(A$1:A$15)%%;);ZEILE(A1));1)/1%%)

Bedingung: A:A Ganzzahlen oder mit begrenzten Nachkommastellen (dann entspr. abzuwandeln)

Ich taufe es Surimi-Formel. 

Surimi: Fischreste werden auf Eiweiß reduziert und mit Fischflavour wieder zu einer scheinbaren Vollfischvariante (nämlich ähnlich Hummerfleisch) angereichert. Muss man als Fischkopp den kontinentalen Fischskeptikern vorsorglich erzählen.

In der Formel wird verwechselbarer Inhalt durch seine Lage ersetzt, und über diese Lage wird zugeordneter unverwechselbarer Inhalt zurückgegeben.

[neopa]

Hallo LCohem,

schöne Formel

Die von Dir vorgegebene Bedingung, schränkt die Anwendung leider ein. Hinzu kommt, dass in A1:A15 kein ="" bzw.  kein Textwert stehen darf.

Für einen allgemeineren Fall als hier, würde ich folgende Formel vorschlagen, die zwar auch nicht exakt 100% alle Eventualitäten berücksichtigt aber dem näher kommt.

Code:

=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$1:A$15)/(AGGREGAT(15;6;A$1:A$15+ZEILE(A$1:A$15)%%;ZEILE(A1))=A$1:A$15+ZEILE(A$1:A$15)%%);1));"")

[Edit:] zu klären wäre nämlich u.a. noch,  ob evtl. vorhandene Leerzellen als 0-Werte gewertet werden sollen (wie da mit der momentanen Formel der Fall ist oder diese z.B. "übersprungen" werden solle.

[LCohen]

Hallo neopa,

zu den Einschränkungen:

Da es ja um eine Sortierformel geht, kann man dem entgegenhalten, dass sehr oft die Ganzzahligkeit schon vorliegt - oder man die Festkommadarstellung brutal erzwingt (über KÜRZEN oder RUNDEN). Denn man darf nicht vergessen, dass die Genauigkeit von 15 Stellen und die Länge des Blatts von 6 Stellen eine HISPALO-Lösung (=hilfsspaltenlose) schon auf maximal 9 Stellen Genauigkeit große Inhalte limitiert, wenn die Daten wie bei mir dafür missbraucht werden. Bei 10.000 statt 1.000.000 Zeilen entspannt sich das etwas auf 11 Stellen.

Das mit dem abweichenden Datentyp kann ich jedoch nicht akzeptieren. Das gehört nicht in eine Wertespalte. Unterschiedliche Datentypen gehören eh nicht in eine Spalte - da bin ich konservativ. Falls doch, kann man eben auf kompliziertere Lösungen verweisen. Und somit kann auch Dein WENNFEHLER weg.

Der Performancetest für A1:B9999 beträgt mit 11 zu 19 Sekunden noch keine Größenordnung. Anzumerken: AGGREGAT stieg ab ca. 50.000 Verwendungen bei älteren (also vermutlich 2010-2013) Versionen aus. Ich habe mit 365 getestet, wo AGGREGAT anscheinend ziemlich gut ist.