Zeilen automatisch in anderes Tabellenblatt

[duddits30]

Hallo,

ich möchte wenn in den Spalten D-F ein Datum eingegeben wird, das automatisch die Spalten B + C mit dem Datum in das jeweilige Tabellenblatt kopiert werden.

Beispiel 
Name a Haus 3 Datum Spalte D 03.07.24 dann sollen die Daten aus Spalte B+C+D in das Tabellenblatt Fußball H3 eingefügt werden.

Ich hoffe es ist verständlich und machbar

[HKindler]

Hi,

wozu willst du das? Setze für das Haus Filter ein und für die Sportart blendest du die anderen Spalten aus. Schon brauchst du nur ein einziges Blatt. Wenn du zu faul bist, die Filter ständig händisch zu setzen, dann machst du das einmalig und speicherst dir die Einstelllungen in benutzerdefinierten Ansichten.

Wenn du ein aktuelles Excel hättest, dann würde auch die Formel (hier für Blatt Fußball H3)
=SPALTENWAHL(FILTER(Gesamt!B3:F28;(Gesamt!C3:C28=3)*(Gesamt!D3:D28<>""));1;2;3)
in B3 genügen. Für die anderen Blätter musst du die letzte Zahl bei Spaltenwahl() anpassen (Sportart) bzw, die Drei bei den Filterbedingungen (Haus).

[Rabe]

Hallo Helmut,

die Formel ist ja so was von cool. Die gefällt mir.

Da ich das nicht kannte, musste ich ne Weile probieren, weil nicht nur die letzte Zahl anzupassen ist, sondern auch die Nummer des Hauses und die Spalte für die Sportart.

Hier mal die Formeln, die ich dann hatte.
Fußball H4: =SPALTENWAHL(FILTER(Gesamt!B3:F28;(Gesamt!C3:C28=4)*(Gesamt!D3:D28<>""));1;2;3)
Volleyball H3: =SPALTENWAHL(FILTER(Gesamt!B3:F28;(Gesamt!C3:C28=3)*(Gesamt!E3:E28<>""));1;2;4)
Badminton H4: =SPALTENWAHL(FILTER(Gesamt!B3:F28;(Gesamt!C3:C28=4)*(Gesamt!F3:F28<>""));1;2;5)

Gruß Ralf

[HKindler]

Hi Ralf,

das hatte ich doch geschrieben (OK, die Spalte für die Sportart hatte ich vergessen):

Für die anderen Blätter musst du die letzte Zahl bei Spaltenwahl() anpassen (Sportart) bzw, die Drei bei den Filterbedingungen (Haus).

Wer lesen kann ist klar im Vorteil...

Freut mich, dass es dir weiter hilft. Auch wenn ich den Sinn immer noch anzweifle.

[EA1950]

Hallo,

1) Ich habe deine Tabelle im Arbeitsblatt "Gesamt" in A1:F28 umgewandelt in eine strukturierte Tabelle namens "tbDaten". Damit werden die weiteren Formeln etwas übersichtlicher.

2) In den Detailarbeitsblättern (Fußball H3, ...) habe ich in Zelle C2 jeweils die Hausnummer gespeichert, damit sie nicht als Direktkonstante in den Formeln aufscheinen muss.

3) Da du als Version Excel2016 angegeben hast, verfügst du damit nicht über die vielen leistungssteigernden Errungenschaften ab Excel2021 bzw. Excel365, zB. über dynamische Arrays und auch nicht über die FILTER-Funktion.
Aus diesem Grund musste ich folgende Formel (von @HKindler) 
=SPALTENWAHL(FILTER(tbDaten;(tbDaten[Haus]=C$2)*(tbDaten[Fußball]<>""));2;3;4)
umschreiben auf:
{=WENNFEHLER(INDEX(tbDaten; AGGREGAT(15;6;ZEILE($1:$999)/((tbDaten[Haus]=C$2)*(tbDaten[Fußball]<>""));$A3);{2.3.4});"")}
Es handelt sich dabei um eine (statische) Array-Funktion, erkennbar an den beiden (rot-)geschweiften Klammern. Um eine solche Formel einzugeben, muss man
a) zuerst den Resultat-Bereich der Array-Formel markieren (zB. Arbeitsblatt "Fußball H3": 'Fußball H3'!$B$3:$D$3), also in diesem Fall ein 1-zeiliger Bereich, bestehend aus 3 Zellen);
b) dann ist die Array-Formel in die Formeleditierzeile einzugeben, jedoch ohne die geschweiften Klammern und ohne EINGABE-Taste zum Abschluss
c) die Formeleingabe ist mit der Tastenkombination UMSCHALT+Strg+EINGABE abzuschließen
d) danach erscheint die Formel in geschweiften Klammern, wie oben zu sehen.

4) Diese Formel im Zellbereich 'Fußball H3'!$B$3:$D$3 habe ich hinunterkopiert bis Zeile 26: $B$26:$D$26.

5) Achtung! Die Formel besitzt eine Beschränkung auf 999 Zeilen. Der einschränkende Formelteil befindet sich in  ZEILE($1:$999). Fallen in einzelnen Arbeitsblättern mehr als diese 999 Zeilen an, müsste der Formelteil entsprechend erhöht werden (Vorgangsweise wie in Punkt 3a-3d).

6) Ähnliches habe ich auch in den anderen 5 Arbeitsblättern ("Fußball H4", "Volleyball H3", ...) durchgeführt.

Datei liegt bei.

[HKindler]

... (gelöscht)

[Rabe]

Hallo Helmut,

ich brauche das nicht, die Formel gefällt mir nur.

Gruß Ralf

[BoskoBiati]

Hi,

hier eine Formel für alle Tabellen, jeweils in B3 einfügen und nach rechts und unten ziehen:

Code:

=WENNFEHLER(INDEX(Gesamt!$A:$F;AGGREGAT(15;6;ZEILE(Gesamt!$A$3:$A$30)/(INDEX(Gesamt!$D$3:$F$30;;VERGLEICH($D$1;Gesamt!$D$1:$F$1;0))<>"")/(Gesamt!$C$3:$C$30=--RECHTS(ZELLE("dateiname";$A$1);1));ZEILE($A1));SPALTE()+(SPALTE()=4)*VERWEIS(LINKS($D$1;1);{"B";"F";"V"};{2;0;1}));"")

für neue Versionen:

Code:

=SPALTENWAHL(FILTER(Gesamt!$B$2:$F$27;(Gesamt!$C2:$C27=--RECHTS(ZELLE("Dateiname";A1);1))*(INDEX(Gesamt!$B$2:$F$27;;VERGLEICH($D$1;Gesamt!$B$1:$F$1;0))<>"");"");1;2;VERGLEICH($D$1;Gesamt!$B$1:$F$1;0))
=LET(a;Gesamt!$B$2:$F$27;b;VERGLEICH($D$1;Gesamt!$B$1:$F$1;0);SPALTENWAHL(FILTER(a;(Gesamt!$C2:$C27=--RECHTS(ZELLE("Dateiname";A1);1))*(INDEX(a;;b)<>"");"");1;2;b))

[duddits30]

  Sportplantest.xlsm (Größe: 318,88 KB / Downloads: 5)

Danke für die vielen Ideen.
Ich habe aber nun nach Ideen und Verbesserungswünschen von mehreren Kollegen, die Liste nochmal umgebaut und dann passt der Code leider nicht mehr.
Wäre gut wenn nochmal jemand drüber gucken könnte.

Danke

[BoskoBiati]

Hallo,

ganz wunderbar. Somit ist jegliche Zuordnung zu den einzelnen Tabellen verloren gegangen! Formeln sind hierfür wohl kaum möglich!