Zeilen mit Bedingung in neue Tabelle kopieren (erweitern)

[m6joe]

Servus zusammen!

Hier hatte ich bereits Eure großartige Hilfe genossen, und möchte das Thema nochmals aufgreifen, da ich die Abfrage noch um ein "Von-Bis-Datum" erweitern möchte, aber kläglich damit scheitere.
Mein Problem ist, dass ich es nicht hinbekomme die Datumsabfrage an die richtige Stelle der Formel zu setzen, die bestehende lautet bereits so:

Code:

=WENNFEHLER(INDEX(Eingangsrechnung!$A$5:$Q$3000;AGGREGAT(15;6;ZEILE(Eingangsrechnung!$C$1:$C$3000)/(Eingangsrechnung!$C$5:$C$3000=$C$3);ZEILE(B1));VERGLEICH(B$7;Eingangsrechnung!$A$4:$P$4;0));"")

Als Datumsabfrage bediene ich mich mit dieser Formel:

Code:

=UND($A$1<=B9;$B$1>=B9)

Wer kann mir hier Input verschaffen?
Danke vorab, Joe

[Jockel]

Hallo, stellst du uns bitte (d)eine neue (Beispiel)Datei zur Verfügung...? Was steht in C3..? Zumindest ein Tabellenblatt hat einen anderen Namen...

[m6joe]

Hier wie gewünscht!

Die Formel hier fängt in B7 an:

Code:

=WENNFEHLER(INDEX('EA Rechnung'!$A$9:$H$3004;AGGREGAT(15;6;ZEILE('EA Rechnung'!$G$1:$G$3004)/('EA Rechnung'!$G$9:$G$3004=$A$1);ZEILE(A1));VERGLEICH(B$6;'EA Rechnung'!$A$8:$H$8;0));"")

Die beiden zu filternden Daten stehen in B3, bzw. B4 (Monats-Erster, Monats-Letzter)

Danke

[Jockel]

Hallo, kann es auch mehrere Kontobewegungen pro Tag geben..? Wieso nutzt du nicht PivotTable oder Power Query..? Wieso ist das Blatt EA Rechnungen schreibgeschützt und man kann doch Zellen löschen..?

[m6joe]

Ja, sind es bereits.

[Jockel]

Ja aber nicht in der Datei...

[m6joe]

Sorry, nicht in dieser Datei - in der Live-Version schon!
Ich selbst nutze Excel 2013 oder 2016; der Vereinskassier soweit mir bekannt Excel 2007

[Jockel]

Hallo, ich habe mal eine zweite Kontobewegung reingetan..:

Arbeitsblatt mit dem Namen 'EA Rechnung'
	A	B	C	D	E	F	G
9	31.05.2018	1	Einkauf Lokal	Limo		23,66	Bar-Kassa
10	03.06.2018	2	Einkauf Lokal	Bier		280,40	Bar-Kassa
11	08.06.2018	3	Einkauf Lokal	Wein		222,80	Bar-Kassa
12	08.06.2018	4	Einkauf Lokal	Chips		5,40	Bar-Kassa

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Bargeld - Kassa'
	B	C	D	E	F	G	H
6	Datum	Bel.Nr.	Konto	Bemerkung	Eingang	Ausgang	Saldo
7	03.06.2018	2	Einkauf Lokal	Bier		280,40	719,60
8	08.06.2018	3	Einkauf Lokal	Wein		222,80	496,80
9	08.06.2018	4	Einkauf Lokal	Chips		5,40	491,40

Zelle	Formel
B7	=WENNFEHLER(AGGREGAT(15;6;'EA Rechnung'!$A$9:$A$100/('EA Rechnung'!$A$9:$A$100>=$E$3)/('EA Rechnung'!$A$9:$A$100<=$E$4);ZEILE(A1));"")
C7	=WENN(B7="";"";INDEX('EA Rechnung'!$B$9:$B$100;AGGREGAT(15;6;ZEILE('EA Rechnung'!$A$9:$A$100)-8/('EA Rechnung'!$A$9:$A$100=B7);ZÄHLENWENN($B$7:B7;B7))))
D7	=WENN($B7="";"";INDEX('EA Rechnung'!C$9:C$100;VERGLEICH($B7&" "&$C7;INDEX('EA Rechnung'!$A$9:$A$100&" "&'EA Rechnung'!$B$9:$B$100;0);0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Jockel]

Sorry, nicht in dieser Datei - in der Live-Version schon!
...der Vereinskassier soweit mir bekannt Excel 2007

Hallo, dann geht AGGREGAT() nicht...!

[m6joe]

Danke @Jockel!
Deine Formel wurde "einfacher", erschließt sich mir ein wenig mehr... DANKE

Und läuft auch bei mir!

Bis zum nächsten Mal, Joe