Zeilenteile automatisch kopieren

[Mütze]

Hallo zusammen,

ich bin blutige Excel Anfängerin, leider finde ich keine geeignete Lösung für mein Problem.

Ich möchte gerne aus dem Blatt "Übersicht", bestimmte Zeilenteile in das Blatt "neue Messe" kopieren. Die soll automatisch passieren, sobald in dem Blatt "Übersicht" eine neue Zeile angelegt wird, welche die Bedingungen erfüllt. Bedingungen: Kontakt: Nein, Beratung: Nein, Warteliste: Nein, Projekt: Nein, Auszug: Leer, diese sollen dann in dem Blatt "neue Messe" auftauchen. Jedoch benötige ich in dem Blatt "neue Messe" nur die Spalten A-E aus dem Blatt "Übersicht". Ab Spalte F sollen dann Manuel Daten eingegeben werden.

Ich hoffe, man kann mein Problem verstehen und es gibt eine einfache Lösung.

Liebe Grüße und danke

Mona

[WillWissen]

Moin Mona,

so?

Arbeitsblatt mit dem Namen 'Neue Messe'
	A	B	C	D	E
1	Einzug	Hotel	Nachname	Vorname	Geburtstag
2	13.02.2019	alte Messe	aa	regg	13.03.1992
3	14.02.2019	alte Messe	aa	e	14.03.1992
4	16.02.2019	alte Messe	dg	gf	16.03.1992
5	17.02.2019	Neue Messe	rtr	gffg	17.03.1992
6	18.02.2019	Neue Messe	rtr	gf	18.03.1992
7	19.02.2019	Neue Messe	rtr	fgf	19.03.1992
8	22.02.2019	Neue Messe	hh	fg	22.03.1992
9	23.02.2019	Neue Messe	ghg	gffg	23.03.1992

Zelle	Formel
A2	=WENNFEHLER(INDEX(Übersicht!A:A;AGGREGAT(15;6;ZEILE(Übersicht!$F$2:$F$1000)/(Übersicht!$F$2:$F$1000="nein")/(Übersicht!$G$2:$G$1000="nein")/(Übersicht!$H$2:$H$1000="nein")/(Übersicht!$J$2:$J$1000="");ZEILE(A1)));"")
B2	=SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(B$1);0)
C2	=SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(C$1);0)
D2	=SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(D$1);0)
E2	=SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(E$1);0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Ich habe einen großen Bereich gewählt, damit du die Formeln so weit als möglich runterziehen kannst. SVERWEIS() ab B2 nach rechts und unten ziehen.

Nachtrag: habe vergessen, um den SVERWEIS() herum ebenfalls ein WENNFEHLER() zu schreiben.

[Mütze]

Moin Günter,

Erst mal Danke für die schnelle Hilfe!

Leider habe ich vergessen zu schreiben, dass nur das Hotel neue Messe in dem Blatt "neue Messe" auftauen soll.

Es tauchen immer noch Personen auf, obwohl diese bei Projekt "ja" stehen haben.

Es dürften dem nach nur Zeile 8 und 12 aus dem Blatt "neue Messe" auftauchen.

Viele Grüße
Mona

[WillWissen]

Hi Mona,

dann so:

=WENNFEHLER(INDEX(Übersicht!A:A;AGGREGAT(15;6;ZEILE(Übersicht!$F$2:$F$1000)/(Übersicht!$B$2:$B$1000="Neue Messe")/(Übersicht!$F$2:$F$1000="nein")/(Übersicht!$G$2:$G$1000="nein")/(Übersicht!$I$2:$I$1000="nein")/(Übersicht!$J$2:$J$1000="");ZEILE(A1)));"")

Beim Projekt bin ich in der Spalte verrutscht. Sorry.

[Mütze]

Vielen Dank! Ich hab es geschaft, die Formeln auf die gesammte Tabelle zu übertragen und bin echt begeistert. Leider verstehe ich deinen Nachtrag nicht.
Bzw. wenn ich einen WENNFEHLER() herum schreibe funktioniert es nicht mehr.

Nachtrag: habe vergessen, um den SVERWEIS() herum ebenfalls ein WENNFEHLER() zu schreiben.

[marose67]

Hallo,

wenn Du  den WENNFEHLER richtig einbaust, dann klappt es:

Neue Messe

	A	B	C	D	E
2	43509	alte Messe	aa	regg	33676

Formeln der Tabelle

Zelle Formel A2 =WENNFEHLER(INDEX(Übersicht!A:A;AGGREGAT(15;6;ZEILE(Übersicht!$F$2:$F$1000)/(Übersicht!$F$2:$F$1000="nein")/(Übersicht!$G$2:$G$1000="nein")/(Übersicht!$H$2:$H$1000="nein")/(Übersicht!$J$2:$J$1000="");ZEILE(A1)));"") B2 =WENNFEHLER(SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(B$1);0);"") C2 =WENNFEHLER(SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(C$1);0);"") D2 =WENNFEHLER(SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(D$1);0);"") E2 =WENNFEHLER(SVERWEIS($A2;Übersicht!$A$1:$E$1000;SPALTE(E$1);0);"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß
Marcus

[WillWissen]

Moin,

Bzw. wenn ich einen WENNFEHLER() herum schreibe funktioniert es nicht mehr.

die Fehlerabfrage ist nur nötig, wenn du die Formel "auf Vorrat" weiter runterziehst. Findet der SVERWEIS() keine Daten mehr, würde #NV auftauchen. Das wird mit WENNFEHLER() unterdrückt.


Wenn "es nicht mehr funktioniert", hast du einen Fehler gemacht, den ich von hier aus nicht sehen kann.