Zeiterfassung

[deejayk]

Hallo Zusammen,

ich habe von einem Kinderheim die Aufgabe bekommen, eine Exceltabelle zu erstellen, um die tägliche Arbeitszeit zu erfassen. Das Grundprinzip (Pausenzeiten usw.) habe ich ohne Probleme hinbekommen. Jetzt ist aber das Problem, dass wenn die Mitarbeiter dort Nachtdienst haben nur 2,5 Stunden gutgeschrieben bekommen. Ich habe jetzt schon hin und her probiert und kriege es nicht hin! Ich habe mir gedacht, dass ich einfach nur eine Spalte einfüge wo bloß für Nachtdienst eine 1 eingetragen wird (siehe Blatt Mai)
Hier die bisherige Formel:
=WENN(C4-B4>=WERT("9:00");C4-B4-WERT("0:45");WENN(C4-B4>=WERT("6:00");C4-B4-WERT("0:30");C4-B4))

Danke im vorraus!

[WillWissen]

Hi,

ich würde noch eine Pausenspalte einfügen.

Tabelle1

	A	B	C	D	E
1	Mitarbeiter 1
2	K	G	Pause	Brutto	Std
3	22:00	06:00	00:30	08:00	7:30

Formeln der Tabelle

Zelle Formel C3 =WENN(D3)*24<=6;0;WENN(D3)*24<9;0,5;0,75)/24) D3 =REST(B3-A3;1) E3 =D3-C3

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[WillWissen]

Hi,

hier noch eine Variante ohne Hilfsspalten

Tabelle1

	A	B	C
1	Mitarbeiter 1
2	K	G	Std
3	20:00	06:00	09:15
4	22:00	06:00	07:30
5	08:00	12:00	04:00

Formeln der Tabelle

Zelle Formel C3 =REST(B3-A3;1)-WENN(REST(B3-A3;1)*24<=6;0;WENN(REST(B3-A3;1)*24<9;0,5;0,75)/24) C4 =REST(B4-A4;1)-WENN(REST(B4-A4;1)*24<=6;0;WENN(REST(B4-A4;1)*24<9;0,5;0,75)/24) C5 =REST(B5-A5;1)-WENN(REST(B5-A5;1)*24<=6;0;WENN(REST(B5-A5;1)*24<9;0,5;0,75)/24)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[shift-del]

Hallo deejayk

Ich sehe nicht wie du 'Nachstunden' abgrenzt bzw. wie da die 2,5 Stunden Gutschrift ins Spiel kommen.

Die Formel für E2 könnte man auch so formulieren:

Code:

=C4-B4-(VERWEIS(REST(C4-B4;1)*24;{0;6;9};{0;30;45})/60/24)

[WillWissen]

Hi Detlef,

deine Formel funktioniert aber nur bei Zeitabrechnungen vor Mitternacht. Zeiträume, die über Mitternacht hinausgehen, werden mit dem "Lattenzaun" dargestellt.

Tabelle1

	A	B	C	D
1	Mitarbeiter 1
2	K	G	Std
3	21:00	05:00	07:30	WillWissen
4	08:00	16:00	07:30	-"-
5	21:00	05:00	####	shift-del
6	08:00	16:00	07:30	-"-

Formeln der Tabelle

Zelle Formel C3 =REST(B3-A3;1)-WENN(REST(B3-A3;1)*24<=6;0;WENN(REST(B3-A3;1)*24<9;0,5;0,75)/24) C4 =REST(B4-A4;1)-WENN(REST(B4-A4;1)*24<=6;0;WENN(REST(B4-A4;1)*24<9;0,5;0,75)/24) C5 =B5-A5-(VERWEIS(REST(B5-A5;1)*24;{0;6;9};{0;30;45})/60/24) C6 =B6-A6-(VERWEIS(REST(B6-A6;1)*24;{0;6;9};{0;30;45})/60/24)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[shift-del]

Hallo Günter

Danke für den Hinweis.

Code:

=REST(C4-B4;1)-(VERWEIS(REST(C4-B4;1)*24;{0;6;9};{0;30;45})/60/24)

[WillWissen]

Hi Detlef,

so schaut's gut aus - schöne Lösung.

[BoskoBiati]

Hallo,

oder auch so:

Code:

=REST(C4-B4;1)-((REST(C4-B4;1)>=0,25)*2+(REST(C4-B4;1)>=0,375))/96

Allerdings ist immer noch offen, wie die Nachtstundenregelung korrekt laufen soll.

[shift-del]

Hi Detlef,

so schaut's gut aus - schöne Lösung.

Viele Wege führen nach Rom. :)