Zeitwert richtig formatieren

[cmor]

Hallo zusammen,

ich habe eine Spalte "Zeitwert" mit folgenden Inhalten:

z.B. 

7.384999999S
7.272S
0.062S
1M27.125S
1M25.655999999S
1H12M12.291S
1H12M10.801999999S
1H12M28.984S

Diese möchte ich gerne in einer Pivot Tabelle weiter verarbeiten z.B. als Bereichsfilter etc.

Wie bekomme ich diese Werte in ein nützliches Format?

Danke euch!

VG

Chris

[schauan]

Hallöchen,

hier mal ein Ansatz wie Du Stunden, Minuten und Sekunden extrahieren kannst. Ich hab die Formel mal in 3 Schritten dargestellt, geht natürlich alles auch in einer Zelle. Dazu kommt noch die Bewertung als Zeit, das bekommst Du hin, oder?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
5	1H12M2.3S	1	12	2,3
6	2.3S			2,3
7	12M2.3S		12	2,3

Zelle	Formel
B5	=LINKS(A5;WENNFEHLER(FINDEN("H";A5);1)-1)
C5	=TEIL(A5;WENNFEHLER(FINDEN("H";A5);0)+1;(WENNFEHLER(FINDEN("M";A5);1)-WENNFEHLER(FINDEN("H";A5);0))-1)
D5	=--WECHSELN(WECHSELN(TEIL(A5;WENNFEHLER(FINDEN("M";A5);0)+1;99);"S";"");".";",")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[ralf_b]

oder so 

	B	C
2	7.384999999S	00:00:07
3	1M27.125S	00:01:27
4	1H12M12.291S	01:12:12

Zelle	Formel
C2	=ZEIT(WENNFEHLER(TEIL(B2;1;FINDEN("H";B2)-1);"00");WENNFEHLER(WENN(ISTFEHL(FINDEN("H";B2));TEIL(B2;1;FINDEN("M";B2)-1);TEIL(B2;FINDEN("H";B2)+1;FINDEN("M";B2)-FINDEN("H";B2)-1));"00");WENN(ISTFEHL(FINDEN("M";B2));WECHSELN(WECHSELN(B2;"S";"");".";",");WECHSELN(TEIL(B2;FINDEN("M";B2)+1;FINDEN("S";B2)-FINDEN("M";B2)-1);".";",")))

[cmor]

okay danke dir vielmals.

In einer Formel mit weiterer Fehlerbehandlung sieht das dann nun so aus:

In L10 steht dann z.B. 1H10M7.51S

=TIME(IF(LEFT(L10,IFERROR(FIND("H",L10),1)-1)="",0,LEFT(L10,IFERROR(FIND("H",L10),1)-1)),IF(MID(L10,IFERROR(FIND("H",L10),0)+1,(IFERROR(FIND("M",L10),1)-IFERROR(FIND("H",L10),0))-1)="",0,MID(L10,IFERROR(FIND("H",L10),0)+1,(IFERROR(FIND("M",L10),1)-IFERROR(FIND("H",L10),0))-1)),ROUND(SUBSTITUTE(MID(L10,IFERROR(FIND("M",L10),0)+1,99),"S",""),0))

Schöne Ostern!