Zellen - Sverweis nur wenn Wert größer 0

[Jockel]

Hallo, meinst du so...? Wenn du unterschiedliche E-Mail-Adressen angeben würdest, könnte man sicher besser testen... .... dann würde sicher auch ein einfacher SVERWEIS() reichen, weil die E-Mail-Adresse sicher nicht doppelt vorkommen... !!!!! Aber das müßte auch so passen...

Arbeitsblatt mit dem Namen 'Februar 2016'
	AO	AP	AQ	AR
3	Essen	3,70 €
4	Leberkäse u. Semmel	3,00 €
5	gmx1@fmx1.de		12,95 €	Max Muster 1
6	gmx1@fmx1.de		31,45 €	Max Muster 4
7	gmx1@fmx1.de		12,95 €	Max Muster 5
8

Zelle	Formel
AO5	=WENNFEHLER(SVERWEIS(INDEX($A$5:$A$70;AGGREGAT(15;6;ZEILE($AH$5:$AH$70)-4/($AH$5:$AH$70<>"")/($AH$5:$AH$70>0)/($AM$5:$AM$70=0);ZEILE(A1)));'aktive Mitglieder'!$C$5:$BD$70;41;0);"")
AP5	=WENNFEHLER(SVERWEIS(INDEX($A$5:$A$70;AGGREGAT(15;6;ZEILE($AH$5:$AH$70)-4/($AH$5:$AH$70<>"")/($AH$5:$AH$70>0)/($AM$5:$AM$70=0);ZEILE(A1)));'aktive Mitglieder'!$C$5:$BD$70;54;0);"")
AQ5	=WENNFEHLER(INDEX($AH$5:$AH$70;AGGREGAT(15;6;ZEILE($AH$5:$AH$70)-4/($AH$5:$AH$70<>"")/($AH$5:$AH$70>0)/($AM$5:$AM$70=0);ZEILE(A1)));"")
AR5	=WENNFEHLER(INDEX($A$5:$A$70;AGGREGAT(15;6;ZEILE($AH$5:$AH$70)-4/($AH$5:$AH$70<>"")/($AH$5:$AH$70>0)/($AM$5:$AM$70=0);ZEILE(A1)));"")

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[neopa]

Hallo Jörg, hallo David,

ich hab jetzt nicht den ganzen thread durchgelesen.

Aber so wie die Datei eingestellt ist, hat die AGGREGAT()-Formel in Spalte AR Einsparpotential (s.u) und braucht mE in AO:AQ lediglich übernommen werden, wenn identische Namen in Spalte A möglich sind.

Somit in AR5:

Code:

=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(A$5:A$99)/(AH$5:AH$99>0);ZEILE(A1)));"")

und in AQ5:

Code:

=WENN(AR5="";"";SVERWEIS(AR5;A:AH;SPALTE(AH1);))

analog in den anderen beiden Spalten AO:AP

[Jockel]

Hallo Jörg, hallo David,

ich hab jetzt nicht den ganzen thread durchgelesen.

Aber so wie die Datei eingestellt ist,... (gibt's) ... in Spalte AR Einsparpotential...

Hallo Werner, sicher, wenn Name und E-Mail-Adresse nicht mehrfach vorkommen (können) - aber das hatte ich auch bereits geschrieben...

[neopa]

Hallo Jörg,

meine Kürzungsvorschlag zur  AGGREGAT()-Formel war und ist unabhängig davon, ob die Namen in Spalte A mehrfach vorkommen können oder nicht.

[Jockel]

Hallo Werner, fällt dir was auf...?

Arbeitsblatt mit dem Namen 'Februar 2016'
	AR	AS
5	Max Muster 1	Max Muster 1
6	Max Muster 4	Max Muster 4
7	Max Muster 5	Max Muster 5
8		Zuschuss 2

Zelle	Formel
AR5	=WENNFEHLER(INDEX($A$5:$A$70;AGGREGAT(15;6;ZEILE($AH$5:$AH$70)-4/($AH$5:$AH$70<>"")/($AH$5:$AH$70>0)/($AM$5:$AM$70=0);ZEILE(A1)));"")
AS5	=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(A$5:A$99)/(AH$5:AH$99>0);ZEILE(A1)));"")

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[neopa]

Hallo Jörg,

... wenn "Zuschuss" in AR nicht gelistet werden soll, ist dann aber immer noch mit:

Code:

=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(A$5:A$99)/(AH$5:AH$99>0)/(AM$5:AM$99=0);ZEILE(A1)));"")

ein Bedingungsabgleich und eine Subtraktion eingespart.  :21:

[Daniel Albert]

Hallo,

also die eMail Adresse kann mehrmals vorkommen der Name nicht. In Spalte C - aktive Mitglieder werden die Kindernamen aufgelistet, somit können die Namen nicht doppelt hinterlegt sein aber da wir Eltern mit mehreren Kindern haben kann die eMailadresse mehrfach vorkommen. Das soll aber bitte so bleiben denn die Vorabinfo zur Abbuchung sollen die Eltern zu jedem Kind einzeln erhalten.

So jetzt schaue ich mir mal den Code an :)

Danke euch beiden

[Jockel]

Hallo Jörg,
...
ein Bedingungsabgleich und eine Subtraktion eingespart.

Hallo Werner, ... wow... ... und die Zeilenbegrenzung beim INDEX() und die daraus resultierenden absoluten Bezüge... und und und... omg... Ich muss mich erstmal hinlegen... ... und das verdauen.

[Jockel]

Hallo,

also die eMail Adresse kann mehrmals vorkommen der Name nicht

Hallo, schau mal - hier kann man wirklich einsparen..:

Arbeitsblatt mit dem Namen 'Februar 2016'
	AO	AP	AQ
5	gmx1@fmx1.de		12,95
6	gmx1@fmx1.de		31,45
7	gmx1@fmx1.de		12,95
8

Zelle	Formel
AO5	=WENNFEHLER(SVERWEIS(AR5;'aktive Mitglieder'!$C$5:$BE$70;41;0);"")
AQ5	=WENNFEHLER(SVERWEIS(AR5;$A$5:$AM$70;34;0);"")

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[Daniel Albert]

Danke Danke euch 3,

Funktioniert :)

Werde es in die richtige Tabelle einbinden und mich nochmal melden.

Falls wir uns nicht mehr hören,

Ich wünsche euch schöne Feiertage