Zellen neben Suchergebnis auflisten

[Egro]

Hallo zusammen.

Ich habe auf einem Arbeitsblatt folgenden Aufbau:

Spalte A = Kundennummern.

Spalte B bis F = nicht relevante Daten.

Spalte G = einen Betrag oder keinen Wert (nicht "Null").

Spalte H = Werte von 1 bis 4.

Nun möchte ich in einem anderen Arbeitsblatt (selbe Mappe/Datei) folgendes:

Spalte A = Alle Kundennummern, die in Spalte G einen Betrag haben und in Spalte H eine 1. (in Zeile 1 beginnend, untereinander aufgelistet).

Spalte B = Alle Kundennummern, die in Spalte G einen Betrag haben und in Spalte H eine 2. (in Zeile 1 beginnend, untereinander aufgelistet).

Spalte C = Alle Kundennummern, die in Spalte G einen Betrag haben und in Spalte H eine 3. (in Zeile 1 beginnend, untereinander aufgelistet).

Spalte D = Alle Kundennummern, die in Spalte G einen Betrag haben und in Spalte H eine 3. (in Zeile 1 beginnend, untereinander aufgelistet).

Ich habe schon mit "WENN" und "XVERWEIS" rumprobiert, aber bringe es einfach nicht hin.

Kann mir da jemand helfen?

Besten Dank im Voraus.
PS: Von VBA habe ich keine Ahnung!!!

[WillWissen]

Hallo,

lad mal bitte eine Beispieldatei mit händisch eingetragenem Wunschergebnis hoch, damit die Helfer Vorschläge eventuell testen können. So geht's: https://www.clever-excel-forum.de/thread-326.html

[Niclaus]

Ich schliesse mich WillWissen an: Auch wenn man von VBA keine Ahnung hat, kann man doch eine Datei hochladen!!
Für eine Lösung habe ich die beiden angehängten Bilder.
Die Spalten I:P in Tabelle1 sind Hilfsspalten. Die kann man ausblenden.
Niclaus

PS Nachträglich festgestellt: In Tabelle1 kann man folgende Formeln vereinfachen:

 M2         =WENN(I2=0;"";(I2<>0)*ZEILE())
 N2         =WENN(J2=0;"";(J2<>0)*ZEILE())
 O2         =WENN(K2=0;"";(K2<>0)*ZEILE())
 P2         =WENN(L2=0;"";(L2<>0)*ZEILE())

[Egro]

Entschuldigung, ich dachte, dass ich ein Beispiel angehängt habe...

  Auflistung.xlsx (Größe: 10,41 KB / Downloads: 6)

Sobald ich Zeit habe, versuche ich das Beispiel von Niclaus.

Besten Dank im Voraus.

[WillWissen]

Moin,

auf die Schnelle eine Formellösung:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H
21	So sollte das Ergebnis aussehen				Meine Lösung
22	Kunden Quartal 1	Kunden Quartal 2	Kunden Quartal 3	Kunden Quartal 4	Kunden Quartal 1	Kunden Quartal 2	Kunden Quartal 3	Kunden Quartal 4
23	1	11	3	4	1	11	3	4
24	2	12	6	14	2	12	6
25	8		9		8		9
26	13				13
27	15				15
28
29

Zelle	Formel
E23	=WENNFEHLER(INDEX(Tabelle1!A:A;AGGREGAT(15;6;ZEILE(Tabelle1!$A$1:$A$20)/(Tabelle1!$H$1:$H$20=1)/(Tabelle1!$G$1:$G$20<>"");ZEILE(Tabelle1!A1)));"")
F23	=WENNFEHLER(INDEX(Tabelle1!A:A;AGGREGAT(15;6;ZEILE(Tabelle1!$A$1:$A$20)/(Tabelle1!$H$1:$H$20=2)/(Tabelle1!$G$1:$G$20<>"");ZEILE(Tabelle1!A1)));"")
G23	=WENNFEHLER(INDEX(Tabelle1!A:A;AGGREGAT(15;6;ZEILE(Tabelle1!$A$1:$A$20)/(Tabelle1!$H$1:$H$20=3)/(Tabelle1!$G$1:$G$20<>"");ZEILE(Tabelle1!A1)));"")
H23	=WENNFEHLER(INDEX(Tabelle1!A:A;AGGREGAT(15;6;ZEILE(Tabelle1!$A$1:$A$20)/(Tabelle1!$H$1:$H$20=4)/(Tabelle1!$G$1:$G$20<>"");ZEILE(Tabelle1!A1)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Eventuell kommst du auch mit Power Query zum Ziel. Im Übrigen stimmt bei deinem Beispiel für das 4. Quartal die Kd.-Nr. 14 nicht. Deine zweite Bedingung, dass in Spalte G ein Betrag stehen muss, ist nicht erfüllt.

[RPP63]

Moin!
In Excel 365 sollte man die neuen dynamischen Formeln nutzen.
In Tabelle2!A2: =FILTER(Tabelle1!$A3:$A17;(Tabelle1!$G3:$G17>0)*(Tabelle1!$H3:$H17=SPALTE()))
nach rechts ziehen.

	A	B	C	D
1	Kunden Quartal 1	Kunden Quartal 2	Kunden Quartal 3	Kunden Quartal 4
2	1	11	3	4
3	2	12	6
4	8		9
5	13
6	15

Formeln der Tabelle

Zelle Formel A2 =FILTER(Tabelle1!$A3:$A17;(Tabelle1!$G3:$G17>0)*(Tabelle1!$H3:$H17=SPALTE()))

Gruß Ralf

[WillWissen]

Hi Ralf,

wo du recht hast...

Ich muss zu meiner Schande gestehen, dass ich mich immer noch nicht richtig mit den neuen Funktionen beschäftigt habe. Ist wohl dem bekannten "Rentnerstress" geschuldet.

[RPP63]

Machet, Günni!
Im Ernst:
Die Funktionen haben schon etwas, was sich der ambitionierte Anwender seit Jahren gewünscht hat.
Und gerade als Rentner, der sich im Rahmen der Selbsthilfe der Forenhilfe verschrieben hat, solltest Du Dich da mal einarbeiten.
Es lohnt sich!
Und demnächst bringe ich Dir auch noch VBA bei! 

Gruß Ralf, der hart an der zukünftigen (derzeit noch gültigen) Höchstgrenze des Renteneintrittsalters knabbert, also noch grob 8 Jahre arbeiten darf …

[WillWissen]

Hi Ralf,

Und demnächst bringe ich Dir auch noch VBA bei!

da wüsste ich was  - schau mal im Forumskopf; Stichwort rote Schrift. Ich schlag schon am 12. auf.

[Egro]

Vielen Dank für eure Hilfe.

Ich werde es, sobald als möglich testen, aber das funktioniert sicher.