Ziffernvergleich für Spiel77

[HelmutHH]

Hallo,

hat jemand etwas Besseres/Kürzeres als das Folgende (in A1 steht die 7stellige Losnummer, in B1 die gezogene auch 7stellige Nummer aus Spiel77):


In C1 steht diese Formel:

=WENN(RECHTS($A$1;7)=RECHTS($B$1;7);"7 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;6)=RECHTS($B$1;6);"6 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;5)=RECHTS($B$1;5);"5 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;4)=RECHTS($B$1;4);"4 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;3)=RECHTS($B$1;3);"3 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;2)=RECHTS($B$1;2);"2 Ziffern Spiel 77 richtig";WENN(RECHTS($A$1;1)=RECHTS($B$1;1);"1 Ziffer Spiel 77 richtig";"KEINE Ziffer Spiel 77 richtig")))))))

Vielen Dank schonmal!

Gruß

Helmut

[RPP63]

Ist mal eine schöne Aufgabe.  :19:

	A	B	C
1	1234668	2345668	3 Ziffern Spiel 77 richtig
2	4567891	3567891	6 Ziffern Spiel 77 richtig

Zelle	Formel
C1	{=MAX((RECHTS(A1;SPALTE(A:G))=RECHTS(B1;SPALTE(A:G)))*SPALTE(A:G))&" Ziffern Spiel 77 richtig"}
C2	{=MAX((RECHTS(A2;SPALTE(A:G))=RECHTS(B2;SPALTE(A:G)))*SPALTE(A:G))&" Ziffern Spiel 77 richtig"}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

P.S.:
Danke Gerd für die Überarbeitung des Tools! :18:

Gruß Ralf

[RPP63]

Ergänzend:
Wenn man die Formel wie folgt ändert:
{=MAX((RECHTS(A1;SPALTE(A1:G1))=RECHTS(B1;SPALTE(A1:G1)))*SPALTE(A1:G1))&" Ziffern Spiel 77 richtig"}
dann kann man die Rechenweise sehr schön in der Formelauswertung nachvollziehen.

[RPP63]

… den Text kann man ja auch zahlabhängig schön über ein benutzerdefiniertes Zahlenformat anzeigen lassen:

	A	B	C
1	4234668	2345668	3 Ziffern richtig
2	4567891	3567881	1 Ziffer richtig
3	1234567	7654321	keine Ziffer richtig

Zelle	Format	Wert
C1	[=0]"keine Ziffer richtig";[=1]0 "Ziffer richtig";0 "Ziffern richtig"	3

Zelle	Formel
C1	{=MAX((RECHTS(A1;SPALTE(A1:G1))=RECHTS(B1;SPALTE(A1:G1)))*SPALTE(A1:G1))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Der Steuerfuzzi]

Hallo,

hier noch eine Alternative (allerdings ist Ralfs Lösung etwas "schöner"):

Code:

{=WENNFEHLER(VERGLEICH(0;1*(TEIL(A1;8-SPALTE($A$1:$G$1);1)=TEIL(B1;8-SPALTE($A$1:$G$1);1));0)-1;7)}

Achtung! Matrixformel: die {} nicht mit eingeben, stattdessen die Formel mit Strg+Shift+Enter beenden.

[Der Steuerfuzzi]

Hier noch eine Abwandlung von Ralfs Lösung ohne Matrixformel:

Code:

=AGGREGAT(14;6;(RECHTS(A1;SPALTE(A1:G1))=RECHTS(B1;SPALTE(A1:G1)))*SPALTE(A1:G1);1)

[RPP63]

Moin Michael!
Die Schönheit liegt ja bekanntlich im Auge des Betrachters. ;)
Jedenfalls wäre ich auf Deinen Ansatz niemals gekommen!

Gruß Ralf

[HelmutHH]

KLASSE ********************************


Herzlichen Dank!

[Willie017]

Danke Gerd für die Überarbeitung des Tools! :18:

Hallo

wo kann man diese neueste Version 2.60 denn bekommen?

[Der Steuerfuzzi]

wo kann man diese neueste Version 2.60 denn bekommen?

Hier