aus bestehendem Datum Textereignis herführen

[kutte44]

Guten Tag in die Runde, ich bin neu in diesem Forum und möchte gern einmal eine Frage in selbige werfen.

Ich habe in einer Zelle ein formatiertes Datum stehen. z. B. 23.09.2001.

Nun möchte ich folgendes erreichen:

=WENN(UND(C2DATUM(2000;1;1);C2DATUM(2006;1;1);C2(UND(C2DATUM(2010;1;1);C2
Die Formel ist sehr viel länger. läßt sich aber nicht anzeigen ??? Die komplette Formel befindet sich im Anhang.

Es will aber nicht klappen. Kann mir jemand sagen wo der Fehler liegt.

Vielen Dank im Voraus.

[steve1da]

Hola,

Edit: da sind so viele Fehler drin...es fehlen schließende Klammern, mal fehlt ein UND, mal ist ein UND zuviel...

Code:

=WENN(C2<DATUM(2000;1;1);"Kunde seit 20 Jahren";WENN(UND(C2>DATUM(2000;1;1);C2<DATUM(2006;1;1));"Kunde seit 15-20 Jahren";WENN(UND(C2>DATUM(2006;1;1);C2<DATUM(2010;1;1));"Kunde seit 10-15 Jahren";WENN(UND(C2>DATUM(2010;1;1);C2<DATUM(2015;1;1));"Kunde seit 5-10 Jahren";""))))

Gruß,
steve1da

[Jockel]

Hallo, ungetestet... 

PHP-Code:

="Kunde seit "&VERWEIS(DATEDIF(C2;HEUTE();"y");{5.10.15.20};{"5-10"."10-15"."15-20"."20"})&" Jahren" 


Was soll denn passieren bei einem Datum wie z.B. 01.01.2010..?

[kutte44]

Ich möchte über eine Pivot am ende Darstellen, ob ein Kunde seit 5 , 10, 15 oder auch 20 Jahren Kunde ist.
Die Rohdaten kommen aus der IT.

[Jockel]

@ steve1da, ist das so geplant...? 

Arbeitsblatt mit dem Namen 'Tabelle2'
	B	C
2		01.01.2010

Zelle	Formel
B2	=WENN(C2<DATUM(2000;1;1);"Kunde seit 20 Jahren";WENN(UND(C2>DATUM(2000;1;1);C2<DATUM(2006;1;1));"Kunde seit 15-20 Jahren";WENN(UND(C2>DATUM(2006;1;1);C2<DATUM(2010;1;1));"Kunde seit 10-15 Jahren";WENN(UND(C2>DATUM(2010;1;1);C2<DATUM(2015;1;1));"Kunde seit 5-10 Jahren";""))))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[kutte44]

Hallo Jockel, danke dir. Hat einwandfrei funktioniert. und ich sitze hier seit Tagen.

---

Hast du auch noch eine lösung wie ich in die Formel Kunden integriere die noch unter 5 Jahren Kunde sind ?

[Jockel]

Hallo, so z.B.:

PHP-Code:

=WENNFEHLER("Kunde seit "&VERWEIS(DATEDIF(C2;HEUTE();"y");{0.5.10.15.20};{"weniger als 5"."5-10"."10-15"."15-20"."20"})&" Jahren";"") 


[steve1da]

Hola,

@Jockel: hast Recht. Dann muss der TE entscheiden wann <= oder >= kommen muss.

Gruß,
steve1da

[kutte44]

Traumhaft. Danke Dir (euch). Hab bestimmt noch öfter mal eine Frage. Als VKL D/A/CH mit 50 MA ist sowas und Pivot mein täglich Brot.