bedingte Formatierung - Partnersuche

[coemm]

Hallo @all,

in Spalte A steht ein Name und den Spalten B,C,D jeweils ein gewünschter Partner. Wie muss die Formel für die bedingte Formatierung aussehen, wenn Name und Wunschpartner jeweils übereinstimmen? (Ich habe einige (nicht alle) mal farbig markiert).

Arbeitsblatt mit dem Namen 'Namen Sitzwunsch'
	A	B	C	D
1	Name	Partner 1	Partner 2	Partner 3
2	Moritz	Kristian	Benedikt	Leo
4	Lenn-Samuel	Julian TF	Moritz	Jonah
5	Janik	Colin	Luca	Kristian
6	Jakob G	Maximilian R	Jakob S
7	Dan	Lenn-Samuel	Luca	Jakob G
13	Maximilian K	Maximilian R	Luca	Jonah
16	Leo	Julian P	Benedikt	Janik
17	Kristian	Jakob S	Jakob G	Benedikt
18	Benedikt	Kristian	Leo
19	Kilian	Moritz	Anna Chiara
20	Colin	Lenn-Samuel
21	Julian P	Leo	Janik	Maximilian K
23	Maximilian R	Jonah	Luca	Maximilian K
24	Philipp	Leo	Kristian	Björn
25	Jonah	Maximilian R	Luca	Maximilian K
27	Jakob S	Jakob G	Kristian	Jonah
28	Luca	Maximilian R	Maximilian K	Dan
30	Julian TF	Jonah	Lenn-Samuel	Luca
31	Björn	Philipp	Lenn-Samuel	Benedikt

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[Der Steuerfuzzi]

Hallo,

für Zelle B2:
=NICHT(ISTFEHLER(VERGLEICH($A2;INDEX($B$2:$D$20;VERGLEICH(B2;$A$2:$A$20;0););0)))

[Elex]

Hi,

B2:D20   =ZÄHLENWENN(INDEX($B$2:$D$20;VERGLEICH(B2;$A$2:$A$20;0););$A2)


Für A fällt mir im Moment nichts besseres ein.
A2:A20    =WENNFEHLER(ZÄHLENWENN(INDEX($B$2:$D$20;VERGLEICH(B2;$A$2:$A$20;0););$A2);0)+WENNFEHLER(ZÄHLENWENN(INDEX($B$2:$D$20;VERGLEICH(C2;$A$2:$A$20;0););$A2);0)+WENNFEHLER(ZÄHLENWENN(INDEX($B$2:$D$20;VERGLEICH(D2;$A$2:$A$20;0););$A2);0)

oder doch A2:A20
=SUMMENPRODUKT((($A$2:$A$20=$B2)+($A$2:$A$20=$C2)+($A$2:$A$20=$D2))*(($B$2:$B$20=$A2)+($C$2:$C$20=$A2)+($D$2:$D$20=$A2)))

Gruß Elex

[coemm]

Danke für die gemachten Vorschläge:

A2:D20

=SUMMENPRODUKT((($A$2:$A$20=$B2)+($A$2:$A$20=$C2)+($A$2:$A$20=$D2))*(($B$2:$B$20=$A2)+($C$2:$C$20=$A2)+($D$2:$D$20=$A2)))

und

für Zelle B2:

=NICHT(ISTFEHLER(VERGLEICH($A2;INDEX($B$2:$D$20;VERGLEICH(B2;$A$2:$A$20;0););0)))

bzw.

=ZÄHLENWENN(INDEX($B$2:$D$20;VERGLEICH(B2;$A$2:$A$20;0););$A2)

funktionieren

[Der Steuerfuzzi]

Für Spalte A:

Code:

=SUMMENPRODUKT(((B2=$A$2:$A$20)+(C2=$A$2:$A$20)+(D2=$A$2:$A$20))*($B$2:$D$20=A2))