ersten abweichenden Wert in Zeile von rechts kommend suchen

[Beth Alumni]

Hallo Zusammen!

Ich stehe vor einem Problem, dass ich nur teilweise lösen konnte. Es sieht wiefolgt aus:

Die Lieferzeiten von Teilenummern können sich im Laufe der Quartale ändern.
Der aktuelle Betrachtungszeitraum ist in diesem beispiel das Quartal 4. Die Werte in Spalte H bekomme ich per Makro eingetragen.

nun zum Problem:

- Unter Spalte F soll der erste abweichende Wert zum betrachteten Quartal aufgeführt werden. Da die Betrachtung rückwirkend stattfindet, soll von rechts kommend der entsprechende Wert gesucht werden. Gibt es keinen abweichenden Wert, so soll der Wert aus Spalte H übernommen werden.

- In Spalte G soll eingetragen werden, in welchem Quartal der erste abweichende Wert auftaucht.


Leider komme ich gerade rein gar nicht weiter, über Vergleich() und Index() konnte ich bisher nichts brauchbaren basteln, evtl ist eine Lösung über VBA eleganter?


Ganz herzlichen Dank schonmal für jeglichen helfenden Gedankengang von euch!

[
Bild bitte so als Datei hochladen: Klick mich!
]

[BoskoBiati]

Hi,

Bilder sind wenig hilfreich um Hilfe zu leisten!

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	Teilenummer	Quartal 1	Quartal 2	Quartal 3	Quartal 4	erster abweichender Wert von rechts	Quartal der ersten Abweichung von rechts
2	A01	5	5	5	6	Quartal 3	Quartal 3
3	A02	7	7	7	7	keine Abweichung	keine Abweichung
4	A03	4	5	5	5	Quartal 1	Quartal 1
5	A04	5	5	5	5	keine Abweichung	keine Abweichung
6	A05	6	6	6	6	keine Abweichung	keine Abweichung
7	A06	3	3	8	8	Quartal 2	Quartal 2

Zelle	Formel
F2	=WENNFEHLER(INDEX($1:$1;VERWEIS(9;1/(B2:E2<>E2);SPALTE(B2:E2)));"keine Abweichung")
G2	=WENN(ZÄHLENWENN($B2:$E2;E2)=4;"keine Abweichung";(INDEX($1:$1;AGGREGAT(14;6;SPALTE($B2:$E2)/($B2:$E2<>E2);1))))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[chris-ka]

HI,

Arbeitsblatt mit dem Namen 'Tabelle1'
	F	G
1	erster abweichender Wert von rechts	Quartal der ersten Abweichung von rechts
2	5	Quartal 3
3	7	Keine Abweichung
4	4	Quartal 1
5	5	Keine Abweichung
6	6	Keine Abweichung
7	3	Quartal 2

Zelle	Formel
F2	=WENNFEHLER(VERWEIS(2;1/(B2:E2<>E2);B2:E2);E2)
G2	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B2:E2<>E2);B2:E2);"Keine Abweichung")}
F3	=WENNFEHLER(VERWEIS(2;1/(B3:E3<>E3);B3:E3);E3)
G3	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B3:E3<>E3);B3:E3);"Keine Abweichung")}
F4	=WENNFEHLER(VERWEIS(2;1/(B4:E4<>E4);B4:E4);E4)
G4	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B4:E4<>E4);B4:E4);"Keine Abweichung")}
F5	=WENNFEHLER(VERWEIS(2;1/(B5:E5<>E5);B5:E5);E5)
G5	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B5:E5<>E5);B5:E5);"Keine Abweichung")}
F6	=WENNFEHLER(VERWEIS(2;1/(B6:E6<>E6);B6:E6);E6)
G6	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B6:E6<>E6);B6:E6);"Keine Abweichung")}
F7	=WENNFEHLER(VERWEIS(2;1/(B7:E7<>E7);B7:E7);E7)
G7	{=WENNFEHLER("Quartal " &VERGLEICH(2;1/(B7:E7<>E7);B7:E7);"Keine Abweichung")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Zelle	Schriftart	Inhalt
F1	Arial	erster abweichender Wert von rechts
G1	Arial	Quartal der ersten Abweichung von rechts
F2	Arial	5
G2	Arial	Quartal 3
F3	Arial	7
G3	Arial	Keine Abweichung
F4	Arial	4
G4	Arial	Quartal 1
F5	Arial	5
G5	Arial	Keine Abweichung
F6	Arial	6
G6	Arial	Keine Abweichung
F7	Arial	3
G7	Arial	Quartal 2

Verwendete Systemkomponenten: [Windows (32-bit) NT :.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

die {} NICHT eingeben Formel mit Strg+Umschalt+Enter abschließen!

[Jockel]

Hi Chris, hier tut keine CSE-Formel not... Auf deinem Vorschlag aufbauend 

Code:

=WENNFEHLER(VERWEIS(2;1/(B2:E2<>E2);$B$1:$E$1);"keine Abweichung")

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1	Teilenummer	Quartal 1	Quartal 2	Quartal 3	Quartal 4	erster abweichender Wert von rechts	Quartal der ersten Abweichung von rechts	Wert aus betrachtetem Quartal4
2	A01	5	5	5	6	5	Quartal 3	6
3	A02	7	7	7	7	7	keine Abweichung	7
4	A03	4	5	5	5	4	Quartal 1	5
5	A04	5	5	5	5	5	keine Abweichung	5
6	A05	6	6	6	6	6	keine Abweichung	6
7	A06	3	3	8	8	3	Quartal 2	8

Zelle	Format	Wert
H1	"Wert aus betrachtetem Quartal"Standard	4

Zelle	Formel
F2	=WENNFEHLER(VERWEIS(2;1/(B2:E2<>E2);B2:E2);E2)
G2	=WENNFEHLER(VERWEIS(2;1/(B2:E2<>E2);$B$1:$E$1);"keine Abweichung")
H2	=INDEX(B2:E2;;$H$1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[chris-ka]

Moin,

stimmt danke!
btw, jetzt musste ich auch noch googeln um dein CSE zu übersetzen 
bis dato hatte ich diese Bezeichnung noch nicht verwendet!
....ich werde meine Konstrukte {} in Zukunft in eingedeutschter Form jetzt SUE nennen. :)