exel verweis

[evera]

Hallo Forum,
bin relativ am anfang meiner exel kentnisse...
und hab ein problem den ich nach stundenlangem probieren nicht lösen konnte,
hoffe auf euer hilfe.....

mein problem:

auf eine tabellenblatt habe ich zwei kleine tabellen mit jeweils 8 zeilen ( 1. tabele=h5:h12, 2. tabele=h15:h22)
im bereich von b10:b17 sollen die einträge von den zwei tabellen aufgelistet werden.
das problem ist folgendes:
in den beiden tabellen habe ich nicht immer die gleiche anzahl von infos...--> soll z.B. heissen in der 1. tabelle stehen mal 3 zeilen, mal 5 und ein anderes mal 7 zeilen voll.
das gleiche gilt auch für die 2. kleine tabelle (unterschiedliche anzahl von infos in den beiden tabellen).

bei der auflistung soll dann für jede abschnitt ein überschrift erzeugt werden.


hier ein beispiel:
daten in der 1 tabelle
vw
mazda
porsche

daten in der 2 tabelle
Josef
peter

in der auflistung (b10:b17)
marke (überschrift)
vw
mazda
porsche
freund (überschrift)
Josef
peter

ich hoffe das ich es erklären konnte....

kann man das problem ohne makro lösen oder muss man hier ein vba code schreiben....

ich danke euch schon im voraus....
gruss
evera

[Luffy]

Hallo,

so ?

Code:

=WENN(ZEILE(H1)>ANZAHL2(H:H);"";INDEX(H:H;KKLEINSTE(WENN(H$1:H$1000<>"";ZEILE($1:$1000));ZEILE(H1))))

ACHTUNG MATRIXFORMEL: DIESE MUSST DU MIT STRG+SHIFT+ENTER ABSCHLIEßEN!

[evera]

hallo luffy,
danke für die schnelle rückmeldung... :100: 

werde s gleich mal probieren, aber ich hätte eine frage:
wo gibt diese formel die überschriften aus?...
danke nochmls....
gruss
evera

[Luffy]

wo gibt diese formel die überschriften aus?...

Hallo,

Wenn du die Überschrift oberhalb der Rohdaten Schreibst werden sie mit übernommen.

so zB:


Tabelle1

	H
4	Marke
5	VW
6	Mazda
7	Porsche
8
9
10
11
12
13
14	Freund
15	Josef
16	Peter
17
18
19
20
21
22

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.15 einschl. 64 Bit

[evera]

:100: :100: :100: :100: :100: :100: :100: :100: 
SUPER:....SUPER:....SUPER:....SUPER:....SUPER:....SUPER:....SUPER:....SUPER:....
VIELEN DANK......
Fuktionert perfekt....
Vielen Vielen Dank...........


Grusss
evera

[Jockel]

Hallo, ich würde AGGREGAT() nehmen..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	H	I	J	K
4	Marke		Marke	Marke
5	VW		VW	VW
6	Mazda		Mazda	Mazda
7	Porsche		Porsche	Porsche
8			Freund	Freund
9			Josef	Josef
10			Peter	Peter
11
12
13
14	Freund
15	Josef
16	Peter
17

Zelle	Formel
J4	{=WENN(ZEILE(H1)>ANZAHL2(H:H);"";INDEX(H:H;KKLEINSTE(WENN(H$1:H$1000<>"";ZEILE($1:$1000));ZEILE(H1))))}
K4	=WENNFEHLER(INDEX($H$4:H22;AGGREGAT(15;6;ZEILE($H$4:$H$22)-3/($H$4:H22<>"");ZEILE(A1)));"")

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[evera]

hallo Jockel und Luffy,
erstmal vielen dank für die lösungsvorschläge.....

hab jetzt aber in der praxis folgendes problem entdeckt....

wenn in meinem 1. tabelle garnichts steht (im beispiel von h4:H12) sollte es dann in der auflistung (b10:b17) dann gleich die daten von der 2. tabelle (im beispiel h14:h22) aufgelistet werden....

wäre das noch machbar.....

vilen dank....
grüsse
evera

[Luffy]

Hallo,

dann würde ich anstatt "Marke" und "Freund" eine Formel einsetzen.


Tabelle1

	H
4	Marke
5	VW
6	Mazda
7	Porsche
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22

verwendete Formeln
Zelle	Formel	Bereich	N/A
H4	=WENN(ZÄHLENWENN(H5:H12;"*")>0;"Marke";"")
H14	=WENN(ZÄHLENWENN(H15:H22;"*")>0;"Freund";"")

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.15 einschl. 64 Bit

Sprich: Wenn die Felder befüllt sind, schreibe in die Zelle "Marke" oder "Freund" ansonsten leer ("").

dann müsstest du meine andere Formel erweitern und zwar so:

Code:

=WENNFEHLER(WENN(ZEILE(H1)>ANZAHL2(H:H);"";INDEX(H:H;KKLEINSTE(WENN(H$1:H$1000<>"";ZEILE($1:$1000));ZEILE(H1))));"")

ACHTUNG MATRIXFORMEL: DIESE MUSST DU MIT STRG+SHIFT+ENTER ABSCHLIEßEN!

oder du nimmst die Formel von Jörg die Funktioniert ohne sie ab zu ändern

Code:

=WENNFEHLER(INDEX($H$4:H22;AGGREGAT(15;6;ZEILE($H$4:$H$22)-3/($H$4:H22<>"");ZEILE(A1)));"")

[evera]

Also ich bin sprachlos.......
wahnsinnnnnnn..
natürlich funktioniert es.......
vielen vielen dank........
super....

ich wünschte ich könnte mich revanchieren....

wenn ich euch bei photoshop helfen kann bitte nicht zögern.....

nochmals vielen dank
gruss
evera