">=" in Zelle bei =zählenwenns als Kriterium

[MT1986]

Hallo zusammen,
ich habe folgendes Problem:
Ich habe eine Tabelle mit Daten und möchte eine =zählenwenns Funktion verwenden (Anhang B2), wenn zwei Kriterien erfüllt sind. Das Problem ist, dass ein Kriterium ">=1 Tag" ist (Anhang F3). Dabei bekomme ich ein falsches Ergebnis (4 statt 3, siehe Anhang rot B2 und grün markiert B3), weil wahrscheinlich irgendwie das ">=" als mathematisches Zeichen und nicht als Text gesehen wird (siehe Anhang Tabelle links, Spalte A bis F). Die Zellen als Text zu definieren habe ich auch schon erfolglos probiert. Wenn ich statt ">=1 Tag", "größer gleich 1 Tag" schreibe funktioniert die Formel natürlich (siehe Anhang Tabelle rechts, Spalte H bis M). 
Habt ihr eine Lösung ohne "größer gleich 1 Tag" und ohne extra Hilfsspalten? 
Aktuell lautet die Formel so: 
=ZÄHLENWENNS(A:A;$E$2;B:B;$F$3)

Vielen Dank im Voraus für eure Mühen.

Schöne Grüße und bleibt gesund.
Michael

[steve1da]

Hola,
Zählenwenns() stört sich scheinbar daran - Summenprodukt() nicht.

Code:

=summenprodukt((A7:A17=E2)*(B7:B16=F3))

Gruß,
steve1da

[Rudi'S]

Hallo Michael,

ich habe deine Aufgabe mal etwas ausgearbeitet.
In Zelle A2 wird die Zusammenfassung der beiden Bedingungen angesetzt und in B2 werden die Werte mit der Formel 

=WENN(LINKS(A2;4)="Wege";SUMMENPRODUKT((LINKS(A7:A16;4)="Wege")*(RECHTS(B7:B16;3)="Tag"));WENN(TEIL(A2;8;3)="mit";SUMMENPRODUKT((LINKS(A7:A16;10)="Unfall mit")*(LINKS(B7:B16;1)=">"));SUMMENPRODUKT((LINKS(A7:A16;11)="Unfall ohne")*(LINKS(B7:B16;1)=">")) ) )

für die Bedingungen mit mehr als / gleich einem Tag berechnet.

Gruß Rudi

[echo]

hallo
durch das zusammenführen der Spalten fehlen Leerzeichen, dadurch passt der Vergleich in summenprodukt nicht.
Wenn man ein Leerzeichen einfügt funktioniert das.
Glätten() löscht ggf. noch unnötige Leerzeichen:

=SUMMENPRODUKT((GLÄTTEN(A7:A16&" "&B7:B16)=GLÄTTEN(A2))*1) 

Gruß Holger

[Rudi'S]

Hallo Holger,

zu meiner Ehrenrettung sei gesagt, dass die Formel schon funktioniert, aber Profis bringen das halt auf einen kurzen Formelansatz.
So habe ich nicht um die Ecke gedacht. Wieder was gelernt. Danke.

Gruß Rudi

[echo]

Hallo Rudi
Ich finde das Ergebnis ist das Ziel, und das passt! 

Zuerst habe ich geglaubt das Summenprodukt nicht funkioniert weil im Beispiel oben die Matrizen nicht gleich groß sind.
Als es immer noch nicht ging, wollte ich halt wissen wo der Fehler liegt

Gruß Holger

[steve1da]

Ups, in meiner Formel stimmen die Bereiche nicht:

Code:

=summenprodukt((A7:A16=E2)*(B7:B16=F3))

Schade aber, dass der TE keinerlei Feedback gibt.

[BoskoBiati]

Hi,

das Ganze funktioniert auch mit Zählenwenns, allerdings muß in F3 folgender Ausdruck stehen:

'+>= 1 Tag

[MT1986]

Das summenprodukt hat das Problem gelöst:
=summenprodukt((A7:A16=E2)*(B7:B16=F3))

Funktioniert prima ohne viel Aufwand.
Vielen Dank steve1da und auch an die anderen Helfer :)

Schöne Grüße