Registriert seit: 24.02.2017
Version(en): 365; (2013)
31.08.2018, 09:40
(Dieser Beitrag wurde zuletzt bearbeitet: 31.08.2018, 09:41 von StrammerMax.)
Hey Leute,
ich habe eine Tabelle mit einer Spalte in der Termine stehen.
Nun möchte ich diese Termine in einer neuen Spalte dem richtigen Geschäftsjahr zuweisen.
Das GJ geht jeweils von 01.04. - 31.03.
Der Termin 15.04.2018 wäre somit GJ19.
Der Termin 29.03.2018 wäre noch GJ18.
In der neuen Spalte sollte dann beim 15.04.2018 GJ19 stehen.
Ich habe folgendes:
=WENN(JAHR([@Termin]<2007)+MONAT([@Termin]>3);"GJ07";WENN(JAHR([@Termin]<2008)+MONAT([@Termin]<4);"GJ07";WENN(JAHR([@Termin]<2008)+MONAT([@Termin]>3);"GJ08";WENN(JAHR([@Termin]<2009)+MONAT([@Termin]<4);"GJ08";WENN(JAHR([@Termin]<2009)+MONAT([@Termin]>3);"GJ09";WENN(JAHR([@Termin]<2010)+MONAT([@Termin]<4);"GJ09";WENN(JAHR([@Termin]<2010)+MONAT([@Termin]>3);"GJ10";WENN(JAHR([@Termin]<2011)+MONAT([@Termin]<4);"GJ10";""))))))))
Das wirft mir aber bei jedem X-beliebigen Termin "GJ07" aus.
Hat jemand eine elegante Lösung dafür?
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo, das geht bestimmt einfacher, aber quick & dirty..:
Code:
="GJ"&RECHTS(JAHR(B14)+(B14>--(4&-JAHR(B14)));2)
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:1 Nutzer sagt Danke an Jockel für diesen Beitrag 28
• StrammerMax
Registriert seit: 24.02.2017
Version(en): 365; (2013)
Perfekt - vielen Dank :)
Da wäre ich in 100 Jahren nicht drauf gekommen.
Registriert seit: 13.04.2014
Version(en): 365, 2019
31.08.2018, 10:10
(Dieser Beitrag wurde zuletzt bearbeitet: 31.08.2018, 10:37 von BoskoBiati.)
Hi,
oder so:
Arbeitsblatt mit dem Namen 'Auswertung' |
| K | L |
16 | 31.03.17 | GJ16 |
17 | 01.04.17 | GJ17 |
18 | 31.03.18 | GJ17 |
19 | 01.04.18 | GJ18 |
20 | 31.03.19 | GJ18 |
21 | 01.04.19 | GJ19 |
Zelle | Formel |
L16 | ="GJ"&RECHTS(JAHR(EDATUM(K16;-3));2) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Es wäre auch mit einer WENN-Formel gegangen, aber Deine Formel war vom Aufbau her schon völlig falsch. Hier mal eine korrigierte Fassung, eine falsche und eine richtige:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| K | L | M | N |
2 | Termin | GJ | Spalte1 | Spalte2 |
3 | 31.03.07 | GJ06 | GJ07 | GJ06 |
4 | 01.04.07 | GJ07 | GJ08 | GJ07 |
5 | 31.03.08 | GJ07 | GJ08 | GJ07 |
6 | 01.04.08 | GJ08 | GJ09 | GJ08 |
7 | 31.03.09 | GJ08 | GJ09 | GJ08 |
8 | 01.04.09 | GJ09 | GJ10 | GJ09 |
Zelle | Formel |
L3 | ="GJ"&RECHTS(JAHR(EDATUM(K3;-3));2) |
M3 | =WENN((JAHR([@Termin])<2007)*(MONAT([@Termin])>3);"GJ07";WENN((JAHR([@Termin])<2008)*(MONAT([@Termin])<4);"GJ07";WENN((JAHR([@Termin])<2008)*(MONAT([@Termin])>3);"GJ08";WENN((JAHR([@Termin])<2009)*(MONAT([@Termin])<4);"GJ08";WENN((JAHR([@Termin])<2009)*(MONAT([@Termin])>3);"GJ09";WENN((JAHR([@Termin])<2010)*(MONAT([@Termin])<4);"GJ09";WENN((JAHR([@Termin])<2010)*(MONAT([@Termin])>3);"GJ10";WENN((JAHR([@Termin])<2011)*(MONAT([@Termin])<4);"GJ10";"")))))))) |
N3 | =WENN((JAHR([@Termin])=2007)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2008)*(MONAT([@Termin])<4);"GJ07";WENN((JAHR([@Termin])=2008)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2009)*(MONAT([@Termin])<4);"GJ08";WENN((JAHR([@Termin])=2009)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2010)*(MONAT([@Termin])<4);"GJ09";WENN((JAHR([@Termin])=2010)*(MONAT([@Termin])>3)+(JAHR([@Termin])=2011)*(MONAT([@Termin])<4);"GJ10";"GJ06")))) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Dieser Term enthält schon mehrere Fehler:
WENN(JAHR([@Termin]<2007)+MONAT([@Termin]>3)
Richtig wäre das:
WENN(
(JAHR([@Termin]
)=2007)
&(MONAT([@Termin]
)>3)
Gruß
Edgar
Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo, oder so..:
Code:
="GJ"&RECHTS(JAHR(B14)+(MONAT(B14)>3);2)
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:1 Nutzer sagt Danke an Jockel für diesen Beitrag 28
• StrammerMax
Registriert seit: 09.09.2017
Version(en): O365
hallo
beide Formeln haben Flüchtigkeitsfehler, Jockels Formel trifft den Übergang am 1.4 nicht
="GJ" & RECHTS(JAHR(A1) + (A1 >= --(4 & -JAHR(A1)));2)
und Boskos GJ hinkt ein Jahr hinterher
="GJ" & RECHTS(JAHR(EDATUM(A1;-3)) +1;2)
meine Formel ist etwas nachvollziehbarer, ich würde mich selbst aber für Bosko's Lösung entscheiden
="GJ" & RECHTS(JAHR(A1) + (MONAT(A1)>3);2)
Willie
Registriert seit: 13.04.2014
Version(en): 365, 2019
31.08.2018, 10:40
(Dieser Beitrag wurde zuletzt bearbeitet: 31.08.2018, 10:40 von BoskoBiati.)
Hallo Willie,
Zitat:und Boskos GJ hinkt ein Jahr hinterher
halte ich aber sehr für ein Gerücht!
Der 31.3.17 gehört zum Geschäftsjahr 2016!
Und noch eine Variante:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| K | L |
2 | Termin | GJ |
3 | 31.03.07 | GJ06 |
Zelle | Formel |
L3 | =RECHTS(JAHR(EDATUM(K3;-3));2)*1 |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Gruß
Edgar
Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Registriert seit: 10.04.2014
Version(en): Office 2019
31.08.2018, 10:45
(Dieser Beitrag wurde zuletzt bearbeitet: 31.08.2018, 10:45 von Jockel.)
(31.08.2018, 10:30)Willie017 schrieb: hallo
...
meine Formel ist etwas nachvollziehbarer...
Hallo, komisch ich sehe
deine Formel gar nicht... ... ich hatte zwischen zeitlich "verschlimmbessert"... Der TE wird sich sicher selber entscheiden können...
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Registriert seit: 13.04.2014
Version(en): 365, 2019
Hi,
Formel von Willie korrigiert:
Code:
="GJ" & RECHTS(JAHR(A2)-(MONAT(A2)<4);2)
Gruß
Edgar
Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Registriert seit: 11.03.2015
Version(en): mittlerweile meistens 2019
31.08.2018, 10:50
(Dieser Beitrag wurde zuletzt bearbeitet: 31.08.2018, 10:51 von Der Steuerfuzzi.)
(31.08.2018, 10:40)BoskoBiati schrieb: Der 31.3.17 gehört zum Geschäftsjahr 2016!
Das ist nicht falsch, aber Ansichtssache. Aus dem OP geht folgendes hervor:
Zitat:Der Termin 15.04.2018 wäre somit GJ19.
Der Termin 29.03.2018 wäre noch GJ18.
Damit hinkt Deine Formel tatsächlich hinterher.
Gruß
Michael