verschiedene Ansichten auf verschiedenen Reitern

[palatzfl]

Hallo liebe Community,

ich sitze seit ein paar Tagen an einem Problem, bei welchem ich nicht weiter komme; und hoffe nun auf Hilfe.
Folgende Ausgangssituation:

Ich habe eine Tablle (Reiter Gesamttabelle), in welcher leer stehende Wohnungen aufgelistet sind.
Die erste Spalte stellt die Wohnungs-ID dar, die weiteren Spalten beinhalten Adresse, sowie, welche Daten mir bereits vorliegen (Grundriss, Bilder, etc.).

Nun möchte ich auf einem weiteren Reiter eine Auflistung aller Wohnungen sehen, welche beispielsweise noch keinen Grundriss, noch keine Bilder haben.
In den Feldern steht dann jeweils der Begriff "fehlt".
Mit einer Pivot-Tabelle bin ich bis dato kläglich gescheitert. Ist es damit überhaupt umsetzbar?

Eine Auflistung, welche Dokumente etc. pro ID fehlen, konnte ich bereits mit einem SVerweis umsetzen (Reiter Datenblatt-Vorlage).
Bei dem oben beschriebenen ist jedoch der SVerweis nicht brauchbar, oder?


Könnt ihr mir weiterhelfen?


Viele Liebe Grüße

Flo

PS. Im Anhang habe ich die bisherige Tabelle der Übersicht halber hinzugefügt.

[shift-del]

Hallo

Füge der Tabelle "Uebersicht" eine weitere Spalte hinzu:

Code:

=ZÄHLENWENNS(Uebersicht[@[Immo ID]:[Online-Stand]];"fehlt")>1

Und dann auf WAHR filtern.

[palatzfl]

Moin,

besten Dank für deine Antwort.
Eine andere Möglichkeit gibt es nicht, oder?

Gruß
Flo

[shift-del]

Es gibt - fast - immer mehrere Möglichkeiten in Excel.
Die Frage ist nur was dir an der genannten Lösung nicht gefällt.

[palatzfl]

Es gibt - fast - immer mehrere Möglichkeiten in Excel.
Die Frage ist nur was dir an der genannten Lösung nicht gefällt.

Das Problem ist, dass im Endeffekt 2500 Wohnungen dort drin stehen werden.
Nun soll jedoch auf einer Extra Seite (Reiter "Datenblatt-Vorlage",
  Immobilien-Gesamt-Auflistung-Export-Clever-Forum.xlsx (Größe: 18,21 KB / Downloads: 4) ) die jeweiligen IDs aufgelistet werden
Im Idealfall würde das dann so wie im Anhang aussehen, nur das es jetzt halt von Hand eingetragen ist.

Ist das so überhaupt umsetzbar?
Vielleicht sogar so, dass sowohl die jeweiligen IDs zu den Rubriken angezeigt werden,
als auch beispielsweise alle IDs, wo nur 2, oder 3 "fehlen".

Lieben Gruß
Flo

[shift-del]

Nun soll jedoch auf einer Extra Seite (Reiter "Datenblatt-Vorlage",  ) die jeweiligen IDs aufgelistet werden
Im Idealfall würde das dann so wie im Anhang aussehen, nur das es jetzt halt von Hand eingetragen ist.

Da dein Beispiel offenbar unvollständig ist rate ich mal.

Arbeitsblatt mit dem Namen 'Datenblatt-Vorlage'
	AE	AF
3	Spalte	WohnungsIDs
4	QM	2, 3
5	Foto-Termin	1
6	Grundrisse	1

Zelle	Formel
AE4	=WENNFEHLER(INDEX(Uebersicht[[#Kopfzeilen];[Straße]:[Online-Stand]];AGGREGAT(15;6;(SPALTE(Uebersicht[[#Ergebnisse];[Straße]:[Online-Stand]])-4)/Uebersicht[[#Ergebnisse];[Straße]:[Online-Stand]];ZEILE(A1)));"")
AF4	{=WENN(AE4="";"";TEXTVERKETTEN(", ";WAHR;WENNFEHLER(INDEX(Uebersicht[Immo ID];N(WENN(1;1/(1/WENN(INDIREKT("Uebersicht["&AE4&"]")="fehlt";ZEILE(Uebersicht[Immo ID])-9)))));"")))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[palatzfl]

Da dein Beispiel offenbar unvollständig ist rate ich mal....

Hallo Shift-Del,

vielen Lieben Dank für die Formel! Du hast mir mega weitergeholfen.
Ich danke dir!!!

Einen schönen Abend.

Flo