wenn mit max verbinden

[lernen]

Hallo zusammen,
ich lerne, oder versuche mein Excel kentnisse zu verbessern.
Nun habe ich folgendes problem, ich habe eine Tabelle erstellt mit Beispiel Werten.
Im Bereich B2 bis D6 stehen Teilnehmer zahlen.
A1 = Kurse            B1 = Januar      C1 = Februar         D1 = März
A2 = Deutsch       B2 = 230           C2 = 210               D2 = 450
A3 = Englisch        B3 = 430          C3 = 190               D3 = 150
A4 = Französisch  B4 = 360           C4 = 340               D4 = 120
A5 = Griechisch    B5 = 220           C5 = 70                 D5 = 80
A6 = Holländisch   B6 = 75            C6 = 53                 D6 = 22
Weiter unten steht folgendes:
A9 Teilnehmer Gesamt                 B9 =SUMME(B2 : D6)
A10 Teilnehmer Durchschnitt       B10 =MITTELWERT(B 2: D6)
A11 Bester Kurs                           B11 =MAX(B2 : D6)
A12 Schwächster Kurs                 B12 =MIN(B2 : D6)
A13 Anzahl Kurse                         B13 =ANZAHL2(A2 : A6)
Natürlich sind bei den Formeln keine Leerzeichen!
Nun möchte ich in C11 und C12 je eine Formel, die mir bezugnehmend auf B11 oder B12 den dazugehörigen Kurs gibt.
Ich hoffe ich habe mich verständlich ausgedrückt. Vielen Dank schon mal im Voraus.

[WillWissen]

Hi,

hier mal ein Vorschlag mit je 2 Hilfszeilen- und Spalten, die du einfach ausblenden kannst.

Tabelle6

	A	B	C	D	E	F
1	Kurse	Januar	Februar	März	HS-Kurs -	HS-Kurs +
2	Deutsch	230	210	450		2
3	Englisch	430	190	150
4	Französisch	360	340	120
5	Griechisch	220	70	80
6	Holländisch	75	53	22	6
7	HS-Zeile bester			4
8	HS-Zeile schwächster			4
9
10	Teiln. Ges.	3000
11	Teiln. MW	200
12	bester Kurs	450	Deutsch/März
13	schwächster Kurs	22	Holländisch/März
14	Anz. Kurse	15

Formeln der Tabelle

Zelle Formel E2 =WENN(ISTZAHL(VERGLEICH($B$13;$A2:$D2;0));ZEILE();"") F2 =WENN(ISTZAHL(VERGLEICH($B$12;$A2:$D2;0));ZEILE();"") E3 =WENN(ISTZAHL(VERGLEICH($B$13;$A3:$D3;0));ZEILE();"") F3 =WENN(ISTZAHL(VERGLEICH($B$12;$A3:$D3;0));ZEILE();"") E4 =WENN(ISTZAHL(VERGLEICH($B$13;$A4:$D4;0));ZEILE();"") F4 =WENN(ISTZAHL(VERGLEICH($B$12;$A4:$D4;0));ZEILE();"") E5 =WENN(ISTZAHL(VERGLEICH($B$13;$A5:$D5;0));ZEILE();"") F5 =WENN(ISTZAHL(VERGLEICH($B$12;$A5:$D5;0));ZEILE();"") E6 =WENN(ISTZAHL(VERGLEICH($B$13;$A6:$D6;0));ZEILE();"") F6 =WENN(ISTZAHL(VERGLEICH($B$12;$A6:$D6;0));ZEILE();"") B7 =WENN(ISTZAHL(VERGLEICH($B$12;B$1:B$6;0));SPALTE();"") C7 =WENN(ISTZAHL(VERGLEICH($B$12;C$1:C$6;0));SPALTE();"") D7 =WENN(ISTZAHL(VERGLEICH($B$12;D$1:D$6;0));SPALTE();"") B8 =WENN(ISTZAHL(VERGLEICH($B$13;B$1:B$6;0));SPALTE();"") C8 =WENN(ISTZAHL(VERGLEICH($B$13;C$1:C$6;0));SPALTE();"") D8 =WENN(ISTZAHL(VERGLEICH($B$13;D$1:D$6;0));SPALTE();"") B10 =SUMME($B$2:$D$6) B11 =MITTELWERT($B$2:$D$6) C12 =INDEX($A$1:$A$6;MAX($F$2:$F$6))&"/"&INDEX($A$1:$D$1;;MAX($B$7:$D$7)) C13 =INDEX($A$1:$A$6;MAX($E$2:$E$6))&"/"&INDEX($A$1:$D$1;;MAX($B$8:$D$8)) B14 =ANZAHL($B$2:$D$6)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[atilla]

Hallo,

passt das so:

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D
1	Kurse	Januar	Februar	März
2	Deutsch	230	210	450
3	Englisch	430	190	150
4	Französisch	360	340	120
5	Griechisch	220	70	80
6	Holländisch	75	53	22
7	unten
8
9	Teilnehmer Gesamt	3000
10	eilnehmer Durchschnitt	200
11	Bester Kurs	450	Deutsch	März
12	Schwächster Kurs	22	Holländisch	März

Zelle	Formel
B9	=SUMME(B2:D6)
B10	=MITTELWERT(B2:D6)
B11	=MAX(B2:D6)
C11	{=INDEX(A:A;MIN(WENN($B$2:$D$6=B11;ZEILE($2:$6))))}
D11	{=INDEX(1:1;MIN(WENN(B2:D6=B11;SPALTE(B:D))))}
B12	=MIN(B2:D6)
C12	{=INDEX(A:A;MIN(WENN($B$2:$D$6=B12;ZEILE($2:$6))))}
D12	{=INDEX(1:1;MIN(WENN(B2:D6=B12;SPALTE(B:D))))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Beim schwächsten Kurs brauchte man eigentlich keine Formel, war doch klar :19: