zählewenn und + oder

[paul227]

Hallo zusammen,

ich brauche bitte eure Hilfe

Ich möchte das Excel alle zahlen nur einml zählt die folgende Kriterien erfüllen:

• J5:J12 sollen <=4 sein und in dem Bereich Z5:Z12 sollen die Wörter "open" oder "ongoing" oder "monitored" stehen. Wenn dies nicht zutrifft also J5:J12 größer als 4 ist und in Z5:Z12 das Wort "closed" steht soll Excel nicht mitzählen.
  
• Der Bereich J5:J12 sollen >=5 oder <=12 sein und in dem Bereich Z5:Z12 sollen die Wörter "open" oder "ongoing" oder "monitored" stehen.
  

Ich hoffe ihr könnt damit etwas anfangen.

Vielen dank und eine gute HomeOffice zeit euch allen 

[Statler]

Hallo,

in deiner Beschreibung ist ein kleiner Fehler:
"Der Bereich J5:J12 sollen >=5 oder <=12 "
Das muß "Der Bereich J5:J12 sollen >=5 UND <=12 " heißen, sonst macht es keinen Sinn (jede Zahl ist entweder >=5 oder <=12) - aber das nur am Rande.

Ich habe in einer Spalte jeweils die Formeln eingetragen:

   =WENN(UND(J5<=4;ODER(Z5="open";Z5="ongoing";Z5="monitored"));1;WENN(UND(J5>=5;J5<=12;UND(ODER(Z5="open";Z5="ongoing";Z5="monitored")));1;0))

Die Fomeln nach unten ziehen, so dass sie für alle Zeilen von J5 bis J12 gelten
und dann in der nächsten darunterliegenden Zelle die Formel

=ZÄHLENWENN(AC5:AC12;1)

Sollte funktionieren.

Gruß
Statler

---

Noch eine Anmerkung,

auf das Wort "closed" zu prüfen macht nur Sinn, wenn dort neben den aufgezählten "positiven" Einträgen (open, ongoing, monitored) und dem Eintrag "closed" noch andere Einträge möglich sind.
Wenn das nicht der Fall ist und nur diese 4 Einträge möglich sind, dann ist ohnehin klar, dass wenn die drei positiven Einträge nicht dort stehen, dass dann dort closed stehen muß.

Wenn es möglich ist, dass nichts dort steht, dann könnte man noch die Abfrage auf "" hinzufügen!?

Gruß
Statler

[paul227]

Vielen dank Statler,

ich verstehe was du meinst.

Ich möchte aber nicht nur eine 1 oder 0 ausgegeben bekommen.

Ich möchte in einem Dashboard alle Fälle Zählen lassen, wo die Kriterien zutreffen.

Wenn ich es so machen würde wie du es beschrieben hast, dann müsste ich ja immer wieder extra Spalten in die Tabelle einfügen, wo mir jeweils eine 1 und 0 ausgegeben wird. Im Dashboard würde ich diese dann zusammen zählen. (Schätze es gibt da einen einfacheren weg)

Kann ich nicht auch das WENN durch ZÄHLEWENN ersetzen, so das Excel alle diese Werte zählt, die den Kriterien (wie in der Formel aufgestellt) entsprechen Bepw. im abschnitt J5:J12 ?

[Statler]

Das geht meiner Meinung nach nur nach 2 Methoden.

1. über eine Programmierung mit VBA
2. über eine Matrix-Formel.

Für beides bräuchte ich etwas Zeit zur Erstellung. Vielleicht kann jemand anderes noch helfen oder hat eine bessere Idee auf die ich noch nicht gekommen bin. Für beides wäre es hilfreich zu wissen, ob und wie weit die Zellbereiche J5-j12 und z5-z12 fix sind oder in wie weit diese erweitert werden müssten.

Gruß
Statler

[Statler]

Es geht natürlich auch mit folgender Formel - ganz so wie gewünscht

=SUMME(WENN(WENN(UND(J5<=4;ODER(Z5="open";Z5="ongoing";Z5="monitored"));1;WENN(UND(J5>=5;J5<=12;UND(ODER(Z5="open";Z5="ongoing";Z5="monitored")));1;0))=1;1;0);WENN(WENN(UND(J6<=4;ODER(Z6="open";Z6="ongoing";Z6="monitored"));1;WENN(UND(J6>=5;J6<=12;UND(ODER(Z6="open";Z6="ongoing";Z6="monitored")));1;0))=1;1;0);WENN(WENN(UND(J7<=4;ODER(Z7="open";Z7="ongoing";Z7="monitored"));1;WENN(UND(J7>=5;J7<=12;UND(ODER(Z7="open";Z7="ongoing";Z7="monitored")));1;0))=1;1;0);WENN(WENN(UND(J8<=4;ODER(Z8="open";Z8="ongoing";Z8="monitored"));1;WENN(UND(J8>=5;J8<=12;UND(ODER(Z8="open";Z8="ongoing";Z8="monitored")));1;0))=1;1;0);WENN(WENN(UND(J9<=4;ODER(Z9="open";Z9="ongoing";Z9="monitored"));1;WENN(UND(J9>=5;J9<=12;UND(ODER(Z9="open";Z9="ongoing";Z9="monitored")));1;0))=1;1;0);WENN(WENN(UND(J10<=4;ODER(Z10="open";Z10="ongoing";Z10="monitored"));1;WENN(UND(J10>=5;J10<=12;UND(ODER(Z10="open";Z10="ongoing";Z10="monitored")));1;0))=1;1;0);WENN(WENN(UND(J11<=4;ODER(Z11="open";Z11="ongoing";Z11="monitored"));1;WENN(UND(J11>=5;J11<=12;UND(ODER(Z11="open";Z11="ongoing";Z11="monitored")));1;0))=1;1;0);WENN(WENN(UND(J12<=4;ODER(Z12="open";Z12="ongoing";Z12="monitored"));1;WENN(UND(J12>=5;J12<=12;UND(ODER(Z12="open";Z12="ongoing";Z12="monitored")));1;0))=1;1;0))

Is halt nur ein wenig unübersichtlich (auch wenn´s funktioniert) - da fand' ich die Lösung mit der zusätzlichen Spalte sehr viel übersichtlicher

Gruß
Statler

[GeorgH]

Hallo,

folgende Formel zählt alle Übereinstimmungen wenn:
(J5:J12<=12) und (Z5:Z12 = "open" oder "ongoing" oder "monitored")
wenn z.B. die Zahl 2 mehrfach mit "open" oder "ongoing" oder "monitored" vorkommen würde, würde diese mehrfach gezählt

=SUMMENPRODUKT(($J$5:$J$12>0)*($J$5:$J$12<=12)*ISTZAHL(VERGLEICH($Z$5:$Z$12;{"open";"ongoing";"monitored"};0)))


Wenn jede Zahl nur einmal gezählt werden soll, wenn "open" oder "ongoing" oder "monitored" --> dann folgende Matrix-Formel:

{=SUMME(--(HÄUFIGKEIT(WENNFEHLER($J$5:$J$12/(($J$5:$J$12>0)*($J$5:$J$12<=12)*ISTZAHL(VERGLEICH($Z$5:$Z$12;{"open";"ongoing";"monitored"};0)));"");WENNFEHLER($J$5:$J$12/(($J$5:$J$12>0)*($J$5:$J$12<=12)*ISTZAHL(VERGLEICH($Z$5:$Z$12;{"open";"ongoing";"monitored"};0)));""))>0))}

(geschweifte Klammer nicht mit eingeben, Formel mit Shift + Strg + Enter abschließen)

Probier es mal aus 

Viele Grüße
Georg