zeitliche Nutzungsbegrenzung

[Julzact]

Hallo zusammen,
ich habe mal eine generelle Frage.

Ist es möglich, in einer Excel Tabelle eine zeitliche Begrenzung für die Nutzung einzufügen?

Die Problemstellung ist:
Es gibt eine Datei, die von mehreren Leuten über einen Server benutzt wird.
Wenn einer die Datei geöffnet hat, können andere nur schreibgeschützt darauf zugreifen, das ist auch gut so.
Manchmal kommt es aber vor, das jemand die Liste öffnet und vergisst sie wieder zu schließen.
Jetzt wäre es toll, wenn man die Tabelle nach z.B. 10 Minuten des nichtnutzens schließt.

Danke für eure Hilfe !

[nitrosworld]

Hallo,

dazu kann man die Funktion Application.OnTime verwenden.
Hier mal ein Bsp.
Dieser Code kommt ins Klassenmodul "DieseArbeitsmappe":

Code:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
   KillTimer
End Sub

Private Sub Workbook_Open()
   SetTimer
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
   KillTimer
   SetTimer
End Sub

Dieser Code kommt in ein Modul:

Code:

Option Explicit
Option Private Module

Global sTime As Date

Public Sub KillTimer()
   On Error Resume Next
   Application.OnTime sTime, "closeWb", , False
   On Error GoTo 0
End Sub

Public Sub SetTimer()
   sTime = Now + TimeValue("00:01:00")
   Application.OnTime sTime, "closeWb"
   Debug.Print "Excel-File wird geschlossen um: " & sTime
End Sub

Public Sub closeWb()
   ThisWorkbook.Close True  'True wenn beim Schliessen gespeichert werden, False wenn nicht
End Sub

[Julzact]

Hallo Nitrous,
danke für deine schnelle Antwort.
Wie funktioniert das alles genau?
Wo kann man hier die Zeit einstellen bis zur Schließung?
Ich Habe das mal als Test eingebaut wie du geschrieben hast, die Mappe ließ sich allerdings nichtmehr speichern..

LG

[Rabe]

Hi,

Wie funktioniert das alles genau?
Wo kann man hier die Zeit einstellen bis zur Schließung?

hier eine Beispielmappe (genau wie von Nitro beschrieben) mit Markierung der Zeile für die Dauer bis zur Schließung.

  Datei automatisch schließen bei Nichtbenutzung.xlsb (Größe: 15,55 KB / Downloads: 8)