zellenformel mit mehreren Bedingungen

[Maximus]

Hallo Experten,
habt ihr eine Idee.

Folgende Bedingungen:

Wenn in Spalte DC in zwei Zellen untereinander eine 0 steht soll in DF2 1 addiert werden.
Wenn in Spalte DC in drei Zellen untereinander eine 0 steht soll in DF2 2 addiert werden.
Wenn in Spalte DC in vier oder mehr Zellen untereinander eine 0 steht soll in DF2 3 addiert werden.
Es kann immer pro Serie in DC eine Bedingung zur Anwendung kommen.
Wenn Bedingung 3, „Wenn in Spalte DC in vier oder mehr Zellen untereinander eine 0 steht,soll in DF2 3 addiert werden.“ Dann findet Bedingung 1 und 2 keine Anwendung.
 In DF2:

Code:

=WENN(ZÄHLENWENN(DC:DC;0)=2;1;WENN(ZÄHLENWENN(DC:DC;0)=3;2;WENN(ZÄHLENWENN(DC:DC;0)>=4;3;0)))

das bekomme ich nicht rein in die Formel:
Es kann immer pro Serie in DC eine Bedingung zur Anwendung kommen.
Wenn Bedingung 3, „Wenn in Spalte DC in vier oder mehr Zellen untereinander eine 0 steht,soll in DF2 3 addiert werden.“ Dann findet Bedingung 1 und 2 keine Anwendung.


Gruß Markus

[neopa]

Hallo Markus,

so wie Du es bisher beschrieben hast mit folgender Formel: =MAX(MIN(ZÄHLENWENN(DC:DC;0);4)-1;0)

[Oberon]

Hi,

ich habe es so verstanden:

Code:

=SUMME(VERWEIS(KGRÖSSTE((DC1:DC50=0)*(DC2:DC51<>0)*(DC2:DC51<>"")*(ZEILE(DC1:DC50)+1);ZEILE(A1:A10))-KGRÖSSTE((DC1:DC50<>0)*(DC2:DC51=0)*(LÄNGE(DC2:DC51)>0)*(ZEILE(DC1:DC50)+1);ZEILE(A1:A10));{0;1;2;3;4};{0;0;1;2;3}))

Mit STRG-Shift-Enter abschließen und Bereiche anpassen.

CU
Oberon

[Maximus]

Danke Werner,
Danke Oberon,
Bin gerade unterwegs. Werde beide Formeln morgen testen und mich dann wieder melden!
Guten Rutsch!!!!‘

[Maximus]

Guten Morgen,

habe eine Test-Datei angehängt mit:
-          meiner Formel
-          Werner Formel
-          Oberon Formel
 
 
Leider zeigen alle drei Formeln nicht das richtige Ergebnis.
 
Das richtige Ergebnis ist: 14
 
 
Regeln:
 
1.       Wenn in Spalte A in zwei Zellen untereinander eine 0 steht,  soll in z.b. in B2 +1 addiert werden.
 
2.       Wenn in Spalte A in drei Zellen untereinander eine 0 steht,  soll in z.b. in B2 +2 addiert werden.
 
3.       Wenn in Spalte A in vier oder mehr Zellen untereinander eine 0 steht,  soll in z.b. in B2 +3 addiert werden.
 
4.       Wenn Regel 3 zutrifft, dann findet Regel 2 und Regel 1 keine Anwendung mehr.
 
Wenn Regel 2 zutrifft, dann findet Regel 1 keine Anwendung mehr.
 
 
 
 
Auf das Ergebnis 14 bei meiner Test-Datei komme ich, weil in Zeilen:
 
9 :10                             +1
15 :17                           +2
21:22                           +1
24:28                           +3
31:34                           +3
36:37                           +1
41:45                           +3
 
 
 
Hat wer eine Idee?
 
 
Danke und Frohes Neues Jahr!
Gruss Markus
  Test-Datei.xlsx (Größe: 12,7 KB / Downloads: 10)

[shift-del]

Auf das Ergebnis 14 bei meiner Test-Datei komme ich, weil in Zeilen:
 
9 :10                             +1
15 :17                           +2
21:22                           +1
24:28                           +3
31:34                           +3
36:37                           +1
41:45                           +3

Dann hast du wohl die falsche Test-Datei hochgeladen.

Code:

=SUMME(XVERWEIS(LÄNGE(TEXTTEILEN(WECHSELN(WECHSELN(TEXTVERKETTEN(" ";FALSCH;Tabelle3[Status]);"  ";"#");" ";"");"#"));{2;3;4};{1;2;3};0;-1;1))

[Oberon]

Hi,

versuch es mal so:

Code:

=SUMME(VERWEIS(KGRÖSSTE((A1:A46=0)*(LÄNGE(A1:A46)>0)*(A2:A47="")*(ZEILE(A1:A46)+1);ZEILE(A1:A20))-KGRÖSSTE(((A1:A46="")+(A1:A46="Status"))*(A2:A47=0)*(LÄNGE(A2:A47)>0)*(ZEILE(A1:A46)+1);ZEILE(A1:A20));{0;1;2;3;4};{0;0;1;2;3}))

Mit STRG-Shift-Enter abschließen.

CU
Oberon

[Maximus]

Hallo Detlef,

meine Test-Datei stimmt.
Viel wichtiger: Deine Formel ist genial - stimmt! Perfekt! 

Danke dir!

Excellent!

Gruss Markus

---

Hallo Oberon,

danke für deine Formel. Komme nicht direkt mit der Formel auf das richtige Ergebnis. Ich teste noch ein bissel herum.

Vielen Dank für deine Arbeit!

Gruss Markus

[shift-del]

meine Test-Datei stimmt.

Die Zeitangaben stehen nicht in der Datei die ich runtergeladen habe.

[Elex]

Servus

Die Zeitangaben stehen nicht in der Datei die ich runtergeladen habe.

Humor oder Fehlinterpretation?

Interessanter ist wie der TE die Formel in Excel 2010 umgesetzt hat.

Bei neuerem Excel sollte auch das gehen.

Code:

=SUMME(LÄNGE(LINKS(TEXTTEILEN(TEXTVERKETTEN("";;WENN(A2:A46="";"#";A2:A46));;"#";1);4))-1)

oder

Code:

=SUMME(LÄNGE(LINKS(TEXTTEILEN(TEXTKETTE(WENN(A2:A46="";"#";A2:A46));;"#";1);4))-1)

Gruß Elex