Wochen&tage in Minuten umwandeln

[dindu]

Hallo zusammen,

ich brauche eine Formel, die Wochen mit Tagen zusammen in Minuten umwandelt
1w 4d= Minuten?

Gruß
Dindu

[steve1da]

Hola,

Code:

=WENNFEHLER(TEIL(A2;FINDEN("w";A2)-1;1)*10080;0)+WENNFEHLER(TEIL(A2;FINDEN("d";A2)-1;1)*1440;0)

Gruß,
steve1da

[WillWissen]

Mein Vorschlag:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Dauer	Dauer in Minuten
2	1w 4d	15840
3	2w 3d	24480
4	1w 1d	11520
5	2w 1d	21600
6	2w 3d	24480
7	2w 3d	24480
8	1w 3d	14400

Zelle	Formel
B2	=(LINKS(A2;1)*7+TEIL(A2;4;1))*24*60

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

beide Formeln versagen bei zweistelligen Wochenzahlen!

   


Mein Vorschlag:

Code:

=(LINKS(A2;SUCHEN("w";A2)-1)*7+WECHSELN(TEIL(A2;SUCHEN("w";A2)+1;99);"d";""))*1440

[dindu]

Danke an euch beide, es funktioniert super.
Nice weekend.
Gruß
Dindu

[dindu]

Hallo zusammen, 

wenn ich die gleiche Formel kopiere und möchte D2 und F2 berechnen , es gibt einen falschen Wert (siehe gelbe Zeilen im Anhang)
Danke.

[WillWissen]

Hi,

das ist doch klar! Schau dir mal die (Original)Formel und die alphanumerischen Werte in Spalte A an. Und dann mache mal das Gleiche mit deinen beiden anderen Spalten. Fällt dir nichts auf?

[Jockel]

Hallo zusammen, 

wenn ich die gleiche Formel kopiere und möchte D2 und F2 berechnen , es gibt einen falschen Wert (siehe gelbe Zeilen im Anhang)
Danke.

Moin, es (er)gibt keinen "falschen" Wert - die Formel ist für diesen Fall nicht falsch, sondern nicht die richtige, weil "w" und "d" in C nicht vorkommen..!?!?

[dindu]

Hi Jörg, 

wie du siehst, ich kenne mich nicht gut aus, ich brauche eine Formel, die W/D/&H in Minuten errechnet, auch wenn in verschiedenen Zellen nur 2 Werte existieren (W/D) W/D/H) siehe im Anhang, danke

[shift-del]

Moin

Typischer Fall von unvollständiger Problembeschreibung.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	W/D/H_1	w	d	h	m	w	d	h	m	10080	1440	60	1
2	1w 4d	2	5	#WERT!	#WERT!	1	4	#WERT!	#WERT!	10080	5760	0	0	15840
3	2w 3d	2	5	#WERT!	#WERT!	2	3	#WERT!	#WERT!	20160	4320	0	0	24480
4	1w 1d	2	5	#WERT!	#WERT!	1	1	#WERT!	#WERT!	10080	1440	0	0	11520
5	2w 1d	2	5	#WERT!	#WERT!	2	1	#WERT!	#WERT!	20160	1440	0	0	21600
6	2w 3d	2	5	#WERT!	#WERT!	2	3	#WERT!	#WERT!	20160	4320	0	0	24480
7	2w 3d	2	5	#WERT!	#WERT!	2	3	#WERT!	#WERT!	20160	4320	0	0	24480
8	1w 3d	2	5	#WERT!	#WERT!	1	3	#WERT!	#WERT!	10080	4320	0	0	14400
9	1h 16m	#WERT!	#WERT!	2	6	#WERT!	#WERT!	1	16	0	0	60	16	76
10	32min	#WERT!	#WERT!	#WERT!	3	#WERT!	#WERT!	#WERT!	32	0	0	0	32	32
11	1d 8h	#WERT!	2	5	#WERT!	#WERT!	1	8	#WERT!	0	1440	480	0	1920
12	6h 43m	#WERT!	#WERT!	2	6	#WERT!	#WERT!	6	43	0	0	360	43	403
13	2h 33m	#WERT!	#WERT!	2	6	#WERT!	#WERT!	2	33	0	0	120	33	153
14	1d 4h	#WERT!	2	5	#WERT!	#WERT!	1	4	#WERT!	0	1440	240	0	1680
15	2d 8h	#WERT!	2	5	#WERT!	#WERT!	2	8	#WERT!	0	2880	480	0	3360

Zelle	Formel
B2	=SUCHEN(B$1;$A2)
C2	=SUCHEN(C$1;$A2)
D2	=SUCHEN(D$1;$A2)
E2	=SUCHEN(E$1;$A2)
F2	=WECHSELN(TEIL($A2;MAX(1;B2-2);2);F$1;"")
G2	=WECHSELN(TEIL($A2;MAX(1;C2-2);2);G$1;"")
H2	=WECHSELN(TEIL($A2;MAX(1;D2-2);2);H$1;"")
I2	=WECHSELN(TEIL($A2;MAX(1;E2-2);2);I$1;"")
J2	=WENNFEHLER(F2*J$1;0)
K2	=WENNFEHLER(G2*K$1;0)
L2	=WENNFEHLER(H2*L$1;0)
M2	=WENNFEHLER(I2*M$1;0)
N2	=SUMME(J2:M2)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg