Arbeitszeit Berechnung

[didi*]

Hi Andre,

ich habe die morgendliche Differenz so =WENN(D15="a";(D$8-D$7-D$9)-(D7-B25);D$8-D$7-D$9)
gelöst. Für der Zeile "Gesamt" ich denke das passt auch. Wie krieg ich denn den Nachmittag da noch rein... :17: mit und / oder stehe ich noch auf dem Kriegsfuß.

EDIT::
Shit passt natürlich nicht... muss ich nochmal ran.

[schauan]

Hallöchen,

im Prinzip addierst Du die 3 Bestandteile Kernzeit, "FrühArzt" und "NachmittagArzt"
Hier mal Kernzeit + FrühArzt
=(E8-E7)+(E7-B27)*(E15="A")

FrühArzt ist hier ohne WENN und aber

(E7-B27)*(E15="A")

Ich habe hier eine boolsche Operation dabei.
E7-B27 wäre die Zeitberechnung.
(E15="A") wäre die Prüfung, ob da ein A steht. Wenn ja, dann ist das 1, wenn nein, dann 0

Ich hätte also je nach A entweder
(E7-B27)*1
oder
(E7-B27)*0

und dadurch klappt's auch mit dem Nachbarn - nein mit der Formel

[didi*]

Hi,

boolesche OP  :16: :15: wie kommt man denn auf sowas...  :19:

Wenn ich dann die Nachmittagzeit so:

"=(E8-E7)+(E8-C27)-(E9)*(E15="A")

Versuche, stimmt es aber nicht. Oder hab ich wieder ein Brett vor dem Kopf?
Kommt um 8 geht um 15:00 (1hPause) = 6:00 
sollte aber 7:00 da bis 16:00 der "Alte" zahlt. 

Kommt um 10 geht um 16:30 (0,5h Pause) =7:00 Passt !

LG


EDIT:
ich bin doof, "=(E8-E7)+(C27-E8)-(E9)*(E15="A")
So macht es mehr Sinn , oder ?

EDIT2:
ich habe mir noch einen "Ausblender" eingebaut.
=WENN(E8>=C27;"";(E8-E7)+(C27-E8)-(E9)*(E15="A"))
Sonst wird es unübersichtlich. 

Schaust du nochmal rüber, bevor ich das final fertig baue?
Ich glaube morgens stimm noch was nicht.

LG

[schauan]

Hi,

müsste das nicht anders rum sein?

=WENN(D7>=$B$27;(D8-D7)+(D7-$B$27)-(D9)*(D15="A");"")

[didi*]

Hi Andre,

sooo habe mal im Rahmen, meiner (ich freu mir einen ab) gewachsenen Möglichkeiten etwas rumprobiert.

1/2 tag Urlaub war jetzt nicht soo schwierig, morgendlicher Arztbesuch.... naja schon eher. Zumindest, das in eine Formel zu bekommen.

Schau dir die grün markierte Zelle bitte an... kann ich das so machen??

LG

[schauan]

Hi Didi,

was soll den eigentlich in der Spalte stehen? Wenn ich die Formel eine Zelle runter ziehe, wird aus den 0,32 dann 7,60. Das würde logisch nicht zur -1 passen...

[didi*]

Hi,

wie gesagt "meine Logik"  :17:

Das ist eine reine Hilfsspalte für "a" und "uh". Bis jetzt aber nur die "morgendlichen" , weiter komme ich nicht.
Wenn du sie runterziehst passiert ohne a oder uh natürlich "logisch" erstmal nix.

In der Zelle erscheinen nach Eingabe von Uh oder a die entsprechenden Minus Stunden vom Tag. (Bei uh halt -4, das war relativ simpel und bei "a"
am Beispiel: kommt um 10:00 geht um 17:00 Pause 1:00= bezahlt von 9:00 bis 17:00 - Pause = 7:00 Ergebnis in der Zelle -1h , wie gewünscht.
Für mehr reichts nicht und Babs genügt das.


Edit: 
ich habe jetzt die *24 mal angepasst. So ergeben die unteren Zellen dann auch Sinn ?!

PHP-Code:

=WENN($M7="UH";(($C$4-$C$39)*24);WENN($B7>=$B$3;(($C7-$B7)+($B7-$B$3)-($D7)-($C$39)*($M7="A"))*24;$J7)) 


LG

[didi*]

Hi,
editieren ging nicht mehr.

habe noch einen Fehler gefunden.

PHP-Code:

=WENN($M7="UH";(($C$4-$C$39)*24);WENN(UND($M7="A";$B7>=$B$3);(($C7-$B7)+($B7-$B$3)-($D7)-($C$39))*24;$J7)) 


Noch ein "und" für die zeit VOR 9:00 eingefügt.

Allerdings habe ich KEINE Idee wie ich den Nachmittag da noch unterbringe :17: ...


LG

[schauan]

Hallöchen,

das könnte dann so aussehen:

=WENN(UND($M7="A";$B7>$B$3);(($C7-$B7)+($B7-$B$3)-($D7)-($C$39))*24;WENN(UND($M7="A";$C7<$C$3);(($C7-$B7)+($C$3-$C7)-($D7)-($C$39))*24;$J7))

Allerdings hättest Du so nur entweder früh oder nachmittags einen Arztbesuch. Hast Du früh und nachmittags einen, wird nur der von früh genommen.
Mit der Logik, wie ich sie anfangs gepostet hatte, könntest Du beides Ich hatte da die Bestandteile getrennt, also Kernzeit + eventueller Arztbesuch früh und dann käme noch eventueller Arztbesuch nachmittags dazu.

Das würde dann so aussehen:

=(C7-B7-D7-$C$39+WENN(M7="a";(B7>$B$3)*(B7-$B$3)+(C7<$C$3)*($C$3-C7);0))*24

Kernzeit: (C7-B7-D7-$C$39)
Früh: (B7>$B$3)*(B7-$B$3)
Nachmittag: (C7<$C$3)*($C$3-C7)

[didi*]

Hi Andre,

kurze Rückmeldung, meine Babs ist zufrieden und ich beruhigt. Danke dir für die Hilfe.
:100: :19: