Datum in Spalte zählen

[Blacky1980]

Guten Morgen alle zusammen und ein schönes Wochenende

Ich habe eine Termin-Liste und möchte nun die Termine nach Datum zählen.


Anzahl Termine diesen Monat (nur die in der zukunft)
Anzahl Termine dieses Jahr (nur die in der zukunft)

Anzahl Termine nächsten Monat
Anzahl Termine nächstes Jahr


Termine dieses Jahr (alle Termine)
Termine Vorjahr

Das Termin-Datum steht im Tabellenblatt "Termine" Spalt E2:E25000.


Kann da mal bitte jemand helfen?


Danke schonmal vorab.

Gruß Michael

[BoskoBiati]

Hi,

ZÄHLENWENNS(Datumsspalte;">="&Monatsanfang; Datumsspalte;"<="&Monatsende)
ansonsten gibt Deine Beschreibung nicht viel mehr her.

[RPP63]

Moin!
Ich würde dies mit einem Pivot-Table lösen:
• Datum in Zeilen
• Datum in Werte
• Werte zusammenfassen nach Anzahl (dürfte gleich per default gewählt sein)
• Filter auf Datum der Pivot setzen: >=19.10.2024

Gruß Ralf

[Blacky1980]

Hallo Edgar
 
 
Ja Sorry irgendwie ist da was schief gelaufen mit dem Beitrag.
 
 
Im Tabellenblatt "Termine" habe ich in der Spalte A2:D21000 meine Termindaten stehen in der Spalte E2:E21000 steht das jeweilige Datum für den Termin.
 
Nun möchte ich nur das Datum in der Spalte E nach bestimmten Kriterien zählen.
 
1. Die Anzahl der Termine die in diesen Monat noch anstehen (Zukunft)
2. Die Anzahl der Termine die im nächsten Monat noch anstehen (Zukunft)
3. Die Anzahl der Termine die in diesem Jahr noch anstehen (Zukunft)
 
4. Alle Termine in diesem Jahr (Zukunft und Vergangenheit)
5. Alle Termine Vorjahr
 
Es soll dann immer von HEUTE() ausgegangen werden.


Gruß Michael

[Sigi.21]

Hallo Michael,

Zählenwenns() ist hier schon richtig. (s. Bsp.)


Gruß Sigi

[EA1950]

Hallo,

Anzahl Termine diesen Monat (nur die in der zukunft)
=LET(h;HEUTE();me;MONATSENDE(h;0);tm;Termine!$E$2:$E$25000;ZÄHLENWENNS(tm;">"&h;tm;"<="&me))
Anzahl Termine dieses Jahr (nur die in der zukunft)
=LET(h;HEUTE();j;JAHR(h);end;DATUM(j;12;31);tm;Termine!$E$2:$E$25000;ZÄHLENWENNS(tm;">"&h;tm;"<="&end))
Anzahl Termine nächsten Monat
=LET(h;HEUTE();j;JAHR(h);m;MONAT(h);anf;MONATSENDE(h;0)+1;end;MONATSENDE(h;1);tm;Termine!$E$2:$E$25000;ZÄHLENWENNS(tm;">="&anf;tm;"<="&end))
Anzahl Termine nächstes Jahr
=LET(h;HEUTE();j;JAHR(h);anf;DATUM(j+1;1;1); end;DATUM(j+1;12;31); tm;Termine!$E$2:$E$25000; ZÄHLENWENNS(tm;">="&anf;tm;"<="&end))

Termine dieses Jahr (alle Termine)
=LET(h;HEUTE();j;JAHR(h);anf;DATUM(j;1;1); end;DATUM(j;12;31);tm;Termine!$E$2:$E$25000; ZÄHLENWENNS(tm;">="&anf;tm;"<="&end))
Termine Vorjahr
=LET(h;HEUTE();j;JAHR(h);anf;DATUM(j-1;1;1); end;DATUM(j-1;12;31);  tm;Termine!$E$2:$E$25000; ZÄHLENWENNS(tm;">="&anf;tm;"<="&end))

[Blacky1980]

Hallo Ralf und Sigi

@Ralf
Die Daten werden auch in anderen Bereichen benötigt und sverweis gearbeitet. Ich habe auch noch nie mit Pivot-Table gearbeitet und kenne mich da garnicht aus.


@Sigi
So hatte ich es auch schon aber leider komme ich da nicht weiter damit ich es nach meinen Kriterien zählen kann.


Gruß Michael

[BoskoBiati]

Hi,

bevor es da endlosese Rätselraten gibt, zeige mal die Datei.

[Blacky1980]

Hallo Anton



Das hätte ich so nie hinbekommen. Ich dachte nicht, dass es so kompliziert ist etwas mit Datum zu berechnen/zählen.

Ich werde mal versuchen die Formel und Funktion zu verstehen.
 
Vielen vielen Dank



Gruß Michael

[Sigi.21]

Hallo Michael,

das kann man doch erweitern. (s. Mappe)


Gruß Sigi