Summenprodukt

[Untertaker.one1]

Hallo liebe Mitglieder :)


Ist es irgendwie möglich bei dieser Formel:

Code:

=SUMMENPRODUKT((Einscannen1!$B$1:$1>=AE$1)*(Einscannen1!$B$1:$1<=AF$1)*(Einscannen1!$B2:2))

 

diesen Teil:

Code:

*(Einscannen1!$B2:2))

so abzuändern das er in Spalte "A2:A" ein Wert sucht und dann die Zeile nutzt?

Es geht bei der Formel um eine Auswertung mittels Datum.

Vielen Dank für eure Unterstützung

[WillWissen]

Hi,

zeig das mal bitte anhand eines Beispiels. .xlsx!!-kein Bild

[Untertaker.one1]

Hallo,

im Anhang dazu eine Datei.

wie du in der Formel sieht ab zeile 9 rechnet er die Daten von M01EdelAS zusammen.
Jetzt wäre es schön wenn man per Formel sagt M02EdelAW muss unter Spalte K gefunden werden dann die Zeile für die Berechnung nutzen

[Klaus-Dieter]

Hallo,

sieht die Originaldatei genau so aus? Dann würde ja eine einfache Summenformel reichen.

[Untertaker.one1]

Hallo,

nein leider nicht das ist jetzt nur eine Beispieldatei Original-Datei beinhaltet mehrere Tausende Zeilen
und nicht jeder Wert taucht bei der Auswertung auf. Deswegen habe ich einige zusätzliche Werte hinzugefügt die in der Datei nicht farblich gekennzeichnet sind.

wenn man hier jetzt ein Kriterium zb. M02EdelAW suchen könnte und die zeilen L30:P30 addiert werden. Dann wäre mein anliegen geklärt.

Code:

*(L9:P9))

[schauan]

Hallöchen,

ich hab das hier mal mit Spalte B gemacht und die Summe von B2 bis zum gesuchten Begriff (steht in D1) gerechnet

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D
1	Artikel Nr.	01.01.2020	05.01.2020	M02EdelAW
2	M01EdelAW	5		33
3	M01BlackAW	4
4	M01GrauAW	5
5	M01WeissAW	13
6	M01RotAW	1
7	M01RostAW	2
8	M01SonderAW	1
9	M02EdelAW	2
10	M02BlackAW	5

Zelle	Formel
D2	=SUMME(B2:INDEX(B2:B21;VERGLEICH(D1;A2:A21;0);))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Untertaker.one1]

Hallo,

vielen Dank für deine Antwort.
Leider führt die Variante nicht zum erwünschten erfolg. 

Diese Formel gibt das Ergebnis 33 aus richtig wäre hier 1.

Du hast die Spalten K-P nicht berücksichtigt. K-P sind die Verkäufe an den jeweilen Tagen.

Die Werte die in Spalte A2:A21 eingetragen sind müssen im Bereich K Gefunden werden und mittels Datum B und C in L-P die Verkäufe zusammenzählen.

daher ist glaube der Ansatz SUMMENPRODUKT soweit ganz richtig denke ich zumindest.

[schauan]

Hallöchen,

ich habe ja geschrieben, dass ich hier eine Summe in Spalte B bilde und die ist auch korrekt. Der Punkt ist, wenn Du Dich mit der Summenfunktion auskennst, dass diese z.B. einen Bereich umfasst, der durch zwei Zellen eingegrenzt ist.

In meiner Formel siehst Du aber keine zwei Zelladressen, sondern nur den Beginn als B2 und das Ende mit Hilfe einer Formel.

Wenn Du nun diese INDEX-Formel mal analysierst, solltest Du erkennen, wie der Suchbegriff mit Hilfe von VERGLEICH gefunden und verarbeitet wird und könntest die Formel auf Deine Bedürfnisse entsprechend anpassen.


Die Lösung sollte dann so aussehen:

=SUMME(INDEX(L2:L100;VERGLEICH(D1;K2:K100;0);):INDEX(P2:P100;VERGLEICH(D1;K2:K100;0);))


Ich hab jetzt allerdings auch wieder D1 als Eingabezelle genommen und nicht die Einträge aus Spalte B  :22:
Und wenn Du die Formel runter ziehen willst musst Du für die Suchbereiche noch absolute Adressierung verwenden statt der relativen.  :17:

[Untertaker.one1]

vielen Dank das sieht jetzt schon besser aus.
aber.... :D

Wie bekomme ich jetzt in dieser Formel mein Datum mit untergebracht?
Spalte B1 und C1 soll den Zeitraum differieren und im Bereich L-P abgleichen.

vielen Dank

[schauan]

Hallöchen,

bei INDEX gibt es eine Zeilen- und eine Spaltenangabe. In der bisherigen Formel fehlt die Spaltenangabe, es ist ja auch nur jeweils ein einspaltiger Bereich definiert.
Für das Finden des Datums benötigen wir einen weiteren Vergleich, den wir als Spaltenangabe für den INDEX nutzen. Den INDEX müssen wir dann natürlich in beiden Teilen auf den gesamten Suchbereich ausdehnen.

Das könnte dann so aussehen, und wieder der Hinweis mit der absoluten Adressierung ...:

=SUMME(INDEX(L2:P100;VERGLEICH(D1;K2:K100;0);VERGLEICH(B1;L1:P1;0)):INDEX(L2:P100;VERGLEICH(D1;K2:K100;0);VERGLEICH(C1;L1:P1;0)))