Tabelleninhalt abhängig von Datum

[GMG-CC]

Mit PT kein Problem ...

[diving_excel]

Also hab jetzt folgende Formel zusammengezimmert:

Code:

=SUMMENPRODUKT((JAHR($W$10:$W$204)=$AF$1)*(MONAT($W$10:$W$204)<4)*($C$10:$C$204="*A*")*($G$10:$G$204="*gewonnen*")*($D$10:$D$204))

Bekomm aber irgendwie nur immer 0 raus?
Achja die Zellen hab ich angepasst, also nicht wundern dass die nicht wie bisher sind.

[diving_excel]

habs mit PT versucht, aber er sagt mir dass die Bezüge Falsch sind, obwohl ich keine leere Zelle in der ersten zeile hab und auch keine verdeckten. Deswegen bin ich den Weg von Guschti gegangen.

[steve1da]

Hola,

bei Summenprodukt funktionieren Platzhalter bei Wörtern nicht.

=Summenprodukt((.......)*(istzahl(suchen("A";$C$10:$C$C204))).....))

Mit „gewonnen“ dann natürlich genau so.

Gruß,
steve1da

[Guschti]

Hallo

Im Anhang deine Datei mit Wunsch zurück

Mfg Guschti

[diving_excel]

Hab jetzt die Formel geändert

Code:

=SUMMENPRODUKT((JAHR($W$10:$W$204)=$AF$1)*(MONAT($W$10:$W$204)<4)*(ISTZAHL(SUCHEN("*gewonnen*";$G$10:$G$204)))*(ISTZAHL(SUCHEN("*A*";$C$10:$C$204)))*($D$10:$D$204))

Funktioniert, ich bekomme aber nicht den korrekten wert raus, ich vermute das liegt an den Sternchen bei gewonnen oder A. Die Brauch ich da manchmal zb bei der Kategorie A noch Text davor bzw. dannach kommt.

Hab ich die Sternchen falsch gesetzt?

[steve1da]

Hola,

ich hab’s doch ohne Sternchen geschrieben. Die sind nicht nötig, es wird nach a oder gewonnen in den Zellen gesucht, egal ob etwas davor oder dahinter steht.

Gruß,
steve1da

[diving_excel]

Mit dem Summenprodukt bekomme ich Werte raus die deutlich zu hoch sind...
Habs jetzt neu mit der Summenwenns Formel versucht:

Code:

=SUMMEWENNS($C:$C;$D:$D;"*AB";$E:$E;"Gewonnen*";$F:$F;I$3)

Wobei der letzte Kriterienbereich das Datum wiederspiegeln soll...
Ich möchte also sagen: Excel soll mir alles aufsummieren wenn:
- Der Term "AB" aus dem Bereich Kategorisierung vorkommt
- Es den jeweiligen Status hat (z.B. Gewonnen)
- Es im jeweiligen Quartal liegt

leider bekomme ich da jedes mal nur Null raus... Woran liegt das?

Im Anhang findet sich eine angefangene Excel Datei...

Mal wieder... danke!!

[steve1da]

Hola,

du vergleichst ein Datum (Zahl) mit einem manuell erstellen "Quartal" (Text). Das ergibt immer Null.
Mach dir eine Hilfsspalte, z.B. ab G3, in der du das Quartal des jew. Datums in F ermittelst:

Code:

=MONAT(MONAT(F3)&0)

In I3, J3, K3 und L3 kommen die Zahlen 1-4. Jetzt kannst du G:G mit I3 usw. vergleichen.

Edit: warum aber schreibst du "gewonnen" mit Sternchen - da steht doch sonst nix in der Zelle. Dann geht auch:

Code:

=SUMMENPRODUKT((ISTZAHL(SUCHEN("ab";$D$3:$D$31)))*($E$3:$E$31=$H5)*($G$3:$G$31=I$3)*($C$3:$C$31))

Gruß,
steve1da

[Jockel]

Hallo, mit kleinen Abänderungen geht (z.B. Hilfsspalte für's Quartal) ..:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	I	J	K	L	M
2	Jahr	2016
3	Quartal	Q1/16	Q2/16	Q3/16	Q4/16
4	Gesamt	344	0	3234	0
5	Gewonnen	0	0	3234	0
6	Verloren	344	0	0	0
7	Ausstehend	0	0	0	0

Zelle	Formel
J3	="Q"&SPALTE(A1)&"/"&RECHTS($J$2;2)
J4	=SUMME(J5:J7)
J5	=SUMMEWENNS($C:$C;$D:$D;"*AB";$E:$E;$I5;$G:$G;J$3)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

oder mit der guten alten Datentabelle..: 

Die geschweiften Klammern werden automatisch gesetzt...

Arbeitsblatt mit dem Namen 'Tabelle1'
	I	J	K	L	M
1
2	Jahr	2015
3	Quartal	Q1/15	Q2/15	Q3/15	Q4/15
4	Gewonnen	300	0	0	0
5	Verloren	0	0	0	0
6	Ausstehend	0	0	0	0
7	Gesamt	300	0	0	0

Zelle	Format	Wert
I3	"Quartal"	0

Zelle	Formel
I3	=SUMMEWENNS($C:$C;$D:$D;"*AB";$E:$E;$I1;$G:$G;J$1)
J3	="Q"&SPALTE(A1)&"/"&RECHTS($J$2;2)
K3	="Q"&SPALTE(B1)&"/"&RECHTS($J$2;2)
L3	="Q"&SPALTE(C1)&"/"&RECHTS($J$2;2)
M3	="Q"&SPALTE(D1)&"/"&RECHTS($J$2;2)
J4	{=MEHRFACHOPERATION(J1;I1)}
K4	{=MEHRFACHOPERATION(J1;I1)}
L4	{=MEHRFACHOPERATION(J1;I1)}
M4	{=MEHRFACHOPERATION(J1;I1)}
J5	{=MEHRFACHOPERATION(J1;I1)}
K5	{=MEHRFACHOPERATION(J1;I1)}
L5	{=MEHRFACHOPERATION(J1;I1)}
M5	{=MEHRFACHOPERATION(J1;I1)}
J6	{=MEHRFACHOPERATION(J1;I1)}
K6	{=MEHRFACHOPERATION(J1;I1)}
L6	{=MEHRFACHOPERATION(J1;I1)}
M6	{=MEHRFACHOPERATION(J1;I1)}
J7	=SUMME(J4:J6)
K7	=SUMME(K4:K6)
L7	=SUMME(L4:L6)
M7	=SUMME(M4:M6)

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg