WENN ODER Verschachtelt

[_yilli_]

Guten Abend zusammen,

ich arbeite aktuell an einer sehr großen Tabelle und benötige eure Hilfe.
Im Anhang befindet sich ein Auszug aus meiner Tabelle.

In der Spalte A stehen verschieden Werte, z. B.:

• B Sample (Datum, teilweise auch ohne Datum)
  
• C Sample (Datum, teilweise auch ohne Datum)
  
• D Sample (Datum, teilweise auch ohne Datum)
  
• B2 Sample (Datum, teilweise auch ohne Datum)
  
• C2 Sample (Datum, teilweise auch ohne Datum)
  
• D2 Sample (Datum, teilweise auch ohne Datum)
  
• 18xxxx
  
• 19xxxx
  
• 20xxxx
  
• SOP
  
• SOP + 1 Year
  
• SOP + 2 Year
  
• ÄJ xxx
  
• System ...
  
• ... System ...
  
• usw.
  

Mein Hauptziel ist es, dass in der Spalte K (Gesamt (Verschachtelung)) sämtliche Werte wie folgt angezeit werden.

• Bei B, C, D, B2, C2 und D2 soll jeweils der Buchstabe mit einem "-" und "Sample" dastehen z. B. B2-Sample (ohne Datum)
  
• Bei 18, 19 und 20 soll immer "Software" dastehen
  
• SOP gleich "SOP"
  
• SOP + 1 year gleich "SOP + 1 year"
  
• SOP + 2 year gleich "SOP +2"
  
• Wenn eine Zelle den Text System bzw. ÄJ enthällt soll "Unknown" dastehen
  

Spalte B bis J diente der Übung, aber ich komme irgendwie nicht weiter.
Ich wäre sehr dankbar, wenn ihr mir Tips geben könnten.
Habe noch weitere Versuche gewagt, diese kann ich im Nachgang noch gerne zeigen.

Vielen Dank im Voraus und freundliche Grüße :)

---

Hier noch zwei Versuche welche aber nicht so recht klappen.

=WENN(ODER(LINKS(A2;1)="B";LINKS(A2;1)="C";LINKS(A2;1)="D");WENN(LINKS(A2;2)="D2";LINKS(A2;2)&"-Sample";LINKS(A2;1)&"-Sample");WENN(ODER(LINKS(A2;2)="20";LINKS(A2;2)="19";LINKS(A2;2)="18";"Software";"Unknown")))
 
=WENN(ODER(LINKS(A2;1)="B";LINKS(A2;1)="C";LINKS(A2;1)="D";LINKS(A2;2)="20";LINKS(A2;2)="19";LINKS(A2;2)="18");WENN(LINKS(A2;2)="D2";LINKS(A2;2)&"-Sample";LINKS(A2;1)&"-Sample";LINKS(A2;2)="20";LINKS(A2;2)="19";LINKS(A2;2)="18");WENN(LINKS(A2;2)="18";"Software";"Unknown"))

[BoskoBiati]

Hi,

versuchs mal so:

Code:

=WENN(ODER(ISTZAHL(SUCHEN("Sys";A2));ISTZAHL(SUCHEN("ÄJ";A2)));"Unknown";WENN(ISTZAHL(SUCHEN("SOP";A2));WECHSELN(A2;WENN(ISTZAHL(SUCHEN("2";A2));" Year";"");"");WENN(ISTZAHL(SUCHEN("Sam";A2));WECHSELN(LINKS(A2;SUCHEN("#";WECHSELN(A2&" ";" ";"#";2))-1);" ";"-");A2)))

[snb]

In VBA

Code:

Sub M_snb()
  with Columns(1)
      .Replace " Sample (*)", "-Sample"
     .Replace " Sample", "-Sample"
     .Replace " year", ""
     .Replace " + 1", " + 1 year"
     .Replace "18*", "software"
     .Replace "19*", "software"
    .Replace "20*", "software"
  end with
End Sub

[_yilli_]

Hi,
vielen Dank für deinen Vorschlag.
Aber sollte ohne VBA sein.
Habe immer noch keine finale Lösung gefunden.
Gruß

[BoskoBiati]

Hi,

nimm diese Formel:

Code:

=WENN(ODER(ISTZAHL(SUCHEN("Sys";A2));ISTZAHL(SUCHEN("ÄJ";A2)));"Unknown";WENN(ISTZAHL(SUCHEN("SOP";A2));WECHSELN(A2;WENN(ISTZAHL(SUCHEN("2";A2));" Year";"");"");WENN(ISTZAHL(SUCHEN("Sam";A2));WECHSELN(LINKS(A2;SUCHEN("#";WECHSELN(A2&" ";" ";"#";2))-1);" ";"-");"Software")))

Sei so gut und setze Dich damit mal auseinander, damit Du verstehst, was passiert --> Formelauswertung!

[Fred11]

Hallo,

du musst halt konsequent mit verschachtelten WENN-Funktionen deine verschiedenen Bedingungen nacheinander abhandeln und dabei versuchen, vielleicht einige (ähnliche) Bedingungen mit ODER zusammenzufassen (B, C, D, B2, C2 und D2), um die Verschachtelungstiefe so gering und damit die Formel so kurz wie möglich zu halten.
Und dann deine WENNs gut durchzählen, dass du nicht den Überblick verlierst und am Ende alle Klammern auch wieder schliesst.

Hie nochr ein Formelvorschlag von mir:

Code:

=WENN(ODER( LINKS(A2;1)="B"; LINKS(A2;1)="C"; LINKS(A2;1)="D");WECHSELN(LINKS(A2;2);" ";"")&"-Sample";WENN(ODER(LINKS(A2;2)="18";LINKS(A2;2)="19";LINKS(A2;2)="20");"Software";WENN(LINKS(A2;3)="SOP";A2;WENN(ODER(ISTZAHL(SUCHEN("System";A2));ISTZAHL(SUCHEN("ÄJ";A2)));"unknown";WENN(A2="";"";"????????????")))))

In dieser Formel habe ich alle deine Bedingungen reingepackt; wenn keine der Bedingung zutrifft,  gibt die Formel "?????????" zurück.
Da bleiben dann ein paar Werte übrig, wie z.B. "ASA-Sample".

Wenn diese übriggebliebenen Werte auch verarbeitet werden sollen, mußt du sie halt auch noch in die Formel mit reinpacken

Gruß
Fred

[BoskoBiati]

Hi,

das:

Code:

=WENN(ISTZAHL(SUCHEN("-Sample";A2));A2;WENN(ODER(ISTZAHL(SUCHEN("Sys";A2));ISTZAHL(SUCHEN("ÄJ";A2)));"Unknown";WENN(ISTZAHL(SUCHEN("SOP";A2));WECHSELN(A2;WENN(ISTZAHL(SUCHEN("2";A2));" Year";"");"");WENN(ISTZAHL(SUCHEN("Sam";A2));WECHSELN(LINKS(A2;SUCHEN("#";WECHSELN(A2&" ";" ";"#";2))-1);" ";"-");"Software"))))

deckt fast alle Fälle ab, außer sowas:

Mechanical Design C-Sample Build Up (2019-05-31)
Hardware C2-Sample (2019-09-30)
ASA-Sample

[snb]

Warum ohne VBA ?
Ein richtiges Ergebnis ist doch wichtiger ?

[_yilli_]

Vielen Dank für die Antworten.

Ich werde mich jetzt damit auseinandersetzen und versuche die Lösungen nachvollziehen zu können.

[WillWissen]

Hi snb,

Warum ohne VBA ?

sehr viele Firmen dulden keine Makros.