Werte unter Voraussetzungen übertragen

[RPP63]

Nur ergänzend!
SPALTENWAHL() ist für mich eine überflüssige neuere Funktion, die imo den einzigen Vorteil hat, "sprechend" zu sein.
Statt
=SPALTENWAHL(Spillbereich;2;8)
nehme ich das "altbewährte"
=INDEX(Spillbereich;;{2.8})

Gruß Ralf

[BoskoBiati]

Hi,

wußte gar nicht, dass das auch funktioniert. Danke für den Hinweis!

[HKindler]

Hi,

@RPP63
=INDEX(Spillbereich;;{2.8})
liefert bei mir aber nur die entsprechenden Spalten der ersten Zeile des Spillbereichs.
SPALTENWAHL hingegen liefert die kompletten Spalten.

[snb]

=INDEX(Spillbereich;0;{2.8})

[HKindler]

Hi,

auch die mit der 0 ergänzte Formel ergibt bei mir nur die erste Zeile.
Übrigens hatte ich das schon versucht


Bei mir funktioniert z.B.
=INDEX(Spillbereich;SEQUENZ(Spillbereich);{2.8})
Aber da nehmen ich doch lieber
=SPALTENWAHL(Spillbereich;2;8)

[snb]

Dan muss funktionieren

=INDEX(Spillbereich;row(Spillbereich);{2\8})

[BoskoBiati]

Hi,

Dan muss funktionieren

=INDEX(Spillbereich;row(Spillbereich);{2.8})

Nein! Nur wenn der Spillbereich in Zeile 1 beginnt. Im Fall der Mappe4 geht das so:

Code:

=INDEX(FILTER(Quelle!R8:Y182;Quelle!S8:S182<>"");ZEILE(1:174);{2.8})

[snb]

Ich mag diese !!!

[HKindler]

Hi,

Code:

=INDEX(FILTER(Quelle!R8:Y182;Quelle!S8:S182<>"");ZEILE(1:174);{2.8})

Das gibt aber jede Menge #BEZUG!-Fehler am Ende aus.

Mit

Code:

=LET(a;FILTER(Quelle!R8:Y182;Quelle!S8:S182<>"");INDEX(a;SEQUENZ(ZEILEN(a));{2.8}))

passiert das nicht.

Aber mal ehrlich:

Code:

=SPALTENWAHL(FILTER(Quelle!R8:Y182;Quelle!S8:S182<>"");2;8)

ist da doch einfacher!

[BoskoBiati]

Hallo Helmut,

Das gibt aber jede Menge #BEZUG!-Fehler am Ende aus.

Stimmt, habe gar nicht soweit geblättert, dass ich das sehen konnte. Mit WENNFEHLER kann man das auch noch ausschalten. Mir ging es in erster Linie darum, den Schwachpunkt in der Formel von snb aufzuzeigen.

Natürlich ist SPALTENWAHL sehr viel einfacher, mit LET und SEQUENZ sieht es aber auch gut aus.